Greater
Details
- Greater is also known as strong inequality or strict inequality.
- Greater gives True or False when its arguments are real numbers.
- Greater does some simplification when its arguments are not numbers.
- For exact numeric quantities, Greater internally uses numerical approximations to establish numerical ordering. This process can be affected by the setting of the global variable $MaxExtraPrecision.
Examples
open all close allBasic Examples (2)
Scope (9)
Numeric Inequalities (7)
Inequalities are defined only for real numbers:
I > 0
3 / 2 > 4 / 3Approximate numbers that differ in at most their last eight binary digits are considered equal:
1. > 1. - 2 ^ 7 10 ^ -161. > 1. - 2 ^ 8 10 ^ -16Compare an exact numeric expression and an approximate number:
N[Pi, 20] > PiN[Pi, 20] > Pi(1 - 2 ^ 8 10 ^ -20)Compare two exact numeric expressions; a numeric test may suffice to prove inequality:
E ^ Pi > Pi ^ EProving this inequality requires symbolic methods:
Sqrt[2] + Sqrt[3] > Sqrt[5 + 2Sqrt[6]]Symbolic and numeric methods used by Greater are insufficient to disprove this inequality:
Sqrt[2] + Sqrt[3] > Root[# ^ 4 - 10# ^ 2 + 1&, 4]
Use RootReduce to decide the sign of algebraic numbers:
RootReduce[%[[1]] - %[[2]]] > 0Numeric methods used by Greater do not use sufficient precision to prove this inequality:
Sqrt[2] + Sqrt[3] > Root[# ^ 4 - 10# ^ 2 + 1&, 4] - 10 ^ -100
RootReduce proves the inequality using exact methods:
RootReduce[%[[1]] - %[[2]]] > 0Increasing $MaxExtraPrecision may also prove the inequality:
Block[{$MaxExtraPrecision = 100}, Sqrt[2] + Sqrt[3] > Root[# ^ 4 - 10# ^ 2 + 1&, 4] - 10 ^ -100]Symbolic Inequalities (2)
Symbolic inequalities remain unevaluated, since x may not be a real number:
x > xUse Refine to reevaluate the inequality assuming that x is real:
Refine[%, Element[x, Reals]]ineq = x ^ 2 - y ^ 2 > 1Use Reduce to find an explicit description of the solution set:
Reduce[ineq, {x, y}]Use FindInstance to find a solution instance:
FindInstance[ineq, {x, y}]Use Minimize to optimize over the inequality-defined region:
Minimize[{x ^ 2, ineq}, {x, y}]
Use Refine to simplify under the inequality defined assumptions:
Refine[Sqrt[(1 - x ^ 2) ^ 2], ineq]Properties & Relations (12)
The negation of two-argument Greater is LessEqual:
Not[x > y]The negation of three-argument Greater does not simplify automatically:
Not[x > y > z]Use LogicalExpand to express the negation in terms of two-argument LessEqual:
LogicalExpand[%]This is not equivalent to three-argument LessEqual:
LogicalExpand[x ≤ y ≤ z]When Greater cannot decide inequality between numeric expressions it returns unchanged:
a = Log[Sqrt[2] + Sqrt[3]];
b = Log[5 + 2Sqrt[6]] / 2;
a > b
FullSimplify uses exact symbolic transformations to disprove the inequality:
FullSimplify[%]Positive[x] is equivalent to 
:
Positive /@ {-1, 0, 1, I}Use Reduce to solve inequalities:
Reduce[x ^ 5 - 3x + 2 > 0, x]Reduce[y ^ 2 - 4x ^ 2 + 4x ^ 4 > 0, {x, y}]Use FindInstance to find solution instances:
FindInstance[y ^ 2 - 4x ^ 2 + 4x ^ 4 > z ^ 2, {x, y, z}]Use RegionPlot and RegionPlot3D to visualize solution sets of inequalities:
RegionPlot[y ^ 2 - 4x ^ 2 + 4x ^ 4 > 0, {x, -1, 1}, {y, -1, 1}]RegionPlot3D[y ^ 2 - 4x ^ 2 + 4x ^ 4 > z ^ 2, {x, -1, 1}, {y, -1, 1}, {z, -1, 1}]Refine[Sqrt[x ^ 2], x > 0]Limit[a ^ n, n -> Infinity, Assumptions -> a > 1]Use Minimize and Maximize to solve optimization problems constrained by inequalities:
Minimize[{x - y, -y ^ 2 + 4x ^ 2 - 4x ^ 4 > 0}, {x, y}]
Use NMinimize and NMaximize to numerically solve constrained optimization problems:
NMinimize[{x - y, 2 > Tan[x] + Tan[y] > 1}, {x, y}]Integrate a function over the solution set of inequalities:
Integrate[x ^ 2 Boole[2 > x ^ 2 + y ^ 2 > 1], {x, -Infinity, Infinity}, {y, -Infinity, Infinity}]Use Median, Quantile, and Quartiles to the 
greatest number(s):
{x1, x2, x3} = {1, 2, 3};x3 > x2 > x1Median[{x2, x3, x1}]Possible Issues (3)
Inequalities for machine-precision approximate numbers can be subtle:
2.00006 - 2.00005 > 0.00001The strict inequality is based on extra digits:
2.00006 - 2.00005//InputFormArbitrary-precision approximate numbers do not have this problem:
2.00006`16 - 2.00005`16 > 0.00001`16Thanks to automatic precision tracking, Greater knows to look only at the first 10 digits:
Precision[2.00006`16 - 2.00005`16]In this case, inequality between machine numbers gives the expected result:
2.6 - 2.5 > 0.1The extra digits in this case are ignored by Greater:
2.6 - 2.5//InputForm
An Elementary Introduction to the Wolfram LanguageText
Wolfram Research (1988), Greater, Wolfram Language function, https://reference.wolfram.com/language/ref/Greater.html (updated 1996).
CMS
Wolfram Language. 1988. "Greater." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 1996. https://reference.wolfram.com/language/ref/Greater.html.
APA
Wolfram Language. (1988). Greater. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Greater.html