Wolfram Language & System Documentation Center

ProbitModelFit

ProbitModelFit[{{x₁,y₁},{x₂,y₂},…},{f₁,f₂,…},x]

constructs a binomial probit regression model of the form that fits the y_i for each x_i.

ProbitModelFit[data,{f₁,f₂,…},{x₁,x₂,…}]

constructs a binomial probit regression model of the form where the f_i depend on the variables x_k.

ProbitModelFit[{m,v}]

constructs a binomial probit regression model from the design matrix m and response vector v.

ProbitModelFit

ProbitModelFit[{{x₁,y₁},{x₂,y₂},…},{f₁,f₂,…},x]

constructs a binomial probit regression model of the form that fits the y_i for each x_i.

ProbitModelFit[data,{f₁,f₂,…},{x₁,x₂,…}]

constructs a binomial probit regression model of the form where the f_i depend on the variables x_k.

ProbitModelFit[{m,v}]

constructs a binomial probit regression model from the design matrix m and response vector v.

Details and Options

ProbitModelFit attempts to model the data using a linear combination of basis functions composed with the inverse of the probit function ().
LogitModelFit is typically used in classification to model probability values.
ProbitModelFit produces a generalized linear model of the form under the assumption that the original are independent realizations of Bernoulli trials with probabilities .
The function is the CDF of the standard NormalDistribution.
ProbitModelFit returns a symbolic FittedModel object to represent the probit model it constructs. The properties and diagnostics of the model can be obtained from model["property"].
The value of the best-fit function from ProbitModelFit at a particular point x₁, … can be found from model[x₁,…].
Possible forms of data are:

	{y₁,y₂,…}	equivalent to the form {{1,y₁},{2,y₂},…}
	{{x₁₁,x₁₂,…,y₁},…}	a list of independent values x_ij and the responses y_i
	{{x₁₁,x₁₂,…}y₁,…}	a list of rules between input values and response
	{{x₁₁,x₁₂,…},…}{y₁,y₂,…}	a rule between a list of input values and responses
	{{x₁₁,…,y₁,…},…}n	fit the n column of a matrix
	Tabular[…]name	fit the column name in a tabular object

With multivariate data such as ${{x_(11),x_(12),... ,y_(1)},{x_(21),x_(22),... ,y_(2)},...}$ , the number of coordinates x_i1, x_i2, … should equal the number of variables x_i.
The y_i are probabilities between 0 and 1.
Additionally, data can be specified using a design matrix without specifying functions and variables:
{m,v} a design matrix m and response vector v
In ProbitModelFit[{m,v}], the design matrix m is formed from the values of basis functions f_i at data points in the form {{f₁,f₂,…},{f₁,f₂,…},…}. The response vector v is the list of responses {y₁,y₂,…}.
For a design matrix m and response vector v, the model is where is the vector of parameters to be estimated.
When a design matrix is used, the basis functions f_i can be specified using the form ProbitModelFit[{m,v},{f₁,f₂,…}].
ProbitModelFit is equivalent to GeneralizedLinearModelFit with ExponentialFamily->"Binomial" and LinkFunction->"ProbitLink".
ProbitModelFit takes the same options as GeneralizedLinearModelFit, with the exception of ExponentialFamily and LinkFunction.

Examples

open all close all

Basic Examples (1)

Define a dataset:

Wolfram Language code:

data = {{1, 0}, {2, 0}, {2, 0}, {2, 1}, {2, 0}, {3, 0}, {3, 0}, {3, 0}, {3, 1}, {3, 1}, {3, 1}, {4, 1}, {4, 1}, {5, 0}, {6, 1}, {7, 1}};

Fit a probit model to the data:

Wolfram Language code: probit = ProbitModelFit[data, x, x]

Evaluate the model at a point:

Wolfram Language code: probit[1.5]

Plot the data points and the models:

Wolfram Language code: Show[ListPlot[data, PlotStyle -> PointSize[Medium]], Plot[probit[x], {x, 0, 8}]]

Scope (13)

Data (6)

Fit data with success probability responses, assuming increasing integer-independent values:

Wolfram Language code: ProbitModelFit[{1 / 3, 2 / 3, 5 / 5}, x, x]//Normal

This is equivalent to:

