WOLFRAM

Wolfram Language & System Documentation Center

MeyerWavelet[]

represents the Meyer wavelet of order 3.

MeyerWavelet[n]

represents the Meyer wavelet of order n evaluated on the equally spaced interval {-10,10}.

MeyerWavelet[n,lim]

represents the Meyer wavelet of order n evaluated on the equally spaced interval {-lim,lim}.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Basic Uses  
Wavelet Transforms  
Higher Dimensions  
Properties & Relations  
Neat Examples  
See Also
Tech Notes
Related Guides
History
Cite this Page

MeyerWavelet

MeyerWavelet[]

represents the Meyer wavelet of order 3.

MeyerWavelet[n]

represents the Meyer wavelet of order n evaluated on the equally spaced interval {-10,10}.

MeyerWavelet[n,lim]

represents the Meyer wavelet of order n evaluated on the equally spaced interval {-lim,lim}.

Details

  • MeyerWavelet defines a family of orthonormal wavelets.
  • MeyerWavelet[n] is equivalent to MeyerWavelet[n,8].
  • MeyerWavelet[n,lim] is defined for any positive integer n and real limit lim.
  • The scaling function () and wavelet function () have infinite support. The functions are symmetric.
  • The scaling function () is given by its Fourier transform as 1 TemplateBox[{omega}, Abs]<=(2 pi)/3; cos(1/2 pi nu((3 TemplateBox[{omega}, Abs])/(2 pi)-1)) (2 pi)/3<=TemplateBox[{omega}, Abs]<=(4 pi)/3. »
  • The wavelet function () is given by its Fourier transform as exp((ⅈ omega)/2) sin(pi/2 nu((3 TemplateBox[{omega}, Abs])/(2 pi)-1)) (2 pi)/3<=TemplateBox[{omega}, Abs]<=(4 pi)/3; exp((ⅈ omega)/2) cos(pi/2 nu((3 TemplateBox[{omega}, Abs])/(4 pi)-1)) (4 pi)/3<=TemplateBox[{omega}, Abs]<=(8 pi)/3.
  • The polynomial is a polynomial of the form , where is the order of the Meyer wavelet.
  • MeyerWavelet can be used with such functions as DiscreteWaveletTransform and WaveletPhi, etc.

Examples

open all close all

Basic Examples  (3)

Scaling function:

Wolfram Language code: Plot[Evaluate[WaveletPhi[MeyerWavelet[3], x]], {x, -8, 8}, PlotRange -> All]
Wolfram Language code: WaveletPhi[MeyerWavelet[3], x]

Wavelet function:

Wolfram Language code: Plot[Evaluate[WaveletPsi[MeyerWavelet[3], x]], {x, -8, 8}, PlotRange -> All]
Wolfram Language code: WaveletPsi[MeyerWavelet[3], x]

Filter coefficients:

Wolfram Language code: WaveletFilterCoefficients[MeyerWavelet[3, 5], {"PrimalLowpass", "PrimalHighpass"}]

Scope  (9)

Basic Uses  (4)

Compute primal lowpass filter coefficients:

Wolfram Language code: WaveletFilterCoefficients[MeyerWavelet[3], "PrimalLowpass"]

Primal highpass filter coefficients:

Wolfram Language code: WaveletFilterCoefficients[MeyerWavelet[3], "PrimalHighpass"]

Meyer scaling function of order 3:

Wolfram Language code: Plot[Evaluate[WaveletPhi[MeyerWavelet[3], x]], {x, -10, 10}, PlotRange -> All]

Meyer scaling function of order 10:

Wolfram Language code: Plot[Evaluate[WaveletPhi[MeyerWavelet[10], x]], {x, -10, 10}, PlotRange -> All]

Meyer wavelet function of order 3:

Wolfram Language code: Plot[Evaluate[WaveletPsi[MeyerWavelet[3], x]], {x, -10, 10}, PlotRange -> All]

Meyer wavelet function of order 10:

Wolfram Language code: Plot[Evaluate[WaveletPsi[MeyerWavelet[10], x]], {x, -10, 10}, PlotRange -> All]

Wavelet Transforms  (4)

Compute a DiscreteWaveletTransform:

Wolfram Language code: data = Table[Sinc[x^2], {x, -3 π, 3 π, (6 π/1023)}];
Wolfram Language code: ListLinePlot[data, PlotRange -> All]
Wolfram Language code: dwt = DiscreteWaveletTransform[data, MeyerWavelet[3, 12], 2]

