WOLFRAM

Wolfram Language & System Documentation Center

Scale[g,s]

represents graphics primitives g scaled by a factor s.

Scale[g,s,{x,y,…}]

scales with the point {x,y,…} kept fixed.

Scale[g,{sx,sy,…},…]

scales by different factors along different axes.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Generalizations & Extensions  
Properties & Relations  
Possible Issues  
Neat Examples  
See Also
Related Guides
Related Workflows
Related Links
History
Cite this Page

Scale

Scale[g,s]

represents graphics primitives g scaled by a factor s.

Scale[g,s,{x,y,…}]

scales with the point {x,y,…} kept fixed.

Scale[g,{sx,sy,…},…]

scales by different factors along different axes.

Details

  • Scale[g,s] scales with the center of the bounding box of g kept fixed.
  • You can specify special points such as {Left,Bottom} within the bounding box for g to be kept fixed.
  • The x position can be specified as Left, Center, or Right; the y position as Bottom, Center, or Top.
  • Explicit coordinates {x,y} are taken to be in the coordinate system of the graphic in which Scale[…] appears.
  • For objects specified with scaled coordinates Scaled[{x,y}], Scale effectively applies its transformation to the corresponding ordinary coordinates.
  • Scale can modify the regions allocated to Text and Inset objects, but does not directly affect their contents, and does not scale fonts or other textual elements. »
  • Normal[expr] if possible replaces all Scale[gi,…] constructs by versions of the gi in which the coordinates have explicitly been transformed.

Examples

open all close all

Basic Examples  (2)

Transform a 2D shape:

Wolfram Language code: Graphics[{Pink, Scale[Disk[], {1, 1 / 2}]}]

Transform a 3D shape:

Wolfram Language code: Graphics3D[Scale[Cylinder[], {1 / 2, 1, 1}, {0, 0, 0}], Boxed -> False]

Scope  (6)

Transformation applied to a 2D shape:

Wolfram Language code: gr = {Rectangle[], AbsolutePointSize[10], Opacity[1], {Magenta, Point[{0, 0}]}, {Green, Point[{1, 1}]}};
Wolfram Language code: Graphics[{{Opacity[.35], Blue, gr}, Scale[{Opacity[.85], Red, gr}, .5]}]

Transformation applied to a 3D shape:

Wolfram Language code: gr = {Cuboid[], AbsolutePointSize[10], Opacity[1], {Magenta, Point[{0, 0, 0}]}, {Green, Point[{1, 1, 1}]}};
Wolfram Language code: Graphics3D[{{Opacity[.35], Blue, gr}, Scale[{Opacity[.85], Red, gr}, .5, {.5, .5, .5}]}, Boxed -> False]

The transformations can be nested:

Wolfram Language code: Graphics3D[Scale[Rotate[Cuboid[], {{1, 1, 1}, {0, 0, 1}}], {1, 1, 1.5}, {0, 0, 0}], Boxed -> False]

Apply transformation to scaled coordinates:

Wolfram Language code: Graphics[Scale[Circle[Scaled[{1, 0}]], 2], Axes -> True]

Keep the point fixed:

Wolfram Language code: Graphics[Scale[Circle[Scaled[{1, 0}]], .5, {1, 0}], Axes -> True]

Keep the top-left corner of the circle's bounding box fixed:

Wolfram Language code: Graphics[Scale[Circle[Scaled[{1, 0}]], .5, {Left, Top}], Axes -> True]

Generalizations & Extensions  (2)

Use Scale to flip text along the axis:

Wolfram Language code: Graphics[Scale[Text[Style["AaBbCc", 20, FontFamily -> "Helvetica"]], {-1, 1}]]

Flip along the axis:

Wolfram Language code: Graphics[Scale[Text[Style["AaBbCc", 20, FontFamily -> "Helvetica"]], {1, -1}]]

The size of text is affected by Scale only when it is specified using Scaled:

Wolfram Language code: Table[Graphics[Scale[Text[Style["AaBbCc", 20, FontSize -> Scaled[.1], FontFamily -> "Helvetica"]], s], PlotRange -> 1], {s, {{-1, 1}, {-2, 2}}}]

Properties & Relations  (1)

When possible, Normal will transform the coordinates explicitly:

Wolfram Language code: Normal@Scale[Cuboid[{x, y, z}], {1, 1, -1}, {0, 0, 0}]

Possible Issues  (1)

By default, scaling in 2D is done to keep the center of the bounding box fixed:

Wolfram Language code: Graphics[{Opacity[0.5], Scale[Rectangle[], .5]}, Axes -> True, PlotRange -> 1]

Explicitly set the origin to be fixed:

Wolfram Language code: Graphics[{Opacity[0.5], Scale[Rectangle[], .5, {0, 0}]}, Axes -> True, PlotRange -> 1]

Neat Examples  (1)

Projections of a cylinder:

Wolfram Language code: Graphics3D[Scale[Cylinder[], #, {0, 0, 0}]& /@ (1 + 10 ^ -3 - IdentityMatrix[3]), Boxed -> False]
Wolfram Research (2007), Scale, Wolfram Language function, https://reference.wolfram.com/language/ref/Scale.html (updated 2008).

Text

Wolfram Research (2007), Scale, Wolfram Language function, https://reference.wolfram.com/language/ref/Scale.html (updated 2008).

CMS

Wolfram Language. 2007. "Scale." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2008. https://reference.wolfram.com/language/ref/Scale.html.

APA

Wolfram Language. (2007). Scale. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Scale.html

BibTeX

@misc{reference.wolfram_2026_scale, author="Wolfram Research", title="{Scale}", year="2008", howpublished="\url{https://reference.wolfram.com/language/ref/Scale.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_scale, organization={Wolfram Research}, title={Scale}, year={2008}, url={https://reference.wolfram.com/language/ref/Scale.html}, note=[Accessed: 12-June-2026]}