WOLFRAM

Wolfram Language & System Documentation Center

PoissonPDEComponent[vars,pars]

yields a Poisson PDE term with model variables vars and model parameters pars.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Applications  
See Also
Related Guides
History
Cite this Page

PoissonPDEComponent

PoissonPDEComponent[vars,pars]

yields a Poisson PDE term with model variables vars and model parameters pars.

Details

  • PoissonPDEComponent returns a sum of differential operators to be used as a part of partial differential equations:
  • PoissonPDEComponent can be used to model Poisson equations with dependent variable , independent variables and time variable .
  • Stationary model variables vars are vars={u[x1,…,xn],{x1,…,xn}}.
  • Time-dependent model variables vars are vars={u[t,x1,…,xn],t,{x1,…,xn}}.
  • The PoissonPDEComponent is based on a diffusion and source term:
  • The Poisson PDE term is realized as a DiffusionPDETerm with –1 as a diffusion coefficient and a SourcePDETerm with coefficient resulting in .
  • The following model parameters pars can be given:
  • parameterdefaultsymbol
    "CoordinateChart""Cartesian"
    "PoissonSourceTerm"1
    "RegionSymmetry"None
  • The source term coefficient is a scalar.
  • The source term coefficient can depend on time, space, parameters and the dependent variables.
  • A possible choice for the parameter "RegionSymmetry" is "Axisymmetric".
  • "Axisymmetric" region symmetry represents a truncated cylindrical coordinate system where the cylindrical coordinates are reduced by removing the angle variable as follows:
  • dimensionreductionequation
    1D
    2D
  • The diffusion coefficient 1 affects the meaning of NeumannValue.
  • If the PoissonPDEComponent depends on parameters that are specified in the association pars as …,keypi…,pivi,…, the parameters are replaced with .

Examples

open all close all

Basic Examples  (4)

Define a Poisson PDE component:

Wolfram Language code: PoissonPDEComponent[{u[x], {x}}, <||>]

Define a Poisson PDE component with a symbolic coefficient:

Wolfram Language code: PoissonPDEComponent[{u[x], {x}}, <|"PoissonSourceTerm" -> κ|>]

Find the eigenvalues of a Poisson PDE component:

Wolfram Language code: NDEigenvalues[PoissonPDEComponent[{u[x], {x}}, <||>], u, {x}∈Line[{{0}, {1}}], 3]

Solve a Poisson equation:

Wolfram Language code: NDSolveValue[{PoissonPDEComponent[{u[x, y], {x, y}}, <|"PoissonSourceTerm" -> 1|>] == 0, DirichletCondition[u[x, y] == 0, True]}, u[x, y], {x, y}∈Disk[]]

Visualize the result:

Wolfram Language code: Plot3D[%, {x, y}∈Disk[]]

Scope  (2)

Define a 2D axisymmetric Poisson equation:

Wolfram Language code: PoissonPDEComponent[{u[r, z], {r, z}}, <|"RegionSymmetry" -> "Axisymmetric", "PoissonSourceTerm" -> f|>]

Activate the equation:

Wolfram Language code: Activate[%]

Set up a Poisson equation in polar coordinates:

Wolfram Language code: PoissonPDEComponent[{u[r, θ], {r, θ}}, <|"CoordinateChart" -> "Polar"|>]

Activate the equation:

Wolfram Language code: Activate[%]

Applications  (1)

Solve an axisymmetric Poisson problem in a solid cylinder. Define the variables and parameters:

Wolfram Language code: vars = {u[r, z], {r, z}}; pars = <|"PoissonSourceTerm" -> -Sin[r] / (r Exp[z]), "RegionSymmetry" -> "Axisymmetric"|>;

The solid cylinder can be approximated by a 2D rectangle that represents a cross section of the solid. Create the 2D rectangle using Polygon:

Wolfram Language code: Ω = Polygon[{{0, 0}, {1, 0}, {1, 1}, {0, 1}}];

Set up the boundary conditions:

Wolfram Language code: bc = {DirichletCondition[u[r, z] == Cos[r], z == 0], DirichletCondition[u[r, z] == Exp[-1] * Cos[r], z == 1], DirichletCondition[u[r, z] == Exp[-z]Cos[1], r == 1]};

Set up the PDE:

Wolfram Language code: pde = {PoissonPDEComponent[vars, pars] == 0, bc};

Solve the PDE:

Wolfram Language code: ufun = NDSolveValue[pde, u, {r, z}∈ Ω]

Visualize the solution with DensityPlot:

Wolfram Language code: DensityPlot[ufun[r, z], {r, z}∈ Ω, ...]

The exact solution is given by . Visualize the error between the exact solution and the 2D axisymmetric solution:

Wolfram Language code: Plot3D[Exp[-z] * Cos[r] - ufun[r, z], {r, z}∈Ω]
Wolfram Research (2020), PoissonPDEComponent, Wolfram Language function, https://reference.wolfram.com/language/ref/PoissonPDEComponent.html (updated 2026).

Text

Wolfram Research (2020), PoissonPDEComponent, Wolfram Language function, https://reference.wolfram.com/language/ref/PoissonPDEComponent.html (updated 2026).

CMS

Wolfram Language. 2020. "PoissonPDEComponent." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2026. https://reference.wolfram.com/language/ref/PoissonPDEComponent.html.

APA

Wolfram Language. (2020). PoissonPDEComponent. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/PoissonPDEComponent.html

BibTeX

@misc{reference.wolfram_2026_poissonpdecomponent, author="Wolfram Research", title="{PoissonPDEComponent}", year="2026", howpublished="\url{https://reference.wolfram.com/language/ref/PoissonPDEComponent.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_poissonpdecomponent, organization={Wolfram Research}, title={PoissonPDEComponent}, year={2026}, url={https://reference.wolfram.com/language/ref/PoissonPDEComponent.html}, note=[Accessed: 13-June-2026]}