View the tree of wavelet coefficients:

Wolfram Language code: dwt["TreeView"]

Get the dimensions of wavelet coefficients:

Wolfram Language code: dwt["Dimensions"]

Plot the wavelet coefficients:

Wolfram Language code: WaveletListPlot[dwt, PlotLayout -> "CommonXAxis"]

MeyerWavelet can be used to perform a DiscreteWaveletPacketTransform:

Wolfram Language code: data = Table[Sinc[t^2], {t, -3 π, 3 π, (6 π/1023)}];
Wolfram Language code: dwpt = DiscreteWaveletPacketTransform[data, MeyerWavelet[3, 12], 2]

View the tree of wavelet coefficients:

Wolfram Language code: dwpt["TreeView"]

Get the dimensions of wavelet coefficients:

Wolfram Language code: dwpt["Dimensions"]

Plot the wavelet coefficients:

Wolfram Language code: WaveletListPlot[dwpt, PlotLayout -> "CommonXAxis"]

MeyerWavelet can be used to perform a StationaryWaveletTransform:

Wolfram Language code: data = Table[Sinc[t^2], {t, -3 π, 3 π, (6 π/1023)}];
Wolfram Language code: swt = StationaryWaveletTransform[data, MeyerWavelet[3, 12], 2];

View the tree of wavelet coefficients:

Wolfram Language code: swt["TreeView"]

Get the dimensions of wavelet coefficients:

Wolfram Language code: swt["Dimensions"]

Plot the wavelet coefficients:

Wolfram Language code: WaveletListPlot[swt, PlotLayout -> "CommonXAxis"]

MeyerWavelet can be used to perform a StationaryWaveletPacketTransform:

Wolfram Language code: data = Table[Sinc[t^2], {t, -3 π, 3 π, (6 π/1023)}];
Wolfram Language code: swpt = StationaryWaveletPacketTransform[data, MeyerWavelet[3, 12], 2];

View the tree of wavelet coefficients:

Wolfram Language code: swpt["TreeView"]

Get the dimensions of wavelet coefficients:

Wolfram Language code: swpt["Dimensions"]

Plot the wavelet coefficients:

Wolfram Language code: WaveletListPlot[swpt, PlotLayout -> "CommonXAxis"]

Higher Dimensions  (1)

Multivariate scaling and wavelet functions are products of univariate ones:

Wolfram Language code: ϕ = WaveletPhi[MeyerWavelet[3, 8]]; ψ = WaveletPsi[MeyerWavelet[3, 8]];
Wolfram Language code: Plot3D[Evaluate[ϕ[x] ψ[y]], {x, -8, 8}, {y, -8, 8}, PlotRange -> All, ColorFunction -> "SolarColors", Mesh -> None, Axes -> None]
Wolfram Language code: Plot3D[Evaluate[ϕ[x] ψ[y]], {x, -8, 8}, {y, -8, 8}, PlotRange -> All, ColorFunction -> "SolarColors", Mesh -> None, Axes -> None]
Wolfram Language code: Plot3D[Evaluate[ψ[x] ϕ[y]], {x, -8, 8}, {y, -8, 8}, PlotRange -> All, ColorFunction -> "SolarColors", Mesh -> None, Axes -> None]
Wolfram Language code: Plot3D[Evaluate[ψ[x] ψ[y]], {x, -8, 8}, {y, -8, 8}, PlotRange -> All, ColorFunction -> "SolarColors", Mesh -> None, Axes -> None]

Properties & Relations  (10)

Lowpass filter coefficients approximately sum to unity; :

Wolfram Language code: Chop[Total[WaveletFilterCoefficients[MeyerWavelet[3, 20], "PrimalLowpass"][[All, 2]]]]

Highpass filter coefficients approximately sum to zero; :

Wolfram Language code: Chop[Total[WaveletFilterCoefficients[MeyerWavelet[3, 20], "PrimalHighpass"][[All, 2]]]]

Scaling function integrates to unity; :

Wolfram Language code: ϕ = WaveletPhi[MeyerWavelet[3]];
Wolfram Language code: Subsuperscript[∫, -∞, ∞]ϕ[x]ⅆx

Wavelet function integrates to zero; :

Wolfram Language code: ψ = WaveletPsi[MeyerWavelet[3, 20]];
Wolfram Language code: NIntegrate[ψ[x], {x, -∞, ∞}]

satisfies the recursion equation :

