VarianceGammaPointProcess[μ,λ,α,β,d]
represents a variance gamma cluster point process with density μ, cluster mean λ and shape parameters α and β in 
.
VarianceGammaPointProcess
VarianceGammaPointProcess[μ,λ,α,β,d]
represents a variance gamma cluster point process with density μ, cluster mean λ and shape parameters α and β in 
.
Details
- VarianceGammaPointProcess models clustered point configurations with centers uniformly distributed over space and cluster points isotropically distributed with a flexible radial distribution.
- Typical uses include cosmology and rainforest tree distribution.
- The cluster centers are placed according to PoissonPointProcess with density μ.
- The point count of a cluster is distributed according to PoissonDistribution with mean λ.
- The cluster points in each cluster in
are distributed according to VarianceGammaDistribution[α,
,0,0]. - The cluster points in
are distributed according to MultinormalDistribution[DiagonalMatrix[{u,u,…}]], with 
sampled from GammaDistribution[α,β] centered at a cluster center. - VarianceGammaPointProcess allows μ, λ, α and β to be any positive real numbers, and d to be any positive integer.
- The following settings can be used for PointProcessEstimator for estimating VarianceGammaPointProcess:
-
"FindClusters" use FindClusters function "MethodOfMoments" use a homogeneity measure to estimate the parameters - VarianceGammaPointProcess can be used with such functions as RipleyK, PointCountDistribution and RandomPointConfiguration.
Examples
open all close allBasic Examples (4)
Sample from a variance gamma point process over a unit disk:
pts = RandomPointConfiguration[VarianceGammaPointProcess[10, 20, .2, .3, 2], Disk[]]Show[RegionPlot[pts["ObservationRegion"]], ListPlot[pts]]Sample from a variance gamma point process over a unit ball:
pts = RandomPointConfiguration[VarianceGammaPointProcess[30, 20, .1, .1, 3], Ball[]]Show[RegionPlot3D[pts["ObservationRegion"], PlotStyle -> Opacity[.2], Boxed -> False], ListPointPlot3D[pts, AspectRatio -> 1]]Sample from a variance gamma point process over a geo region:
proc = VarianceGammaPointProcess[.01, .6, .1, .2, 2];pts = RandomPointConfiguration[proc, Entity["Country", "Slovakia"]]GeoListPlot[pts]Pair correlation function of a variance gamma point process:
pcf = PairCorrelationG[VarianceGammaPointProcess[μ, λ, α, β, 3], r]Visualize the function with given parameter values:
Plot[pcf /. {μ -> 3, λ -> 2, α -> 1, β -> 1 / 2}, {r, 0, 3}]Scope (2)
Sample from any valid RegionQ, whose RegionEmbeddingDimension is equal to its RegionDimension:
ℛ = ImplicitRegion[x ^ 2 - 2y ^ 2 <= 1, {{x, -3, 3}, {y, -4, 4}}];{RegionQ[ℛ], RegionEmbeddingDimension[ℛ] == RegionDimension[ℛ]}pts = RandomPointConfiguration[VarianceGammaPointProcess[4, 15, .2, .3, 2], ℛ]Show[RegionPlot[pts["ObservationRegion"]], ListPlot[pts]]Simulate a point configuration from a variance gamma point process:
proc = VarianceGammaPointProcess[20, 30, .3, .2, 2];
points = RandomPointConfiguration[proc, Rectangle[]];PointValuePlot[points]Use the "FindClusters" method to estimated a point process model:
est = EstimatedPointProcess[points, VarianceGammaPointProcess[a, b, c1, c2, d], PointProcessEstimator -> "FindClusters"]Compare Ripley's 
measure between the original process and the estimated model:
DiscretePlot[{RipleyK[proc, r], RipleyK[est, r]}, {r, 0.1, .5, .005}, PlotLegends -> {"original process", "estimated model"}]Properties & Relations (5)
The PointCountDistribution is known:
proc = VarianceGammaPointProcess[4, 15, .4, .3, 2];dist = PointCountDistribution[proc, Disk[]]{Mean[dist], Variance[dist]}DiscretePlot[PDF[dist, x], {x, 0, 400, 5}]sample = RandomVariate[dist, 10 ^ 4];The probability density histogram:
Histogram[sample, 30, "PDF"]Ripley's 
and Besag's 
for a variance gamma point process in 2D:
proc = VarianceGammaPointProcess[μ, λ, α, β, 2];RipleyK[proc, r]BesagL[proc, r]Block[{μ = 20, λ = 10, α = .5, β = .3},
Plot[{RipleyK[proc][r], BesagL[proc][r]}, {r, 0, 1}, PlotLegends -> {"Ripley's K", "Besag's L"}]]Ripley's 
of a variance gamma point process is larger than for a Poisson point process:
proc = VarianceGammaPointProcess[μ, λ, α, β, d];RipleyK[proc][r]Compare to a Poisson point process:
pproc = PoissonPointProcess[μ, d];RipleyK[pproc][r]Besag's 
of a variance gamma point process is larger than for a Poisson point process:
proc = VarianceGammaPointProcess[μ, λ, α, β, d];BesagL[proc][r]//SimplifyCompare to a Poisson point process:
pproc = PoissonPointProcess[μ, d];BesagL[pproc][r]The pair correlation of a variance gamma point process is larger than 1:
pc = PairCorrelationG[VarianceGammaPointProcess[μ, λ, α, β, d], r]Compare to a homogeneous Poisson point process:
PairCorrelationG[PoissonPointProcess[μ, d], r]Text
Wolfram Research (2020), VarianceGammaPointProcess, Wolfram Language function, https://reference.wolfram.com/language/ref/VarianceGammaPointProcess.html.
CMS
Wolfram Language. 2020. "VarianceGammaPointProcess." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/VarianceGammaPointProcess.html.
APA
Wolfram Language. (2020). VarianceGammaPointProcess. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/VarianceGammaPointProcess.html