ParetoPickandsDistribution
ParetoPickandsDistribution[μ,σ,ξ]
gives a Pareto–Pickands distribution with location parameter μ, scale parameter σ and shape parameter ξ.
gives the standard Pareto–Pickands distribution with zero location and unit scale parameters.
Details
- The ParetoPickandsDistribution is also known as generalized Pareto distribution or GPD.
- ParetoPickandsDistribution allows σ to be any positive real number and μ and ξ to be any real numbers.
- The probability density function for value
in the generalized Pareto distribution is proportional to 
for 
and 
, and 
for 
for 
and 
. » - The survival function for value
in the generalized Pareto distribution equals 
for 
and 
, and 
for 
for 
and 
. - The hazard function for value
in the generalized Pareto distribution equals 
for 
and 
, and zero otherwise. » - ParetoPickandsDistribution can be used with such functions as Mean, CDF and RandomVariate.
Examples
open all close allBasic Examples (4)
Probability density function for the standard Pareto–Pickands distribution:
Plot[Table[PDF[ParetoPickandsDistribution[ξ], x], {ξ, {-1.5, -1, -0.6, 0, 2}}]//Evaluate, {x, -.1, 2}, Filling -> Axis]PDF[ParetoPickandsDistribution[ξ], x]Hazard function for the standard Pareto–Pickands distribution:
Plot[Table[HazardFunction[ParetoPickandsDistribution[ξ], x], {ξ, {-1.5, -1, -0.6, 0, 2}}]//Evaluate, {x, -.1, 2}, Filling -> Axis]HazardFunction[ParetoPickandsDistribution[ξ], x]Mean of the Pareto–Pickands distribution:
Mean[ParetoPickandsDistribution[μ, σ, ξ]]Standard deviation of the Pareto–Pickands distribution:
StandardDeviation[ParetoPickandsDistribution[μ, σ, ξ]]Median of the Pareto–Pickands distribution:
Median[ParetoPickandsDistribution[μ, σ, ξ]]Scope (7)
Generate a sample of pseudorandom numbers from generalized Pareto distribution:
dist = ParetoPickandsDistribution[2, 3, .07];data = RandomVariate[dist, 10 ^ 4];Compare data histogram to the population PDF:
Show[Histogram[data, Automatic, "PDF"], Plot[PDF[dist, x], {x, Min[data], Max[data]}, PlotStyle -> Thick, PlotRange -> All]]Generate a sample of pseudorandom numbers from generalized Pareto distribution:
data = RandomVariate[ParetoPickandsDistribution[-.7], 10 ^ 5];Estimate the distribution parameters from sample data:
e𝒟1 = EstimatedDistribution[data, ParetoPickandsDistribution[ξ]]e𝒟2 = EstimatedDistribution[data, ParetoPickandsDistribution[μ, σ, ξ]]Compare sample histogram with probability density functions of the estimated distribution:
Show[Histogram[data, 30, "LogPDF"], LogPlot[PDF[e𝒟1, x], {x, 0, Max[data]}, PlotRange -> All]]Skewness of the generalized Pareto distribution depends only on ξ where defined:
Plot[Skewness[ParetoPickandsDistribution[μ, σ, ξ]], {ξ, -3, 1 / 2}]Skewness[ParetoPickandsDistribution[μ, σ, ξ]]Limit[Skewness[ParetoPickandsDistribution[μ, σ, ξ]], ξ -> 1 / 3, Direction -> 1]Limit[Skewness[ParetoPickandsDistribution[μ, σ, ξ]], ξ -> -Infinity]Invert skewness as a function of the shape parameter ξ:
ξ /. Solve[Skewness[ParetoPickandsDistribution[μ, σ, ξ]] == γ, ξ, Reals]Visualize the inverse function:
Plot[%, {γ, -2, 2}]Kurtosis of Pareto–Pickands distribution only depends on the shape parameter where defined:
Kurtosis[ParetoPickandsDistribution[μ, σ, ξ]]LogPlot[%, {ξ, -2, 1 / 4}]Limit[Kurtosis[ParetoPickandsDistribution[μ, σ, ξ]], ξ -> 1 / 4, Direction -> 1]Limit[Kurtosis[ParetoPickandsDistribution[μ, σ, ξ]], ξ -> -Infinity]The minimal value of the kurtosis within the family of Pareto–Pickands distributions:
FindMinValue[Kurtosis[ParetoPickandsDistribution[μ, σ, ξ]], {ξ, 0.2}]Table of moments of Pareto–Pickands distribution:
FormulaGrid[list_, type_] := Grid[...]FormulaGrid[Table[Moment[ParetoPickandsDistribution[μ, σ, ζ], r], {r, 3}], M]Closed form for symbolic order:
Moment[ParetoPickandsDistribution[μ, σ, ξ], r]FormulaGrid[Table[CentralMoment[ParetoPickandsDistribution[μ, σ, ζ], r], {r, 3}], CM]Closed form for symbolic order:
CentralMoment[ParetoPickandsDistribution[μ, σ, ξ], r]FormulaGrid[Table[Cumulant[ParetoPickandsDistribution[μ, σ, ζ], r], {r, 3}], C]FormulaGrid[Table[FactorialMoment[ParetoPickandsDistribution[μ, σ, ζ], r], {r, 3}], FM]Quantile function of Pareto–Pickands distribution:
Plot[Table[Quantile[ParetoPickandsDistribution[xi], q], {xi, {-1.5, -1, -0.6, 0, 3}}]//Evaluate, {q, 0, 1}, Filling -> Axis]Quantile[ParetoPickandsDistribution[μ, σ, ξ], q]Consistent use of Quantity in parameters yields QuantityDistribution:
ParetoPickandsDistribution[Quantity[105, "Fahrenheit"], Quantity[15, "Fahrenheit"], 0.7]QuartileDeviation[%]Applications (2)
Model a tail of a power‐tail distribution, e.g. StudentTDistribution:
data = RandomVariate[StudentTDistribution[5], 10 ^ 5];Truncate data to the left at 
:
trData = Cases[data, x_ /; x >= 2];Fit truncated data to Pareto–Pickands distribution:
EstimatedDistribution[trData, ParetoPickandsDistribution[μ, σ, ξ]]QuantilePlot[trData, %]Generate a sample from standard Gaussian distribution:
data = RandomVariate[NormalDistribution[], 10 ^ 6];Define a function to extract 
largest elements of the sample while shifting the 
largest element to zero:
exceedance[data_, m_] := Standardize[TakeLargest[data, m], Min, 1&]Exceedance in large data samples is well described by Pareto–Pickands family of distributions:
PPlot[data_, n_] := ProbabilityPlot[exceedance[RandomSample[data, n], 4 ⌈Sqrt[n]⌉], ParetoPickandsDistribution[μ, σ, ξ], ImageSize -> Small, PlotLegends -> makeLabel[n]];
makeLabel[n_] := Placed[Row[{"n", "=", Superscript[10, Log10[n]]}], {Scaled[{0.8, 0.2}], Scaled[{0.4, 0.6}]}];Illustrate this fact with a sequence of probability plots of exceedance data against Pareto–Pickands family of distributions:
Table[PPlot[data, n], {n, {10 ^ 2, 10 ^ 4, 10 ^ 3, 10 ^ 6}}]//MulticolumnProperties & Relations (8)
Pareto–Pickands distribution family is closed under affine transformations:
TransformedDistribution[a + b x, xParetoPickandsDistribution[μ, σ, ξ], Assumptions -> b > 0]Pareto–Pickands distribution family is closed under left truncation (threshold stability):
TruncatedDistribution[{c, Infinity}, ParetoPickandsDistribution[μ, σ, ξ]]Refine the result, assuming that truncation point belongs to the support of ParetoPickandsDistribution:
Refine[%, μ < c && 1 + ξ(c - μ) > 0]Pareto–Pickands distribution with 
is equivalent to a UniformDistribution:
CDF[ParetoPickandsDistribution[μ, σ, -1], x]FullSimplify[% == CDF[UniformDistribution[{μ, μ + σ}], x], σ > 0]Pareto–Pickands distribution with 
is equivalent to a shifted ExponentialDistribution:
HazardFunction[ParetoPickandsDistribution[μ, σ, 0], x]HazardFunction[TransformedDistribution[μ + σ ℯ, ℯExponentialDistribution[1], Assumptions -> σ > 0], x]The Pareto–Pickands distribution family includes ParetoDistribution of types I and II:
Pareto𝒟[k_, α_] := ParetoPickandsDistribution[k, k / α, 1 / α]ParetoTypeII𝒟[k_, α_, μ_] := ParetoPickandsDistribution[μ, k / α, 1 / α]Check that probability density functions coincide:
PDF[Pareto𝒟[k, α], x] == PDF[ParetoDistribution[k, α], x]//Simplify[#, DistributionParameterAssumptions[ParetoDistribution[k, α]]]&PDF[ParetoTypeII𝒟[k, α, μ], x] == PDF[ParetoDistribution[k, α, μ], x]//Simplify[#, DistributionParameterAssumptions[ParetoDistribution[k, α, μ]]]&Standard Pareto–Pickands distribution with a positive shape parameter ξ is a special case of TsallisQExponentialDistribution:
gpd[xi_] := TsallisQExponentialDistribution[1 + xi, (1 + 2xi/1 + xi)]Simplify[SurvivalFunction[ParetoPickandsDistribution[ξ], x] == SurvivalFunction[gpd[ξ], x], ξ > 0 && x > 0]Standard Pareto–Pickands distributions are stochastically ordered, i.e. for any two parameters 
, cumulative distributions functions are (reverse) ordered 
for all 
:
r = {-3, -1, -0.5, 0, 1, 7};
Plot[Table[CDF[ParetoPickandsDistribution[xi], x], {xi, r}]//Evaluate, {x, 0, 0.9}, Exclusions -> None, Filling -> Table[k -> {k + 1}, {k, 5}], PlotLabels -> r]Pareto–Pickands distribution with positive shape parameter ξ occurs as a parametric mixture of ExponentialDistribution whose rate follows a GammaDistribution:
ParameterMixtureDistribution[ExponentialDistribution[λ], λGammaDistribution[1 / ξ, ξ / σ], Assumptions -> ξ > 0]Text
Wolfram Research (2019), ParetoPickandsDistribution, Wolfram Language function, https://reference.wolfram.com/language/ref/ParetoPickandsDistribution.html.
CMS
Wolfram Language. 2019. "ParetoPickandsDistribution." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/ParetoPickandsDistribution.html.
APA
Wolfram Language. (2019). ParetoPickandsDistribution. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ParetoPickandsDistribution.html