Wolfram Language code: ϕ = WaveletPhi[MeyerWavelet[3]];
Wolfram Language code: a = WaveletFilterCoefficients[MeyerWavelet[3], "PrimalLowpass"];

Plot the components and the sum of the recursion:

Wolfram Language code: scalet[x_, ϕ_, a_] := 2 Table[a[[i, 2]] ϕ[2 x - a[[i, 1]]], {i, Length[a]}]
Wolfram Language code: {Plot[Evaluate[scalet[x, ϕ, a]], {x, -8, 8}, PlotRange -> All], Plot[Total[scalet[x, ϕ, a]], {x, -8, 8}, PlotRange -> All]}

satisfies the recursion equation :

Wolfram Language code: ϕ = WaveletPhi[MeyerWavelet[3]];
Wolfram Language code: b = WaveletFilterCoefficients[MeyerWavelet[3], "PrimalHighpass"];

Plot the components and the sum of the recursion:

Wolfram Language code: wavelet[x_, ϕ_, b_] := 2 Table[b[[i, 2]] ϕ[2 x - b[[i, 1]]], {i, Length[b]}]
Wolfram Language code: {Plot[Evaluate[wavelet[x, ϕ, b]], {x, -8, 8}, PlotRange -> All], Plot[Total[wavelet[x, ϕ, b]], {x, -8, 8}, PlotRange -> All]}

Frequency response for is given by :

Wolfram Language code: h[wav_, ω_] := With[{a = WaveletFilterCoefficients[wav]}, Underoverscript[∑, i, Length[a]]a[[i, 2]] Exp[-I a[[i, 1]] ω]]

The filter is a lowpass filter:

Wolfram Language code: Plot[Evaluate[Abs[h[MeyerWavelet[3, 20], ω]]], {ω, -π, π}, Ticks -> {{-π, -(π/2), 0, (π/2), π}, Automatic}, AxesLabel -> {ω, Abs[H[ω]]}]

Frequency response for is given by :

Wolfram Language code: g[wav_, ω_] := With[{b = WaveletFilterCoefficients[wav, "PrimalHighpass"]}, Underoverscript[∑, i, Length[b]]b[[i, 2]] Exp[-I b[[i, 1]] ω]]

The filter is a highpass filter:

Wolfram Language code: Plot[Evaluate[Abs[g[MeyerWavelet[3, 20], ω]]], {ω, -π, π}, Ticks -> {{-π, -(π/2), 0, (π/2), π}, Automatic}, AxesLabel -> {ω, Abs[G[ω]]}]

Fourier transform of is given by :

Wolfram Language code: h[wav_, ω_] := With[{a = WaveletFilterCoefficients[wav]}, Underoverscript[∑, i, Length[a]]a[[i, 2]] Exp[-I a[[i, 1]] ω]]
Wolfram Language code: fh[wav_, ω_, j_] := Abs[Underoverscript[∏, i, j]h[wav, (ω/2^i)]]
Wolfram Language code: Plot[Evaluate[fh[MeyerWavelet[3, 20], ω, 10]], {ω, -2 π, 2 π}, PlotRange -> All, Ticks -> {Range[-2 π, 2 π, (2 π/3)], {1}}, AxesLabel -> {ω, Overscript[ϕ, ^ ][ω]}]

Compare the above result with the exact Fourier transform:

Wolfram Language code: phihat[n_, ω_] := Piecewise[{{1, Abs[ω] ≤ (2 π/3)}, {Cos[(1/2) π ν[n, (3 Abs[ω]/2 π) - 1]], (2 π/3) ≤ Abs[ω] ≤ (4 π/3)}}]
Wolfram Language code: νcoeff[n_, l_] := (Underoverscript[∑, k = Ceiling[(l - 1/2)], n]((Binomial[n, k] Binomial[2 k + 1, l] 2^l (-1)^k + l - 1) (2 n + 1)!!/2 k + 1)/2 (2 n)!!)
Wolfram Language code: ν[n_, x_] := Piecewise[{{0, x ≤ 0}, {Underoverscript[∑, l = n + 1, 2 n + 1]νcoeff[n, l] x^l, 0 ≤ x ≤ 1}, {1, x ≥ 1}}]
Wolfram Language code: Plot[Abs[phihat[3, ω]], {ω, -2 π, 2 π}, PlotRange -> All, AxesLabel -> {ω, Overscript[ϕ, ^ ][ω]}, Ticks -> {Range[-2 π, 2 π, (2 π/3)], {1}}]

