WOLFRAM

Wolfram Language & System Documentation Center

RamanujanTau[n]

gives the Ramanujan function .

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Numerical Evaluation  
Specific Values  
Visualization  
Function Properties  
Applications  
Properties & Relations  
Possible Issues  
Neat Examples  
See Also
Tech Notes
Related Guides
History
Cite this Page

RamanujanTau

RamanujanTau[n]

gives the Ramanujan function .

Details

  • Integer mathematical function.
  • gives the coefficient of in the series expansion of .
  • RamanujanTau automatically threads over lists.

Examples

open all close all

Basic Examples  (2)

The first 10 values of RamanujanTau:

Wolfram Language code: Table[RamanujanTau[n], {n, 10}]

Plot over a subset of the reals:

Wolfram Language code: ListLinePlot[RamanujanTau[Range[20]], PlotRange -> All]

Scope  (12)

Numerical Evaluation  (3)

Evaluate numerically:

Wolfram Language code: RamanujanTau[5]
Wolfram Language code: RamanujanTau[485]

Evaluate efficiently for large values of the argument:

Wolfram Language code: RamanujanTau[72675]//Timing
Wolfram Language code: RamanujanTau[586586575];//Timing

Compute the elementwise values of an array:

Wolfram Language code: RamanujanTau[{{1, 0}, {-1, 2}}]

Or compute the matrix RamanujanTau function using MatrixFunction:

Wolfram Language code: MatrixFunction[RamanujanTau, {{1, 0}, {-1, 2}}]//FullSimplify

Specific Values  (2)

Values at fixed points:

Wolfram Language code: Table[RamanujanTau[s ], {s, 1, 5}]

Value at zero:

Wolfram Language code: RamanujanTau[0]

Visualization  (3)

Plot the RamanujanTau function:

Wolfram Language code: ListLinePlot[RamanujanTau[Range[20]], PlotRange -> All]

Plot the contours of the RamanujanTau function:

Wolfram Language code: ListContourPlot[Table[RamanujanTau[x + y], {x, 0, 20, 1}, {y, 0, 20, 1}]]

Plot the RamanujanTau function in three dimensions:

Wolfram Language code: ListPlot3D[Table[RamanujanTau[x + y], {x, 0, 20, 1}, {y, 0, 20, 1}], ColorFunction -> "BlueGreenYellow"]

Function Properties  (4)

RamanujanTau is only defined for integer inputs:

Wolfram Language code: FunctionDomain[RamanujanTau[x], x]
Wolfram Language code: FunctionDomain[RamanujanTau[z], z, Complexes]

RamanujanTau threads over lists:

Wolfram Language code: RamanujanTau[{2, 3, 5, 7, 11}]

RamanujanTauL is everywhere singular:

Wolfram Language code: FunctionSingularities[RamanujanTau[x], x]
Wolfram Language code: FunctionDiscontinuities[RamanujanTau[x], x]

Traditional form:

Wolfram Language code: RamanujanTau[n] // TraditionalForm

Applications  (7)

Logarithmic plot of RamanujanTau:

Wolfram Language code: ListLinePlot[Log[Abs[RamanujanTau[Range[2000]]]]]

The first prime value of RamanujanTau:

Wolfram Language code: RamanujanTau[63001]
Wolfram Language code: PrimeQ[%]

The first 20,000 values are nonzero, satisfying Lehmer's conjecture [more info]:

Wolfram Language code: And@@Table[RamanujanTau[n] != 0, {n, 20000}]

Plot of at primes :

