MathieuC
MathieuC[a,q,z]
gives the even Mathieu function with characteristic value a and parameter q.
Details
- Mathematical function, suitable for both symbolic and numerical manipulation.
- The Mathieu functions satisfy the equation
. - For certain special arguments, MathieuC automatically evaluates to exact values.
- MathieuC can be evaluated to arbitrary numerical precision.
- MathieuC automatically threads over lists.
Examples
open all close allBasic Examples (4)
MathieuC[2, 1, 3.2]Plot over a subset of the reals:
Plot[MathieuC[3, 2, x], {x, -4, 4}]Plot over a subset of the complexes:
ComplexPlot3D[MathieuC[3, 1, z], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]Series expansion about the origin:
Series[MathieuC[3, 2, z], {z, 0, 4}]Scope (21)
Numerical Evaluation (5)
Evaluate numerically to high precision:
N[MathieuC[2, 1, 37 / 10], 50]The precision of the output tracks the precision of the input:
MathieuC[2, 1, 3.70000000000000000000000000000000]Evaluate for complex arguments and parameters:
MathieuC[I, -2, 2.5 + I]Evaluate MathieuC efficiently at high precision:
MathieuC[2, 1, 3.7`500]//TimingMathieuC[2, 1, 3.7`10000];//TimingMathieuC threads elementwise over lists:
MathieuC[a, q, {z1, z2, z3}]Compute the elementwise values of an array:
MathieuC[1, 0, {{-π / 2, 0}, {0, π / 4}}]Or compute the matrix MathieuC function using MatrixFunction:
MatrixFunction[MathieuC[1, 0, #]&, {{-π / 2, 0}, {0, π / 4}}]Specific Values (4)
Simple exact values are generated automatically:
MathieuC[a, 0, z]Find a local maximum as the root of 
in the maximum's neighborhood:
xmax = FindRoot[D[MathieuC[3, 2, x], x] == 0, {x, 0.5}][[1, 2]]Plot[MathieuC[3, 2, x], {x, -3, 3}, Epilog -> Style[Point[{xmax, MathieuC[3, 2, xmax]}], PointSize[Large], Red]]MathieuC is an even function:
MathieuC[a, q, -x]Heun functions can be reduced to Mathieu functions:
HeunC[q, alpha, 1 / 2, 1 / 2, 0, z] == MathieuC[-2 alpha + 4 q, -alpha, ArcSin[Sqrt[z]]] / MathieuC[-2 alpha + 4 q, -alpha, 0]Visualization (3)
Plot the MathieuC function:
Plot[{MathieuC[3, -2, x], MathieuC[2, 1, x], MathieuC[1, 0, x]}, {x, -5, 5}]Plot the real part of MathieuC for 
and 
:
ComplexContourPlot[Re[MathieuS[2, 1, z]], {z, -π - 2I, π + 2I}, Contours -> 24, PlotLabel -> {"Re(MathieuC[2,1,z])"}, FrameTicks -> {{Automatic, None}, {{-π, 0, π}, None}}]Plot the imaginary part of MathieuC for 
and 
:
ComplexContourPlot[Im[MathieuC[2, 1, z]], {z, -π / 2 - 2I, π / 2 + 2I}, IconizedObject[«PlotOptions»]]Plot the real part of MathieuC for 
and 
:
ComplexContourPlot[Im[MathieuC[3, -2, z]], {z, -π / 2 - 2I, π / 2 + 2I}, IconizedObject[«PlotOptions»]]Plot the imaginary part of MathieuC for 
and 
:
ComplexContourPlot[Im[MathieuC[3, -2, z]], {z, -π / 2 - 2I, π / 2 + 2I}, IconizedObject[«PlotOptions»]]Function Properties (4)
MathieuC has singularities and discontinuities when the characteristic exponent is an integer:
FunctionSingularities[MathieuC[a, q, z], {a, q, z}]//QuietFunctionDiscontinuities[MathieuC[a, q, z], {a, q, z}]//Quiet
is neither nondecreasing nor nonincreasing:
FunctionMonotonicity[MathieuC[3, 2, x], x]MathieuC is neither non-negative nor non-positive:
FunctionSign[MathieuC[a, q, x], {a, q, x}]MathieuC is neither convex nor concave:
FunctionConvexity[MathieuC[a, q, x], {a, q, x}]Differentiation (3)
D[MathieuC[a, q, x], x]derivs = Table[D[MathieuC[a, q, x], {x, n}], {n, 1, 4}]Plot higher derivatives for 
and 
:
Plot[Evaluate[derivs /. {a -> 3, q -> 2}], {x, -2, 2}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]Plot higher derivatives for 
and 
:
Plot[Evaluate[derivs /. {a -> 3, q -> -2}], {x, -2, 2}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]Mathieu functions are the solutions to the differential equation 
:
DSolve[D[y[x], {x, 2}] + (a - 2 q Cos[2 x]) y[x] == 0, y, x]Series Expansions (2)
Series[MathieuC[3, 2, x], {x, 0, 8}]Plot the first three approximations for MathieuC around 
:
terms = Normal@Table[Series[MathieuC[3, 2, x], {x, 0, m}], {m, 2, 6, 2}];
Plot[{MathieuC[3, 2, x], terms}, {x, -1.5, 1.5}]Taylor expansion of MathieuC at a generic point:
Series[MathieuC[a, q, x], {x, x0, 2}]Applications (3)
This differential equation is solved in terms of MathieuC and MathieuS functions:
DSolve[(b + a x) y[x] + (-1 + 2 x) Derivative[1][y][x] + 2 (-1 + x) x Derivative[2][y][x] == 0, y[x], x]Solve the Schrödinger equation with periodic potential:
DSolve[-y''[x] + Cos[x]y[x] == ℰ y[x], y[x], x]By the Bloch theorem, solutions are bounded provided 
is within an energy band. The energy gap corresponds to a range of 
where MathieuCharacteristicExponent has a non-vanishing imaginary part:
Plot[{ArcTan[Re[MathieuC[a, 2, 100]]], Im[MathieuCharacteristicExponent[a, 2]]}, {a, 2, 8}, WorkingPrecision -> 16, PlotStyle -> {{Dashing[Tiny]}, {Thick}}]Solve the Laplace equation in an ellipse using separation of variables:
ellipseψ[n_, z0_][r_, f_] := With[{ch = MathieuCharacteristicA[n, z0]}, MathieuC[ch, z0, I r]MathieuC[ch, z0, f]]FindRoot[MathieuC[MathieuCharacteristicA[5, q], q, I / 2], {q, 20}, WorkingPrecision -> 25]This plots an eigenfunction. It vanishes at the ellipse boundary:
ParametricPlot3D[{Cosh[r] Cos[f], Sinh[r] Sin[f], ellipseψ[5, q /. %][r, f]}, {r, 0, 1 / 2}, {f, 0, 2Pi}, Mesh -> False]Possible Issues (1)
Related Links
MathWorld
The Wolfram Functions Site
NKS|OnlineText
Wolfram Research (1996), MathieuC, Wolfram Language function, https://reference.wolfram.com/language/ref/MathieuC.html.
CMS
Wolfram Language. 1996. "MathieuC." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/MathieuC.html.
APA
Wolfram Language. (1996). MathieuC. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/MathieuC.html