Fourier transform of is given by :

Wolfram Language code: h[wav_, ω_] := With[{a = WaveletFilterCoefficients[wav]}, Underoverscript[∑, i, Length[a]]a[[i, 2]] Exp[-I a[[i, 1]] ω]]
Wolfram Language code: g[wav_, ω_] := With[{b = WaveletFilterCoefficients[wav, "PrimalHighpass"]}, Underoverscript[∑, i, Length[b]]b[[i, 2]] Exp[-I b[[i, 1]] ω]]
Wolfram Language code: fg[wav_, ω_, j_] := Abs[g[wav, (ω/2)] Underoverscript[∏, i = 2, j]h[wav, (ω/2^i)]]
Wolfram Language code: Plot[Evaluate[fg[MeyerWavelet[3, 20], ω, 10]], {ω, -10, 10}, PlotRange -> All, AxesLabel -> {ω, Abs[Overscript[ψ, ^ ][ω]]}]

Compare the above result with the exact Fourier transform:

Wolfram Language code: phihat[n_, ω_] := Piecewise[{{1, Abs[ω] ≤ (2 π/3)}, {Cos[(1/2) π ν[n, (3 Abs[ω]/2 π) - 1]], (2 π/3) ≤ Abs[ω] ≤ (4 π/3)}}]
Wolfram Language code: νcoeff[n_, l_] := (Underoverscript[∑, k = Ceiling[(l - 1/2)], n]((Binomial[n, k] Binomial[2 k + 1, l] 2^l (-1)^k + l - 1) (2 n + 1)!!/2 k + 1)/2 (2 n)!!)
Wolfram Language code: ν[n_, x_] := Piecewise[{{0, x ≤ 0}, {Underoverscript[∑, l = n + 1, 2 n + 1]νcoeff[n, l] x^l, 0 ≤ x ≤ 1}, {1, x ≥ 1}}]
Wolfram Language code: psihat[n_Integer, w_] := Exp[(I w/2)] (phihat[n, w + 2 π] + phihat[n, w - 2 π]) phihat[n, (w/2)]
Wolfram Language code: Plot[Abs[psihat[3, ω]], {ω, -10, 10}, PlotRange -> All, AxesLabel -> {ω, Abs[Overscript[ψ, ^ ][ω]]}]

Neat Examples  (2)

Plot translates and dilations of scaling function:

Wolfram Language code: ϕ[x_, j_, k_] := 2^j / 2 WaveletPhi[MeyerWavelet[3], 2^j x - k]
Wolfram Language code: Plot[Evaluate[Table[ϕ[x, j, 0], {j, 0, 2}]], {x, -1, 1}, Filling -> Axis, PlotRange -> All]
Wolfram Language code: Plot[Evaluate[Table[ϕ[x, 2, k], {k, 0, 2^2 - 1}]], {x, -1, 2}, Filling -> Axis, PlotRange -> All]

Plot translates and dilations of wavelet function:

Wolfram Language code: ψ[x_, j_, k_] := 2^j / 2 WaveletPsi[MeyerWavelet[3], 2^j x - k]
Wolfram Language code: Plot[Evaluate[Table[ψ[x, j, 0], {j, 0, 2}]], {x, -0.5, 1}, Filling -> Axis, PlotRange -> All]
Wolfram Language code: Plot[Evaluate[Table[ψ[x, 2, k], {k, 0, 2^2 - 1}]], {x, -0.5, 1.5}, Filling -> Axis, PlotRange -> All]
Wolfram Research (2010), MeyerWavelet, Wolfram Language function, https://reference.wolfram.com/language/ref/MeyerWavelet.html.

Text

Wolfram Research (2010), MeyerWavelet, Wolfram Language function, https://reference.wolfram.com/language/ref/MeyerWavelet.html.

CMS

Wolfram Language. 2010. "MeyerWavelet." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/MeyerWavelet.html.

APA

Wolfram Language. (2010). MeyerWavelet. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/MeyerWavelet.html

BibTeX

@misc{reference.wolfram_2026_meyerwavelet, author="Wolfram Research", title="{MeyerWavelet}", year="2010", howpublished="\url{https://reference.wolfram.com/language/ref/MeyerWavelet.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_meyerwavelet, organization={Wolfram Research}, title={MeyerWavelet}, year={2010}, url={https://reference.wolfram.com/language/ref/MeyerWavelet.html}, note=[Accessed: 12-June-2026]}