Wolfram Language code: ListLinePlot[RamanujanTau[#] / (2 # ^ (11 / 2)) & /@ Prime[Range[50]], Mesh -> All]

The modular discriminant:

Wolfram Language code: m[q_] := (2Pi) ^ 12 NSum[RamanujanTau[n] E ^ (2Pi I n q), {n, 1, Infinity}]

Relation with DedekindEta:

Wolfram Language code: m[I] == (2 Pi) ^ 12 DedekindEta[I] ^ 24

The summatory -function [more info]:

Wolfram Language code: Plot[Sum[RamanujanTau[n], {n, 1, x - 1}] + Piecewise[{{RamanujanTau[x] / 2, Element[x, Integers]}}, RamanujanTau[Floor[x]]], {x, 0, 30}, PlotRange -> All, Filling -> Axis]

The modular discriminant:

Wolfram Language code: m[τ_] := (2Pi) ^ 12 NSum[RamanujanTau[n] (E^2π I τ)^n, {n, 1, Infinity}]

Relation with DedekindEta:

Wolfram Language code: DedekindEta[2I]^24 == m[2I] / (2 Pi) ^ 12

Properties & Relations  (7)

The first 10 values of RamanujanTau using Product:

Wolfram Language code: CoefficientList[QPochhammer[x] ^ 24 + O[x] ^ 10, x]
Wolfram Language code: RamanujanTau[Range[10]]

RamanujanTau is multiplicative for coprime integers:

Wolfram Language code: RamanujanTau[7 5]
Wolfram Language code: RamanujanTau[7] RamanujanTau[5]

For prime :

Wolfram Language code: With[{p = 3, n = 6}, RamanujanTau[p ^ (n + 1)] == RamanujanTau[p]RamanujanTau[p ^ n] - p ^ 11 RamanujanTau[p ^ (n - 1)]]

Congruence relations:

Wolfram Language code: And @@ Table[Mod[RamanujanTau[5 n], 5] == 0, {n , 200}]
Wolfram Language code: And@@Table[Mod[RamanujanTau[4n] - RamanujanTau[n], 3] == 0, {n, 200}]
Wolfram Language code: And @@ Table[Mod[RamanujanTau[n] - DivisorSigma[11, n], 691] == 0, {n, 200}]

Representation of an integer as the sum of 24 squares:

Wolfram Language code: r[n_] := 16 / 691 Sum[(-1) ^ (n + d) d ^ 11, {d, Divisors[n]}] + 128 / 691(259(-1) ^ (n - 1)RamanujanTau[n] - 512 RamanujanTau[n / 2])
Wolfram Language code: r[8]
Wolfram Language code: SquaresR[24, 8]

RamanujanTauL is the Dirichlet -function associated with RamanujanTau:

Wolfram Language code: NSum[RamanujanTau[n] / n ^ (20 + I), {n, 1, Infinity}]
Wolfram Language code: N[RamanujanTauL[20 + I]]

FindSequenceFunction can recognize the RamanujanTau sequence:

Wolfram Language code: Table[RamanujanTau[n], {n, 10}]
Wolfram Language code: FindSequenceFunction[%, n]

Possible Issues  (1)

Large prime numbers can take a long time:

Wolfram Language code: RamanujanTau[1999993]//Timing

Neat Examples  (3)

Successive differences of RamanujanTau modulo 3:

Wolfram Language code: ArrayPlot[Mod[NestList[Differences, RamanujanTau[Range[100]], 100], 3]]

A representation of zero in terms of RamanujanTau:

Wolfram Language code: RamanujanTau[6] + RamanujanTau[14] + RamanujanTau[29] + RamanujanTau[41] + RamanujanTau[42] + RamanujanTau[44] + RamanujanTau[48]

Find digit counts for RamanujanTau[10^12]:

Wolfram Language code: DigitCount[RamanujanTau[10 ^ 12]]
Wolfram Research (2007), RamanujanTau, Wolfram Language function, https://reference.wolfram.com/language/ref/RamanujanTau.html.

Text

Wolfram Research (2007), RamanujanTau, Wolfram Language function, https://reference.wolfram.com/language/ref/RamanujanTau.html.

CMS

Wolfram Language. 2007. "RamanujanTau." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/RamanujanTau.html.

APA

Wolfram Language. (2007). RamanujanTau. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/RamanujanTau.html

BibTeX

@misc{reference.wolfram_2026_ramanujantau, author="Wolfram Research", title="{RamanujanTau}", year="2007", howpublished="\url{https://reference.wolfram.com/language/ref/RamanujanTau.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_ramanujantau, organization={Wolfram Research}, title={RamanujanTau}, year={2007}, url={https://reference.wolfram.com/language/ref/RamanujanTau.html}, note=[Accessed: 13-June-2026]}