root of 
Surd
Surd[x,n]
gives the real-valued 
root of x.
Details
- Surd[x,n] returns the real-valued
root of real-valued x for odd n. - Surd[x,n] returns the principal
root for non-negative real-valued x and even n. - For symbolic x in Surd[x,n], x is assumed to be real valued.
- Surd can be evaluated to arbitrary numerical precision.
- Surd automatically threads over lists. »
- In StandardForm, Surd[x,n] formats as
. 
can be entered as 
surd
, and 
moves between the fields.- Surd can be used with Interval and CenteredInterval objects. »
Examples
open all close allBasic Examples (5)
Surd gives a real-valued root:
Surd[-32, 5]Plot over a subset of the reals:
Plot[{x, Surd[x, 3], Surd[x, 5], Surd[x, 7]}, {x, -1, 1}, PlotLegends -> "Expressions"]
, then use 
:Surd[-4.5, 3]Note that this is not the same as 
, which is Power[x,1/3]:
-4.5^(1/(3))Compare the real and imaginary parts of 
and 
over the reals:
ReImPlot[{x^(1/(3)), Surd[x, 3]}, {x, -4, 4}, PlotLegends -> Automatic]Series[Surd[x, 3], {x, 1, 3}]Scope (31)
Numerical Evaluation (5)
Surd[5., 3]N[Surd[2, 8], 50]The precision of the output tracks the precision of the input:
Surd[-2.1564564564564641111400000000, 5]Evaluate efficiently at high precision:
Surd[8.3`100, 3]//TimingSurd[8.3`10000000, 3];//TimingCompute the elementwise values of an array using automatic threading:
Surd[{{1 / 2, -1}, {0, 1 / 2}}, 3]Or compute the matrix Surd function using MatrixFunction:
MatrixFunction[Surd[#, 3]&, {{1 / 2, -1}, {0, 1 / 2}}]//FullSimplifyCompute worst-case guaranteed intervals using Interval and CenteredInterval objects:
Surd[Interval[{0.5, 0.6}], 2]Surd[CenteredInterval[2, 1 / 100], 3]Or compute average-case statistical intervals using Around:
Surd[ Around[2, 0.01], 2]Specific Values (4)
Table[Surd[x, 3], {x, -2, 2}]Surd[x, 2]Surd[4, n]Surd[∞, 2]Surd[-∞, 3]Surd[∞, -3]Find a value of x for which (![RadicalBox[x, 2, MultilineFunction -> None, SurdForm -> True]](Files/Surd.en/31.png "RadicalBox[x, 2, MultilineFunction -> None, SurdForm -> True]"){kind=small}
)=1.5:
FindRoot[Surd[x, 2] == 1.5, {x, 1}]xval = x /. First[%]Plot[Surd[x, 2], {x, 0, 5}, Epilog -> Style[Point[{xval, Surd[xval, 2 ]}], PointSize[Large], Red]]Visualization (4)
Plot the Surd function for various orders:
Plot[{Surd[x, 1], Surd[x, 2], Surd[x, 3], Surd[x, 4]}, {x, 0, 3}, PlotLegends -> "Expressions"]Visualize the absolute value and argument (sign) of 
for odd n:
AbsArgPlot[{Surd[x, 3], Surd[x, 5], Surd[x, 7]}, {x, -1, 1}, PlotLegends -> Automatic]The function 
has the same absolute value but a different argument for 
:
AbsArgPlot[{x^(1/(3)), x^(1/(5)), x^(1/(7))}, {x, -1, 1}, PlotLegends -> Automatic]Compare the real and imaginary parts of 
and 
for even n:
ReImPlot[{x^(1/(6)), Surd[x, 6]}, {x, -4, 4}, PlotLegends -> Automatic]//Quiet
PolarPlot[Surd[ϕ, 3], {ϕ, 0, 6 π}, Frame -> True]Function Properties (8)
Surd[x,n] is defined for all real x when n is a positive, odd integer:
FunctionDomain[Surd[x, 3], x]For positive, even n, it is defined for non-negative x:
FunctionDomain[Surd[x, 4], x]For negative n, 0 is removed from the domain:
FunctionDomain[Surd[x, -2], x]Surd is not defined for nonreal complex values:
FunctionDomain[Surd[z, -2], z, ℂ]Surd[x,n] achieves all non-negative real values when n is a positive even integer:
FunctionRange[Surd[x, 2], x, y]For positive odd n, its range is the whole real line:
FunctionRange[Surd[x, 3], x, y]For negative n, 0 is removed from the range:
FunctionRange[Surd[x, -3], x, y]Surd[x,n] is not an analytic function of x for any integer n:
{FunctionAnalytic[Surd[x, -3], x], FunctionAnalytic[Surd[x, -2], x], FunctionAnalytic[Surd[x, 3], x], FunctionAnalytic[Surd[x, 4], x]}
FunctionMonotonicity[Surd[x, 2n], x, NonNegativeReals, Assumptions -> n∈Integers && n > 0, StrictInequalities -> True]FunctionMonotonicity[Surd[x, 2n + 1], x, Assumptions -> n∈Integers && n > 0, StrictInequalities -> True]Decreasing for negative even 
:
FunctionMonotonicity[Surd[x, 2n], x, PositiveReals, Assumptions -> n∈Integers && n < 0, StrictInequalities -> True]
FunctionMonotonicity[{Surd[x, 2n + 1], x ≠ 0}, x, Assumptions -> n∈Integers && n < 0, StrictInequalities -> True]
FunctionInjective[Surd[x, n], x, Assumptions -> n∈Integers && n != 0]
Plot[{Surd[x, 5], 1}, {x, -5, 5}]And it is surjective onto 
for odd, positive 
, but not other values of 
:
FunctionSurjective[Surd[x, 2n + 1], x, Assumptions -> n∈Integers && n > 0]FunctionSurjective[Surd[x, 2n], x, Assumptions -> n∈Integers && n > 0]
Plot[{Surd[x, 4], -1}, {x, -5, 5}]//Quiet
FunctionSign[{Surd[x, 2n + 1], x ≠ 0}, x, Assumptions -> n∈Integers]It is non-negative on its real domain for even 
:
FunctionSign[{Surd[x, 2n], x > 0}, x, Assumptions -> n∈Integers && n ≠ 0]
in general has both singularities and discontinuities at zero:
{FunctionSingularities[Surd[x, 4], x], FunctionSingularities[Surd[x, 5], x]}However, for positive odd 
it is continuous at the origin:
FunctionDiscontinuities[Surd[x, 5], x]
is neither convex nor concave for odd 
:
{FunctionConvexity[Surd[x, 5], x], FunctionConvexity[{Surd[x, -5], x ≠ 0}, x]}On its domain of definition, it is concave for positive even 
and convex of negative even 
:
{FunctionConvexity[{Surd[x, 6], x >= 0}, x], FunctionConvexity[{Surd[x, -6], x > 0}, x]}Differentiation (3)
The first derivative with respect to x:
D[Surd[x, 3], x]Higher derivatives with respect to x:
Table[D[Surd[x, 2], {x, k}], {k, 1, 3}]//FullSimplifyPlot the higher derivatives with respect to x:
Plot[%, {x, 0, 4}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative"}]Formula for the 
derivative with respect to x:
D[Surd[x, 2], {x, k}]// FullSimplifyIntegration (3)
Compute the indefinite integral using Integrate:
∫Surd[x, 2]ⅆxFullSimplify[D[%, x] == Surd[x, 2], x > 0]Subsuperscript[∫, 0, 1]Surd[x, 5]ⅆxIntegrate[ x Surd[x, 2], x]//FullSimplifyIntegrate[x Surd[x^2, 3], {x, 0, 4}]//FullSimplifySeries Expansions (4)
Find the Taylor expansion using Series:
Series[Surd[x, 3], {x, -1, 4}]Plots of the first three approximations around 
:
terms = Normal@Table[Series[Surd[x, 3], {x, -1, m}], {m, 1, 5, 2}];
Plot[{Surd[x, 3], terms}, {x, -3, 1}]General term in the series expansion using SeriesCoefficient:
SeriesCoefficient[Surd[x, 3], {x, 1, m}]The first-order Fourier series:
FourierSeries[Surd[x, 3], x, 1]// FullSimplifyThe Taylor expansion at a generic point:
Series[Surd[x, 3], {x, x0, 2}]// FullSimplifyApplications (1)
With 
, the real vector field corresponding to the complex function 
is 
, and the trajectories that follow the field satisfy the differential equation 
. The implicit solution is 
for real 
, which corresponds to a family of circles that are tangent to the real axis at the origin:
Show[ContourPlot[(x^2/y) + y, {x, -3, 3}, {y, -3, 3}, ContourShading -> None, ContourStyle -> Red, Contours -> Range[-8, 8]], ComplexStreamPlot[z^2, {z, -3 - 3I, 3 + 3I}, StreamColorFunction -> None]]In polar coordinates, the trajectories are 
for any real 
:
Show[PolarPlot[Evaluate@Table[c Sin[θ], {c, -3, 3}], {θ, 0, π}, PlotStyle -> Red], ComplexStreamPlot[z^2, {z, -3 - 3I, 3 + 3I}, StreamColorFunction -> None]]More generally, for 
where 
is an integer, the streamlines follow 
for constant 
:
Block[{n = 4},
Show[PolarPlot[Evaluate@Table[c Surd[Sin[(n - 1)θ], n - 1], {c, -3, 3}], {θ, 0, π}, PlotStyle -> Red], ComplexStreamPlot[z^n, {z, -3 - 3I, 3 + 3I}, StreamColorFunction -> None]]]This also works for negative powers:
Block[{n = -4}, Show[PolarPlot[Evaluate@Table[c Surd[Sin[(n - 1)θ], n - 1], {c, -3, 3}], {θ, 0, 2π}, PlotStyle -> Red], ComplexStreamPlot[z^n, {z, -3 - 3I, 3 + 3I}, StreamColorFunction -> None], PlotRange -> 3]]For odd powers, care must be taken to ensure the first argument to Surd is non-negative:
Block[{n = 3}, Show[PolarPlot[Evaluate@Table[c Surd[RealAbs[Sin[(n - 1)θ]], n - 1], {c, -3, 3}], {θ, 0, 2π}, PlotStyle -> Red], ComplexStreamPlot[z^n, {z, -3 - 3I, 3 + 3I}, StreamColorFunction -> None], PlotRange -> 3]]Properties & Relations (3)
Surd[x,n] is only defined for real x and integer n:
FunctionDomain[Surd[x, n], x, Complexes]Surd[x,n] is a bijection onto its domain of definition for every nonzero integer n:
bijection[f_, x_] := FunctionBijective[{f, FunctionDomain[f, x], FunctionRange[f, x, y]}, x, y]{bijection[Surd[x, 4], x], bijection[Surd[x, -5], x]}Use Surd[x,n] to find the 
real root:
Surd[-16., 4]
Surd[-32., 5]Use Power[x,1/n] or 
to find the principle complex root:
(-16.)^1 / 4-32.^(1/(5))Possible Issues (1)
On the negative real axis, Surd[x,n] is undefined for even n:
Surd[-3, 2]
On the negative real axis, Surd[x,n] is different from the principal root returned by Power[x,1/n]:
Manipulate[ParametricPlot[Evaluate[{Re[#], Im[#]}& /@ {Surd[x, n], Power[x, 1 / n]}], {x, 0, -1}, PlotStyle -> Thickness[.025], PlotRange -> {{-1, 1}, {0, 1}}, Exclusions -> None], {{n, 3}, 3, 21, 2, Appearance -> "Labeled", ImageSize -> Small}]Neat Examples (1)
Plot a composition of Surd:
Plot[Evaluate[Nest[Surd[1 + #, 3]&, x, 5]], {x, -5, 5}]Related Links
MathWorldText
Wolfram Research (2012), Surd, Wolfram Language function, https://reference.wolfram.com/language/ref/Surd.html.
CMS
Wolfram Language. 2012. "Surd." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/Surd.html.
APA
Wolfram Language. (2012). Surd. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Surd.html