Wolfram Language code: ProbitModelFit[{{1, 1 / 3}, {2, 2 / 3}, {3, 5 / 5}}, x, x]//Normal

Weight by the number of observations for each predictor value:

Wolfram Language code: ProbitModelFit[{{1, 1 / 3}, {2, 2 / 3}, {3, 5 / 5}}, x, x, Weights -> {3, 6, 5}]//Normal

This gives the same best fit function as success failure data:

Wolfram Language code:

sfdata = {{1, 0}, {1, 1}, {1, 0}, {2, 0}, {2, 0}, {2, 1}, {2, 1}, {2, 1}, {2, 1}, {3, 1}, {3, 1}, {3, 1}, {3, 1}, {3, 1}};
GroupBy[sfdata, First -> Last]

Wolfram Language code: ProbitModelFit[sfdata, x, x] //Normal

Fit a list of rules:

Wolfram Language code: ProbitModelFit[{1 -> 1 / 3, 2 -> 2 / 3, 3 -> 3 / 3}, x, x]

Fit a rule of input values and responses:

Wolfram Language code: ProbitModelFit[{1, 2, 3} -> {1 / 3, 2 / 3, 3 / 3}, x, x]

Specify a column as the response:

Wolfram Language code: data = {...};

Wolfram Language code: fit = ProbitModelFit[data -> 1, {1, x, y}, {x, y}]

Wolfram Language code:

Show[
	Plot3D[fit[x, y], {x, -5, 5}, {y, -5, 5}], 
	ListPointPlot3D[data[[All, {2, 3, 1}]]], 
	PlotRange -> All
	]

Fit a model given a design matrix and response vector:

Wolfram Language code:

dm = {{1, 1}, {1, 2}, {1, 3}, {1, 4}};
resp = {0, 1, 0, 1};ProbitModelFit[{dm, resp}]

See the functional form:

Wolfram Language code: Normal[%]

Fit the model referring to the basis functions as and :

Wolfram Language code: ProbitModelFit[{dm, resp}, {x, y}]//Normal

Obtain a list of available properties:

Wolfram Language code: probit = ProbitModelFit[RandomReal[1, 10], x, x]

Wolfram Language code: probit["Properties"]

Properties (7)

Data & Fitted Functions (1)

Fit a probit model:

Wolfram Language code: data = Join[RandomReal[10, {10, 2}], Transpose[{RandomReal[1, 10]}], 2];

Wolfram Language code: probit = ProbitModelFit[data, {x, y}, {x, y}]

Extract the original data:

Wolfram Language code: probit["Data"]

Obtain and plot the best fit:

Wolfram Language code:

{fit = probit["BestFit"], Show[Plot3D[fit, {x, 0, 10}, {y, 0, 10}], Graphics3D[{PointSize[0.025], Point[probit["Data"]]}]]}

Obtain the fitted function as a pure function:

Wolfram Language code: probit["Function"]

Get the design matrix and response vector for the fitting:

Wolfram Language code: MatrixForm /@ probit[{"DesignMatrix", "Response"}]

Residuals (1)

Examine residuals for a fit:

Wolfram Language code: data = Join[RandomReal[10, {100, 2}], Transpose[{RandomReal[1, 100]}], 2];

Wolfram Language code: probit = ProbitModelFit[data, {x, y}, {x, y}]

Wolfram Language code: {fr, ar, spr} = probit[{"FitResiduals", "StandardizedPearsonResiduals", "AnscombeResiduals"}];

Visualize the raw residuals:

Wolfram Language code: ListPlot[fr]

Visualize Anscombe residuals and standardized Pearson residuals in stem plots:

