WOLFRAM

Wolfram Language & System Documentation Center

RegionCongruent[reg1,reg2]

tests whether the regions reg1 and reg2 are congruent.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Basic Uses  
Special Regions  
Formula Regions  
Mesh Regions  
Derived Regions  
Applications  
Properties & Relations  
See Also
Related Guides
History
Cite this Page

RegionCongruent

RegionCongruent[reg1,reg2]

tests whether the regions reg1 and reg2 are congruent.

Details and Options

  • The regions reg1 and reg2 are congruent if reg2 can be obtained from reg1 by a combination of translations, rotations and reflections.
  • Typically used to test whether two regions have the same shape and size or whether one has the same shape and size as the mirror image of the other.
  • RegionCongruent[reg1,reg2] gives True if there is an affine transformation from reg1 to reg2 with matrix m satisfying TemplateBox[{m}, Transpose]=TemplateBox[{m}, Inverse].

Examples

open all close all

Basic Examples  (1)

Test whether two regions are congruent:

Wolfram Language code: RegionCongruent[Rectangle[], Polygon[{{0, 0}, {1, 0}, {1, 1}, {0, 1}}]]
Wolfram Language code: RegionCongruent[Rectangle[], Parallelogram[]]

Scope  (10)

Basic Uses  (2)

Test whether two regions are congruent:

Wolfram Language code: RegionCongruent[Rectangle[], Parallelogram[]]

Show two regions are not congruent:

Wolfram Language code: RegionCongruent[Rectangle[{1, 1}], Rectangle[{2, 3}]]

Special Regions  (3)

RegionCongruent works in 1D:

Wolfram Language code: RegionCongruent[Line[{{0}, {1}}], Interval[{0, 1}]]

Point:

Wolfram Language code: RegionCongruent[Point[{1, 1}], Point[{2, 2}]]

Ball:

Wolfram Language code: RegionCongruent[Ball[1], Interval[{-1, 1}]]

InfiniteLine:

Wolfram Language code: RegionCongruent[InfiniteLine[{0}, {1}], FullRegion[1]]

RegionCongruent works in 2D:

Wolfram Language code: Subscript[ℛ, 1] = Point[Tuples[Range[3], 2]]; Subscript[ℛ, 2] = Point[Join@@Table[{i, j}, {j, 3}, {i, 3}]];
Wolfram Language code: RegionCongruent[Subscript[ℛ, 1], Subscript[ℛ, 2]]

Disk and Ball:

Wolfram Language code: Subscript[ℛ, 1] = Disk[]; Subscript[ℛ, 2] = Ball[2];
Wolfram Language code: RegionCongruent[Subscript[ℛ, 1], Subscript[ℛ, 2]]

Polygon:

Wolfram Language code: Subscript[ℛ, 1] = Polygon[{{0, 0}, {1, 0}, {1, 1}, {0, 1}}]; Subscript[ℛ, 2] = Rectangle[];
Wolfram Language code: RegionCongruent[Subscript[ℛ, 1], Subscript[ℛ, 2]]

RegionCongruent works in 3D:

Wolfram Language code: Subscript[ℛ, 1] = Point[Tuples[Range[5], 3]]; Subscript[ℛ, 2] = Point[Flatten[Table[{i, j, k}, {j, 5}, {k, 5}, {i, 5}], 2]];
Wolfram Language code: RegionCongruent[Subscript[ℛ, 1], Subscript[ℛ, 2]]

Formula Regions  (1)

Compare two formula regions:

Wolfram Language code: Subscript[ℛ, 1] = ImplicitRegion[-1 ≤ x ≤ 1 && y^2 ≤ x^4 - 2x^2 + 1, {x, y}]; Subscript[ℛ, 2] = ParametricRegion[{t, s (1 - t^2)}, {{s, -1, 1}, {t, -1, 1}}];
Wolfram Language code: RegionCongruent[Subscript[ℛ, 1], Subscript[ℛ, 2]]

Mesh Regions  (3)

Test whether two mesh regions are congruent:

Wolfram Language code: Subscript[ℛ, 1] = MeshRegion[{{0}, {1}}, Line[{1, 2}]]; Subscript[ℛ, 2] = MeshRegion[{{0}, {1 / 2}, {1}}, Line[{3, 2, 1}]];
Wolfram Language code: RegionCongruent[Subscript[ℛ, 1], Subscript[ℛ, 2]]
Wolfram Language code: Subscript[ℛ, 1] = MeshRegion[{{0, 0}, {1, 0}, {1, 1}, {0, 1}}, Polygon[{1, 2, 3, 4}]]; Subscript[ℛ, 2] = TriangulateMesh[Subscript[ℛ, 1]];
Wolfram Language code: RegionCongruent[Subscript[ℛ, 1], Subscript[ℛ, 2]]

Test whether two boundary mesh regions are congruent:

