WOLFRAM

Wolfram Language & System Documentation Center

AxesLabel

is an option for graphics functions that specifies labels for axes.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Generalizations & Extensions  
Properties & Relations  
Possible Issues  
Neat Examples  
See Also
Tech Notes
Related Guides
History
Cite this Page

AxesLabel

AxesLabel

is an option for graphics functions that specifies labels for axes.

Details

  • The following settings can be used:
  • Noneno labels
    labellabel for y in 2D or z in 3D
    {lblx,lbly}labels for x and y
    {lblx,lbly,lblz}labels for x, y, and z
    Automaticlabels based on variables specified to Plot etc.
  • By default, axes labels in two-dimensional graphics are placed at the ends of the axes. In three-dimensional graphics, they are aligned with the middles of the axes.
  • Any expression can be specified as a label. It will be given by default in TraditionalForm. Arbitrary strings of text can be given as "text". »

Examples

open all close all

Basic Examples  (4)

Place a label for the axis in 2D:

Wolfram Language code: Plot[Sinc[x], {x, 0, 10}, AxesLabel -> Sinc[x]]

Place a label for the axis in 3D:

Wolfram Language code: Plot3D[Abs[x + I y], {x, -4, 4}, {y, -4, 4}, AxesLabel -> Abs[z]]

Specify a label for each axis:

Wolfram Language code: Graphics[Circle[], Axes -> True, AxesLabel -> {x, y}]

Use labels based on variables specified in Plot3D:

Wolfram Language code: Plot3D[Sin[θ ρ], {θ, 0, 3}, {ρ, 0, 3}, AxesLabel -> Automatic]

Overall style of all the label-like elements can be specified by LabelStyle:

Wolfram Language code: Plot[2Sin[x], {x, 0, 10}, AxesLabel -> {x, 2Sin[x]}, LabelStyle -> Directive[Blue, Bold]]

Scope  (2)

Labels use TraditionalForm by default:

Wolfram Language code: Plot[Sinc[x], {x, 0, 10}, AxesLabel -> Sinc[x]]

Use StandardForm instead:

Wolfram Language code: Plot[Sinc[x], {x, 0, 10}, AxesLabel -> StandardForm[Sinc[x]]]

Individually styled labels can be used together with LabelStyle, and have higher priority:

Wolfram Language code: Plot[Sin[x], {x, 0, 10}, AxesLabel -> {Style[x, Large, Bold, Red], Style[y, Large, Bold, Blue]}, LabelStyle -> Directive[Orange, Bold]]

Generalizations & Extensions  (2)

Use labels based on variables specified in Plot and Plot3D:

Wolfram Language code: Plot[Sinc[θ], {θ, 0, 10}, AxesLabel -> Automatic]

Any graphic can be used as a label:

Wolfram Language code: label = Graphics[{Text["radian", {0, -2}], Pink, Disk[{0, 0}, 1, {0, 3Pi / 2}]}, ImageSize -> 30];
Wolfram Language code: Plot[{Sin[x], Cos[x]}, {x, 0, 2Pi}, AxesLabel -> {label, None}]

Properties & Relations  (1)

The overall output format can be specified using FormatType:

Wolfram Language code: Plot[Sin[x], {x, 0, 10}, AxesLabel -> {x, Sin[x]}, FormatType -> StandardForm]

Possible Issues  (1)

When different format types are combined, the result is likely to be unpredictable:

Wolfram Language code: Plot[Sin[x], {x, 0, 10}, AxesLabel -> TraditionalForm@Sin[x], FormatType -> StandardForm]

This is equivalent to:

Wolfram Language code: StandardForm[TraditionalForm[Sin[x]]]

Neat Examples  (2)

Use 3D graphics labels:

Wolfram Language code: Plot[{Sin[x], Cos[x]}, {x, 0, 10}, AxesLabel -> {Graphics3D[Sphere[], ImageSize -> 40], Graphics3D[Cylinder[], ImageSize -> 40]}]

Use dynamic checkboxes as the axes labels:

Wolfram Language code: DynamicModule[{t = Automatic, s = Automatic}, Dynamic@Show[Plot[{Sin[x], Cos[x]}, {x, 0, 10}], AxesLabel -> {Labeled[Checkbox[Dynamic[t], {None, Automatic}], x], Labeled[Checkbox[Dynamic[s], {None, Automatic}], y]}, Ticks -> {t, s}, ImagePadding -> 40]]
Wolfram Research (1988), AxesLabel, Wolfram Language function, https://reference.wolfram.com/language/ref/AxesLabel.html (updated 2007).

Text

Wolfram Research (1988), AxesLabel, Wolfram Language function, https://reference.wolfram.com/language/ref/AxesLabel.html (updated 2007).

CMS

Wolfram Language. 1988. "AxesLabel." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2007. https://reference.wolfram.com/language/ref/AxesLabel.html.

APA

Wolfram Language. (1988). AxesLabel. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/AxesLabel.html

BibTeX

@misc{reference.wolfram_2026_axeslabel, author="Wolfram Research", title="{AxesLabel}", year="2007", howpublished="\url{https://reference.wolfram.com/language/ref/AxesLabel.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_axeslabel, organization={Wolfram Research}, title={AxesLabel}, year={2007}, url={https://reference.wolfram.com/language/ref/AxesLabel.html}, note=[Accessed: 12-June-2026]}