Wolfram Language code: Map[ListPlot[#, Filling -> 0]&, {ar, spr}]//Row

Dispersion and Deviances (1)

Fit a probit model to some data:

Wolfram Language code:

SeedRandom[1];
data = Flatten[Table[{x, y, 1 / (1 + Exp[.2 + .3x + .1y + RandomReal[{-1, 1}]])}, {x, RandomReal[5, 10]}, {y, RandomReal[5, 10]}], 1];probit = ProbitModelFit[data, {x, y}, {x, y}]

The estimated dispersion is 1 by default:

Wolfram Language code: probit["EstimatedDispersion"]

Use Pearson's as the dispersion estimator instead:

Wolfram Language code: probit["EstimatedDispersion", DispersionEstimatorFunction -> "PearsonChiSquare"]

Plot the deviances for each point:

Wolfram Language code: ListPlot[probit["Deviances"], Filling -> 0]

Obtain the analysis of deviance table:

Wolfram Language code: probit["DevianceData"]

Get the residual deviances from the table:

Wolfram Language code: probit["DevianceData"][All, "ResidualDeviance"]//Normal

Parameter Estimation Diagnostics (1)

Obtain a formatted table of parameter information:

Wolfram Language code:

SeedRandom[1];
data = Table[{i, RandomInteger[BinomialDistribution[20, .05 + i / 30 + Sin[i] / 10]] / 20}, {i, 1, 20, .2}];
probit = ProbitModelFit[data, {x, Sin[x], Cos[x]}, x];

Wolfram Language code: probit["ParameterEstimates"]

Extract the column of -statistic values:

Wolfram Language code: probit["ParameterEstimates"][All, "ZStatistic"]//Normal

Influence Measures (1)

Fit some data containing extreme values to a probit model:

Wolfram Language code:

data = Table[{i, 1 / 2(1 + Erf[(2 + 4i + RandomReal[]) / Sqrt[2]])}, {i, RandomReal[{1, 10}, 20]}];
data[[{3, 8}, -1]] = 1 - data[[{3, 8}, -1]];
probit = ProbitModelFit[data, x, x]

Check Cook distances to identify highly influential points:

Wolfram Language code: ListPlot[probit["CookDistances"], PlotRange -> {0, All}, Filling -> 0]

Check the diagonal elements of the hat matrix to assess influence of points on the fitting:

Wolfram Language code: ListPlot[probit["HatDiagonal"], PlotRange -> {0, All}, Filling -> 0]

Prediction Values (1)

Fit a probit model:

Wolfram Language code:

data = Flatten[Table[{x, y, 1 / (1 + Exp[.3x - .5y + RandomReal[{-1, 1}]])}, {x, RandomReal[5, 3]}, {y, RandomReal[5, 3]}], 1];probit = ProbitModelFit[data, {x, y}, {x, y}]

Plot the predicted values against the observed values:

Wolfram Language code:

ListPlot[Transpose[probit[{"Response", "PredictedResponse"}]], FrameLabel -> {"observed", "predicted"}, Frame -> True, Axes -> False]

Goodness-of-Fit Measures (1)

Obtain a table of goodness-of-fit measures for a probit model:

Wolfram Language code:

data = Flatten[Table[{i, j, RandomReal[], 1 / 2(1 + Erf[(.2 + .3i + j + RandomReal[]) / Sqrt[2]])}, {i, RandomReal[1, 5]}, {j, RandomReal[1, 5]}], 1];

Wolfram Language code: probit = ProbitModelFit[data, {x, y, z}, {x, y, z}]

Wolfram Language code: Grid[Transpose[{#, probit[#]}&[{"AIC", "BIC", "LikelihoodRatioIndex", "PearsonChiSquare"}]], Alignment -> Left]

Compute goodness-of-fit measures for all subsets of predictor variables:

Wolfram Language code:

sub = Table[Join[{i}, ProbitModelFit[data, i, {x, y, z}][{"AIC", "BIC", "LikelihoodRatioIndex", "PearsonChiSquare"}]], {i, Subsets[{x, y, z}]}]

Rank the models by AIC:

Wolfram Language code: Grid[Join[{{"Model", "AIC", "BIC", "LikelihoodRatioIndex", "PearsonChiSquare"}}, SortBy[sub, -#[[2]]&]]]

Generalizations & Extensions (1)

Perform other mathematical operations on the functional form of the model:

Wolfram Language code: probit = ProbitModelFit[Table[{i, RandomReal[{i - 1, i}] / 10}, {i, 10}], x, x]

Integrate symbolically and numerically:

Wolfram Language code: Integrate[probit[x], x]

Wolfram Language code: NIntegrate[probit[x], {x, 1, 5}]

Find a predictor value that gives a particular value for the model:

Wolfram Language code: FindRoot[probit[x] == .5, {x, 5}]

Options (8)

ConfidenceLevel (1)

The default gives 95% confidence intervals:

Wolfram Language code: data = {{0, 1}, {1, 0}, {3, 1}, {5, 0}};

Wolfram Language code: probit = ProbitModelFit[data, x, x]

Wolfram Language code: probit["ParameterEstimates"][All, "ConfidenceInterval"]//Normal

Use 99% intervals instead:

Wolfram Language code: probit = ProbitModelFit[data, x, x, ConfidenceLevel -> .99]

Wolfram Language code: probit["ParameterEstimates"][All, "ConfidenceInterval"]//Normal

Set the level to 90% within FittedModel:

Wolfram Language code: probit["ParameterEstimates", ConfidenceLevel -> .9][All, "ConfidenceInterval"]//Normal

CovarianceEstimatorFunction (1)

Fit a probit model:

Wolfram Language code: data = {{0, 1}, {1, 0}, {3, 1}, {5, 0}};

Wolfram Language code: probit = ProbitModelFit[data, x, x]

Compute the covariance matrix using the expected information matrix:

Wolfram Language code: probit["CovarianceMatrix"]

Use the observed information matrix instead:

Wolfram Language code: probit["CovarianceMatrix", CovarianceEstimatorFunction -> "ObservedInformation"]

DispersionEstimatorFunction (1)

Fit a probit model:

Wolfram Language code: data = {{1, 0}, {1, 1}, {1, 1}, {2, 0}, {2, 0}, {2, 1}, {2, 1}, {2, 1}, {2, 1}};

Wolfram Language code: probit = ProbitModelFit[data, x, x]

Compute the covariance matrix:

Wolfram Language code: probit["CovarianceMatrix"]

Compute the covariance matrix estimating the dispersion by Pearson's :

Wolfram Language code: probit["CovarianceMatrix", DispersionEstimatorFunction -> "PearsonChiSquare"]

IncludeConstantBasis (1)

Fit a probit model:

Wolfram Language code: data = {{0, 1}, {1, 0}, {3, 1}, {5, 0}};

Wolfram Language code: ProbitModelFit[data, x, x]//Normal

Fit the model with zero constant term:

Wolfram Language code: ProbitModelFit[data, x, x, IncludeConstantBasis -> False]//Normal

LinearOffsetFunction (1)

Fit data to a probit model:

Wolfram Language code: data = {{0, 1}, {1, 0}, {3, 1}, {5, 0}};

Wolfram Language code: ProbitModelFit[data, x, x]//Normal

Fit data to a model with a known Sqrt[x] term:

Wolfram Language code: ProbitModelFit[data, x, x, LinearOffsetFunction -> (Sqrt[#]&)]//Normal

NominalVariables (1)

Wolfram Language code: data = {{a, 0, 0}, {b, 2, 1}, {a, 2, 0}, {b, 0, 1}, {a, 2, 1}, {b, 0, 0}};

Fit the data, treating the first variable as a nominal variable:

Wolfram Language code: nom = ProbitModelFit[data, {x, y}, {x, y}, NominalVariables -> x]

Wolfram Language code: Normal[nom]

Treat both variables as nominal:

Wolfram Language code: ProbitModelFit[data, {x, y}, {x, y}, NominalVariables -> All]//Normal

Weights (1)

Fit a model using equal weights:

Wolfram Language code: data = {{0, 1}, {1, 0}, {3, 1}, {5, 0}};

Wolfram Language code: ProbitModelFit[data, x, x]//Normal

Give explicit weights for the data points:

Wolfram Language code: ProbitModelFit[data, x, x, Weights -> {1, (1/2), (1/3), (1/4)}]//Normal

WorkingPrecision (1)

Use WorkingPrecision to get higher precision in parameter estimates:

Wolfram Language code: data = Table[{x, (10 - x) / 10}, {x, 10}]

Wolfram Language code: probit = ProbitModelFit[data, x, x, WorkingPrecision -> 25]

Obtain the fitted function:

Wolfram Language code: probit["BestFit"]

Reduce the precision in property computations after the fitting:

Wolfram Language code: probit["BestFit", WorkingPrecision -> MachinePrecision]

Properties & Relations (4)

ProbitModelFit is equivalent to a "Binomial" model from GeneralizedLinearModelFit with "ProbitLink":

Wolfram Language code: data = Table[{i, RandomReal[{i - 1, i}] / 10}, {i, 10}];

Wolfram Language code: GeneralizedLinearModelFit[data, x, x, ExponentialFamily -> "Binomial", LinkFunction -> "ProbitLink"]//Normal

Wolfram Language code: probitFit = ProbitModelFit[data, x, x]//Normal

LogitModelFit is a "Binomial" model from GeneralizedLinearModelFit with default "LogitLink":

Wolfram Language code: GeneralizedLinearModelFit[data, x, x, ExponentialFamily -> "Binomial"]//Normal

Wolfram Language code: logitFit = LogitModelFit[data, x, x]//Normal

ProbitModelFit assumes binomially distributed responses:

Wolfram Language code: data = Table[{i, RandomReal[{i - 1, i}] / 10}, {i, 10}];

Wolfram Language code: pm = ProbitModelFit[data, x, x]

NonlinearModelFit assumes normally distributed responses:

Wolfram Language code: nm = NonlinearModelFit[data, 1 / 2(1 + Erf[(a + b x) / Sqrt[2]]), Transpose[{{a, b}, pm["BestFitParameters"]}], x]

The fits are not identical:

Wolfram Language code: {Normal[pm], Normal[nm]}

Wolfram Language code: Plot[{pm[x], nm[x]}, {x, 1, 5}, PlotRange -> All]

ProbitModelFit will use the time stamps of a TimeSeries as variables:

Wolfram Language code:

ts1 = TemporalData[TimeSeries, {{{0.7758532198866042, 0.20426632015371096, 0.2353690565215641, 
    0.4448009174525732, 0.5081575045542254, 0.5371908040104083, 0.6223323745794831, 
    0.669522447912184, 0.7204685251554224, 0.7633871517003976}}, {{0, 9, 1}}, 1, {"Continuous", 1}, 
  {"Discrete", 1}, 1, {ResamplingMethod -> {"Interpolation", InterpolationOrder -> 1}}}, False, 
 10.1];

Wolfram Language code: ts1["Times"]

Wolfram Language code: ProbitModelFit[ts1, x, x]

Rescale the time stamps and fit again:

Wolfram Language code: ts2 = TimeSeriesRescale[ts1, {.1, 2}]

Wolfram Language code: ts2["Times"]

Wolfram Language code: ProbitModelFit[ts2, x, x]

Find fit for the values:

Wolfram Language code: ProbitModelFit[ts1["Values"], x, x]

ProbitModelFit acts pathwise on a multipath TemporalData:

Wolfram Language code:

ProbitModelFit[TemporalData[Automatic, {{{0.009753347177267509, 0.18455899093641098, 0.20260886672737863, 
    0.37977270854029854, 0.45927203330240407, 0.5010683896315415, 0.6468842072138713, 
    0.7452632634563319, 0.8683334166368966, 0.9876532168951402}, 
    ... 2138713, 0.7452632634563319, 
    0.8683334166368966, 0.9876532168951402}}, {{0, 9, 1}, {0.1, 2., 0.2111111111111111}}, 2, 
  {"Continuous", 2}, {"Discrete", 2}, 1, 
  {ResamplingMethod -> {"Interpolation", InterpolationOrder -> 1}}}, False, 10.1], x, x]

Possible Issues (1)

Responses outside the interval from 0 to 1 are not valid for probit models:

Wolfram Language code: ProbitModelFit[Range[5], x, x]

Wolfram Language code: ProbitModelFit[Table[{i, 2i}, {i, 10}], x, x]

Top

ProbitModelFit

Details and Options

Examples

Basic Examples (1)

Scope (13)

Data (6)

Properties (7)

Data & Fitted Functions (1)

Residuals (1)

Dispersion and Deviances (1)

Parameter Estimation Diagnostics (1)

Influence Measures (1)

Prediction Values (1)

Goodness-of-Fit Measures (1)

Generalizations & Extensions (1)

Options (8)

ConfidenceLevel (1)

CovarianceEstimatorFunction (1)

DispersionEstimatorFunction (1)

IncludeConstantBasis (1)

LinearOffsetFunction (1)

NominalVariables (1)

Weights (1)

WorkingPrecision (1)

Properties & Relations (4)

Possible Issues (1)

See Also

Tech Notes

Related Guides

History

Text

CMS

APA

BibTeX

BibLaTeX