WOLFRAM

Wolfram Language & System Documentation Center

MathieuCharacteristicA[r,q]

gives the characteristic value for even Mathieu functions with characteristic exponent r and parameter q.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Numerical Evaluation  
Specific Values  
Visualization  
Function Properties  
Series Expansions  
Applications  
Properties & Relations  
Neat Examples  
See Also
Tech Notes
Related Guides
Related Links
History
Cite this Page

MathieuCharacteristicA

MathieuCharacteristicA[r,q]

gives the characteristic value for even Mathieu functions with characteristic exponent r and parameter q.

Details

  • Mathematical function, suitable for both symbolic and numerical manipulation.
  • The characteristic value gives the value of the parameter in for which the solution has the form , where is an even function of with period .
  • For certain special arguments, MathieuCharacteristicA automatically evaluates to exact values.
  • MathieuCharacteristicA can be evaluated to arbitrary numerical precision.
  • MathieuCharacteristicA automatically threads over lists.

Examples

open all close all

Basic Examples  (3)

Evaluate numerically:

Wolfram Language code: MathieuCharacteristicA[1, 0.5]

Plot over a subset of the reals:

Wolfram Language code: Plot[MathieuCharacteristicA[3, x], {x, -4, 4}]

Plot over a subset of the complexes:

Wolfram Language code: ComplexPlot3D[MathieuCharacteristicA[1 / 3, z], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

Scope  (20)

Numerical Evaluation  (6)

Evaluate numerically:

Wolfram Language code: MathieuCharacteristicA[-2Pi, 0.5]
Wolfram Language code: MathieuCharacteristicA[Pi, 0.]

Evaluate to high precision:

Wolfram Language code: N[MathieuCharacteristicA[15 / 17, 5], 25]

The precision of the output tracks the precision of the input:

Wolfram Language code: MathieuCharacteristicA[0.21111111111111100111, 5]

Complex number inputs:

Wolfram Language code: N[MathieuCharacteristicA[Pi / 5, 5 - I]]

Evaluate efficiently at high precision:

Wolfram Language code: MathieuCharacteristicA[1 / 2347, 5`100]//Timing
Wolfram Language code: MathieuCharacteristicA[152 / 71, 5`1000];//Timing

Compute average-case statistical intervals using Around:

Wolfram Language code: MathieuCharacteristicA[1, Around[1 / 2, 0.01]]

Compute the elementwise values of an array:

Wolfram Language code: MathieuCharacteristicA[.2, {{1 / 2, 0}, {0, 1 / 2}}]

Or compute the matrix MathieuCharacteristicA function using MatrixFunction:

Wolfram Language code: MatrixFunction[MathieuCharacteristicA[.2, #]&, {{1 / 2, 0}, {0, 1 / 2}}]

Specific Values  (2)

Simple exact values are generated automatically:

Wolfram Language code: MathieuCharacteristicA[r, 0]

Find the positive maximum of MathieuCharacteristicA[2,q ]:

Wolfram Language code: qmax = q /. FindRoot[D[MathieuCharacteristicA[2, q ], q] == 0, {q, 4}]
Wolfram Language code: Plot[MathieuCharacteristicA[2, q ], {q, -1, 30}, Epilog -> Style[Point[{qmax, MathieuCharacteristicA[2, qmax ]}], PointSize[Large], Red]]

Visualization  (3)

Plot the MathieuCharacteristicA function for integer parameters:

Wolfram Language code: Plot[{MathieuCharacteristicA[3, x], MathieuCharacteristicA[2, x], MathieuCharacteristicA[1, x]}, {x, -10, 10}]

Plot the MathieuCharacteristicA function for noninteger parameters:

Wolfram Language code: Plot[{MathieuCharacteristicA[1 / 7, x], MathieuCharacteristicA[1 / 3, x], MathieuCharacteristicA[1 / 2, x]}, {x, -1, 1}]

Plot the real part of MathieuCharacteristicA:

Wolfram Language code: ComplexContourPlot[Re[MathieuCharacteristicA[10, z]], {z, -4 - 4I, 4 + 4I}, IconizedObject[«PlotOptions»]]

Plot the imaginary part of MathieuCharacteristicA:

Wolfram Language code: ComplexContourPlot[Im[MathieuCharacteristicA[10, z]], {z, -4 - 4I, 4 + 4I}, IconizedObject[«PlotOptions»]]

Function Properties  (7)

The real domain of MathieuCharacteristicA:

Wolfram Language code: FunctionDomain[MathieuCharacteristicA[r, x], x]

Approximate function range of TemplateBox[{1, x}, MathieuCharacteristicA]:

Wolfram Language code: FunctionRange[MathieuCharacteristicA[1, x], x, y]//Quiet

TemplateBox[{1, x}, MathieuCharacteristicA] is a continuous function of :

Wolfram Language code: FunctionContinuous[MathieuCharacteristicA[r, x], x, Assumptions -> r∈Reals]

TemplateBox[{1, x}, MathieuCharacteristicA] is neither non-increasing nor non-decreasing:

Wolfram Language code: FunctionMonotonicity[MathieuCharacteristicA[1, x], x]

TemplateBox[{1, x}, MathieuCharacteristicA] is not injective:

Wolfram Language code: FunctionInjective[MathieuCharacteristicA[1, x], x]
Wolfram Language code: Plot[{MathieuCharacteristicA[1, x], 1}, {x, -3, 7}]

MathieuCharacteristicA threads elementwise over lists:

Wolfram Language code: MathieuCharacteristicA[{1, 2, 3, 4, 5}, 0.33]

TraditionalForm formatting:

Wolfram Language code: TraditionalForm[MathieuCharacteristicA[r, x]]

Series Expansions  (2)

Find the Taylor expansion using Series:

Wolfram Language code: Series[MathieuCharacteristicA[1, q], {q, 0, 3}]

Plots of the first three approximations around :

Wolfram Language code: terms = Normal@Table[Series[MathieuCharacteristicA[1, q], {q, 0, m}], {m, 1, 5, 2}]; Plot[{MathieuCharacteristicA[1, q], terms}//Evaluate, {q, -7, 7}, PlotRange -> {-7, 7}]

Find the series expansion at infinity:

Wolfram Language code: Series[MathieuCharacteristicA[4 / 3, q], {q, ∞, 3}]

Applications  (4)

Symmetric periodic solutions of the Mathieu differential equation:

Wolfram Language code: Plot[Evaluate[Table[MathieuC[MathieuCharacteristicA[r, 2], 2, x], {r, 3}]], {x, -6, 6}]

This shows the stability diagram for the Mathieu equation:

Wolfram Language code: Plot[Evaluate[Flatten[Table[{MathieuCharacteristicA[r, q], MathieuCharacteristicB[r + 1, q]}, {r, 0, 4}]]], {q, 0, 20}, Filling -> Table[i -> {i + 1}, {i, 1, 10, 2}]]

As a function of the first argument, MathieuCharacteristicA is a piecewise continuous function (called bands and band gaps in solid state physics):

Wolfram Language code: Plot[MathieuCharacteristicA[r, 1], {r, -2.5, 2.5}]

Solve the Laplace equation in an ellipse using separation of variables:

Wolfram Language code: ellipseψ[n_, z0_][r_, f_] := With[{ch = MathieuCharacteristicA[n, z0]}, MathieuC[ch, z0, I r]MathieuC[ch, z0, f]]

This finds a zero:

Wolfram Language code: FindRoot[MathieuC[MathieuCharacteristicA[5, q], q, I / 2], {q, 20}, WorkingPrecision -> 25]

This plots an eigenfunction. It vanishes at the ellipse boundary:

Wolfram Language code: ParametricPlot3D[{Cosh[r] Cos[f], Sinh[r] Sin[f], ellipseψ[5, q /. %][r, f]}, {r, 0, 1 / 2}, {f, 0, 2Pi}, Mesh -> False]

Properties & Relations  (1)

MathieuCharacteristicA is a special case of SpheroidalEigenvalue:

Wolfram Language code: SpheroidalEigenvalue[n, 1 / 2, c]

Neat Examples  (1)

Branch points of the Mathieu characteristic along the imaginary q axis:

Wolfram Language code: Plot[Evaluate[Table[Re[MathieuCharacteristicA[i, I q]], {i, 0, 9}]], {q, 0, 30}]
Wolfram Research (1996), MathieuCharacteristicA, Wolfram Language function, https://reference.wolfram.com/language/ref/MathieuCharacteristicA.html.

Text

Wolfram Research (1996), MathieuCharacteristicA, Wolfram Language function, https://reference.wolfram.com/language/ref/MathieuCharacteristicA.html.

CMS

Wolfram Language. 1996. "MathieuCharacteristicA." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/MathieuCharacteristicA.html.

APA

Wolfram Language. (1996). MathieuCharacteristicA. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/MathieuCharacteristicA.html

BibTeX

@misc{reference.wolfram_2026_mathieucharacteristica, author="Wolfram Research", title="{MathieuCharacteristicA}", year="1996", howpublished="\url{https://reference.wolfram.com/language/ref/MathieuCharacteristicA.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_mathieucharacteristica, organization={Wolfram Research}, title={MathieuCharacteristicA}, year={1996}, url={https://reference.wolfram.com/language/ref/MathieuCharacteristicA.html}, note=[Accessed: 12-June-2026]}