WOLFRAM

Wolfram Language & System Documentation Center

Ordering[list]

gives the positions in list at which each successive element of Sort[list] appears.

Ordering[list,n]

gives the positions in list at which the first n elements of Sort[list] appear.

Ordering[list,-n]

gives the positions of the last n elements of Sort[list].

Ordering[list,n,p]

gives positions in list of elements of Sort[list,p].

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Generalizations & Extensions  
Applications  
Properties & Relations  
See Also
Tech Notes
Related Guides
History
Cite this Page

Ordering

Ordering[list]

gives the positions in list at which each successive element of Sort[list] appears.

Ordering[list,n]

gives the positions in list at which the first n elements of Sort[list] appear.

Ordering[list,-n]

gives the positions of the last n elements of Sort[list].

Ordering[list,n,p]

gives positions in list of elements of Sort[list,p].

Details

  • In a numerical list, Ordering[list,n] gives the positions of the n smallest elements. Ordering[list,-n] gives the positions of the n largest elements.
  • If there are several smallest elements in list, Ordering[list,1] will give only the position of the one that appears first.
  • list[[Ordering[list]]] is the same as Sort[list].
  • Ordering[list,seq] is equivalent to Take[Ordering[list],seq].
  • Ordering[list,UpTo[n]] returns n positions, or as many as are available.
  • Ordering[list,All,p] gives the position at which all elements of list appear in Sort[list,p].
  • Ordering can be used on expressions with any head, not only List.

Examples

open all close all

Basic Examples  (4)

Find the ordering that sorts a list:

Wolfram Language code: Ordering[{c, a, b}]

Apply the ordering:

Wolfram Language code: {c, a, b}[[{2, 3, 1}]]

Find the positions of the 4 smallest elements in a list:

Wolfram Language code: Ordering[{2, 6, 1, 9, 1, 2, 3}, 4]

Find the position of the largest element:

Wolfram Language code: Ordering[{2, 6, 1, 9, 1, 2, 3}, -1]

Find the ordering of values in an Association:

Wolfram Language code: Ordering[<|1 -> c, 2 -> a, 3 -> b|>]

Scope  (4)

Find positions of elements from the 4^(th) smallest to the largest:

Wolfram Language code: Ordering[{2, 6, 1, 9, 1, 2, 3}, {4, -1}]

Find positions of elements in Sort[list,Greater]:

Wolfram Language code: Ordering[{2, 6, 1, 9, 1, 2, 3}, All, Greater]
Wolfram Language code: Sort[{2, 6, 1, 9, 1, 2, 3}, Greater]

Find the positions of the 6 smallest elements in a list, or as many as are available:

Wolfram Language code: Ordering[{2, 6, 1, 9, 2}, UpTo[6]]

Find the ordering of rows in a Tabular object:

Wolfram Language code: Tabular[{{1, 2}, {2, 1}, {0, 4}}, {"a", "b"}]
Wolfram Language code: Ordering[%]

Generalizations & Extensions  (1)

Use expressions with any head:

Wolfram Language code: Ordering[f[3, 1, 2]]

Applications  (3)

Find a permutation that sorts a list:

Wolfram Language code: Ordering[{2, 6, 1, 9, 1, 2, 3}]

Apply the permutation:

Wolfram Language code: {2, 6, 1, 9, 1, 2, 3}[[%]]

Find the inverse of a permutation:

Wolfram Language code: Ordering[{4, 5, 1, 2, 3}]
Wolfram Language code: {b, c, a, d, e}[[{4, 5, 1, 2, 3}]]
Wolfram Language code: %[[{3, 4, 5, 1, 2}]]

Sort a list of lists with respect to a particular position:

Wolfram Language code: sll[ll_, elem_] := ll[[Ordering[ll[[All, elem]]]]]
Wolfram Language code: sll[{{1, 2, 3}, {4, 5, 6}, {5, 4, 3}, {9, 5, 1}}, 2]

The same as Sort, but Ordering keeps the original ordering when elements are the same:

Wolfram Language code: Sort[{{1, 2, 3}, {4, 5, 6}, {5, 4, 3}, {9, 5, 1}}, (#1[[2]] < #2[[2]])&]

Using Ordering this way is much faster for large sets of lists:

Wolfram Language code: data = RandomInteger[9, {10 ^ 5, 4}];
Wolfram Language code: First /@ {Timing[sll[data, 3];], Timing[Sort[data, (#1[[2]] < #2[[2]])&]]}

Properties & Relations  (2)

Find the position of the maximum element:

Wolfram Language code: Ordering[{4, 5, -2, 3}, -1]
Wolfram Language code: Position[{4, 5, -2, 3}, Max[{4, 5, -2, 3}]]

list[[Ordering[list]]] is equivalent to Sort[list]:

Wolfram Language code: list = RandomInteger[47, 13];
Wolfram Language code: Sort[list]
Wolfram Language code: list[[Ordering[list]]]
Wolfram Research (2000), Ordering, Wolfram Language function, https://reference.wolfram.com/language/ref/Ordering.html (updated 2015).

Text

Wolfram Research (2000), Ordering, Wolfram Language function, https://reference.wolfram.com/language/ref/Ordering.html (updated 2015).

CMS

Wolfram Language. 2000. "Ordering." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2015. https://reference.wolfram.com/language/ref/Ordering.html.

APA

Wolfram Language. (2000). Ordering. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Ordering.html

BibTeX

@misc{reference.wolfram_2026_ordering, author="Wolfram Research", title="{Ordering}", year="2015", howpublished="\url{https://reference.wolfram.com/language/ref/Ordering.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_ordering, organization={Wolfram Research}, title={Ordering}, year={2015}, url={https://reference.wolfram.com/language/ref/Ordering.html}, note=[Accessed: 13-June-2026]}