Wolfram Language code: Subscript[ℛ, 1] = BoundaryMeshRegion[{{0}, {1}}, Point[{1, 2}]]; Subscript[ℛ, 2] = BoundaryMeshRegion[{{0}, {1}}, Point[{2, 1}]];
Wolfram Language code: RegionCongruent[Subscript[ℛ, 1], Subscript[ℛ, 2]]
Wolfram Language code: Subscript[ℛ, 1] = BoundaryMeshRegion[{{0, 0}, {2, 0}, {2, 2}, {0, 2}}, Line[{1, 2, 3, 4, 1}]]; Subscript[ℛ, 2] = BoundaryMeshRegion[{{0, 0}, {1, 0}, {2, 0}, {2, 2}, {0, 2}}, Line[{1, 2, 3, 4, 5, 1}]];
Wolfram Language code: RegionCongruent[Subscript[ℛ, 1], Subscript[ℛ, 2]]

Test whether a mesh region and a boundary mesh region are congruent:

Wolfram Language code: Subscript[ℛ, 1] = DelaunayMesh[RandomReal[{-1, 1}, {25, 2}]]; Subscript[ℛ, 2] = BoundaryMesh[Subscript[ℛ, 1]];
Wolfram Language code: {Subscript[ℛ, 1], Subscript[ℛ, 2]}
Wolfram Language code: RegionCongruent[Subscript[ℛ, 1], Subscript[ℛ, 2]]

In :

Wolfram Language code: Subscript[ℛ, 1] = DelaunayMesh[RandomReal[{-1, 1}, {25, 3}]]; Subscript[ℛ, 2] = BoundaryMesh[Subscript[ℛ, 1]];
Wolfram Language code: RegionCongruent[Subscript[ℛ, 1], Subscript[ℛ, 2]]

Derived Regions  (1)

Test whether Boolean regions are congruent:

Wolfram Language code: Subscript[ℛ, 1] = BooleanRegion[Xnor, {Disk[], Disk[{1, 0}]}]; Subscript[ℛ, 2] = BooleanRegion[(!#1 || #2) && (#1 || !#2)&, {Disk[], Disk[{1, 0}]}];
Wolfram Language code: RegionCongruent[Subscript[ℛ, 1], Subscript[ℛ, 2]]

Applications  (3)

Two disks with the same radius are congruent:

Wolfram Language code: RegionCongruent[Disk[{0, 0}, 2], Disk[{2, 2}, 2]]
Wolfram Language code: RegionCongruent[Disk[{0, 0}, 2], Disk[{2, 2}, 3]]

Two rectangles with the same width and height are congruent:

Wolfram Language code: RegionCongruent[Rectangle[{0, 0}, {1, 3}], Rectangle[{2, 2}, {3, 5}]]
Wolfram Language code: RegionCongruent[Rectangle[{0, 0}, {1, 3}], Rectangle[{2, 1}, {4, 2}]]

Two polygons with the same vertex angles and edge lengths are congruent:

Wolfram Language code: p = RandomPolygon[{"Convex", 5}]; q = TransformedRegion[p, RotationTransform[Pi / 4]];
Wolfram Language code: RegionCongruent[p, q]
Wolfram Language code: r = TransformedRegion[p, ScalingTransform[Pi / 4, {1, 1}]];
Wolfram Language code: RegionCongruent[p, r]

Properties & Relations  (3)

RegionSimilar returns True for congruent regions:

Wolfram Language code: RegionCongruent[Rectangle[], Polygon[{{0, 0}, {1, 0}, {1, 1}, {0, 1}}]]
Wolfram Language code: RegionSimilar[Rectangle[], Polygon[{{0, 0}, {1, 0}, {1, 1}, {0, 1}}]]

Regions that are similar are not always congruent:

Wolfram Language code: RegionSimilar[Rectangle[], Parallelogram[]]
Wolfram Language code: RegionCongruent[Rectangle[], Parallelogram[]]

Two equal regions are congruent:

Wolfram Language code: RegionEqual[Disk[], Ball[2]]
Wolfram Language code: RegionCongruent[Disk[], Ball[2]]

FindRegionTransform gives an affine transformation m of the form TemplateBox[{m}, Transpose]=TemplateBox[{m}, Inverse] between two congruent regions:

Wolfram Language code: RegionCongruent[Rectangle[{0, 0}, {2, 2}], Rectangle[{2, 2}, {4, 4}]]

The affine transformation:

Wolfram Language code: tr = FindRegionTransform[Rectangle[{0, 0}, {2, 2}], Rectangle[{2, 2}, {4, 4}]]

Its affine matrix:

Wolfram Language code: m = tr["AffineMatrix"]
Wolfram Language code: Transpose[m] == Inverse[m]
Wolfram Research (2021), RegionCongruent, Wolfram Language function, https://reference.wolfram.com/language/ref/RegionCongruent.html.

Text

Wolfram Research (2021), RegionCongruent, Wolfram Language function, https://reference.wolfram.com/language/ref/RegionCongruent.html.

CMS

Wolfram Language. 2021. "RegionCongruent." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/RegionCongruent.html.

APA

Wolfram Language. (2021). RegionCongruent. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/RegionCongruent.html

BibTeX

@misc{reference.wolfram_2026_regioncongruent, author="Wolfram Research", title="{RegionCongruent}", year="2021", howpublished="\url{https://reference.wolfram.com/language/ref/RegionCongruent.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_regioncongruent, organization={Wolfram Research}, title={RegionCongruent}, year={2021}, url={https://reference.wolfram.com/language/ref/RegionCongruent.html}, note=[Accessed: 12-June-2026]}