Wolfram Language & System Documentation Center

RegionDimension

RegionDimension[reg]

gives the geometric dimension of the region reg.

Details and Options

The geometric dimension d of reg is the largest d such that a d-dimensional ball can be completely embedded in the region.
Typical names for regions of different dimensions include:
0 points

1 lines, curves, arcs, segments, intervals

2 planes, surfaces

3 solids, volumes
Example cases with rows corresponding to embedding dimension and columns to RegionDimension:

RegionDimension takes an Assumptions option that can be used to specify assumptions on parameters.

Examples

open all close all

Basic Examples (4)

The dimension of regions in :

Wolfram Language code: RegionDimension[Point[{0}]]

Wolfram Language code: RegionDimension[Interval[{1, 2}]]

The dimension of regions in :

Wolfram Language code: RegionDimension[Point[{0, 0}]]

Wolfram Language code: RegionDimension[Line[{{0, 0}, {1, 1}}]]

Wolfram Language code: RegionDimension[Rectangle[]]

The dimension of regions in :

Wolfram Language code: RegionDimension[Point[{0, 0, 0}]]

Wolfram Language code: RegionDimension[Line[{{0, 0, 0}, {1, 1, 1}}]]

Wolfram Language code: RegionDimension[Sphere[]]

Wolfram Language code: RegionDimension[Ball[]]

The dimension of regions in :

Wolfram Language code: RegionDimension[Point[{0, 0, 0, 0}]]

Wolfram Language code: RegionDimension[Line[{{0, 0, 0, 0}, {1, 1, 1, 1}}]]

Wolfram Language code: RegionDimension[InfinitePlane[{{0, 0, 0, 0}, {1, 0, 0, 0}, {0, 1, 0, 0}}]]

Wolfram Language code: RegionDimension[Sphere[{0, 0, 0, 0}, 1]]

Wolfram Language code: RegionDimension[Ball[{0, 0, 0, 0}, 1]]

Scope (19)

Special Regions (4)

Regions in including Point:

Wolfram Language code: RegionDimension[Point[{{0}, {1}}]]

Interval:

Wolfram Language code:

ℛ = Interval[{1, 2}];
NumberLinePlot[ℛ]

Wolfram Language code: RegionDimension[ℛ]

Regions in including Point:

Wolfram Language code:

ℛ = Point[Tuples[Range[5], 2]];
Region[ℛ]

Wolfram Language code: RegionDimension[ℛ]

Line:

Wolfram Language code:

ℛ = Line[{{1, 2}, {4, 3}}];
Region[ℛ]

Wolfram Language code: RegionDimension[ℛ]

Circle:

Wolfram Language code:

ℛ = Circle[{1, 2}, 3];
Region[ℛ]

Wolfram Language code: RegionDimension[ℛ]

Disk:

Wolfram Language code:

ℛ = Disk[{1, 2}, {4, 3}];
Region[ℛ]

Wolfram Language code: RegionDimension[ℛ]

Regions in including Point:

Wolfram Language code:

ℛ = Point[Tuples[Range[5], 3]];
Region[ℛ]

Wolfram Language code: RegionDimension[ℛ]

Line:

Wolfram Language code:

ℛ = Line[{{1, 2, 3}, {6, 5, 4}}];
Region[ℛ]

Wolfram Language code: RegionDimension[ℛ]

Polygon:

Wolfram Language code:

ℛ = Polygon[{{0, 0, 0}, {(5/3), (2/3), -(4/3)}, {(2/3), (2/3), -(1/3)}, {1, 2, 0}}];
Region[ℛ]

Wolfram Language code: RegionDimension[ℛ]

Cylinder:

Wolfram Language code:

ℛ = Cylinder[{{0, 0, 0}, {1, 1, 1}}, 2];
Region[ℛ]

Wolfram Language code: RegionDimension[ℛ]

Regions in including Simplex in :

Wolfram Language code: RegionDimension[Simplex[{{1, 0, 0, 0}, {0, 1, 0, 0}, {0, 0, 1, 0}, {0, 0, 0, 1}}]]

Cuboid in :

Wolfram Language code: RegionDimension[Cuboid[{1, 2, 3, 4, 5}, {6, 7, 8, 9, 10}]]

Ball in :

Wolfram Language code: RegionDimension[Ball[{1, 2, 3, 4, 5, 6, 7}, 8]]

Formula Regions (3)

The dimension of a disk represented as an ImplicitRegion:

Wolfram Language code: ℛ = ImplicitRegion[x^2 + y^2 ≤ 1, {x, y}];

Wolfram Language code: Region[ℛ]

Wolfram Language code: RegionDimension[ℛ]

A cylinder:

Wolfram Language code: RegionDimension[ImplicitRegion[x^2 + y^2 ≤ 1, {x, y, {z, 0, 2}}]]

The dimension of a disk represented as a ParametricRegion:

Wolfram Language code: RegionDimension[ParametricRegion[{r Cos[θ], r Sin[θ]}, {{r, 0, 1}, {θ, 0, 2π}}]]

Using a rational parametrization of the disk:

Wolfram Language code: RegionDimension[ParametricRegion[{r(1 - t^2/1 + t^2), r(2t/1 + t^2)}, {t, {r, 0, 1}}]]

A cylinder:

Wolfram Language code: RegionDimension[ParametricRegion[{r Cos[θ], r Sin[θ], z}, {{r, 0, 1}, {θ, 0, 2π}, {z, 0, 2}}]]

ImplicitRegion can have several components of different dimension:

Wolfram Language code: ℛ = ImplicitRegion[x^2 + y^2 ≤ 1∨x == y, {x, y}];

Wolfram Language code: DiscretizeRegion[ℛ, {{-2, 2}, {-2, 2}}]

RegionDimension gives the largest dimension:

Wolfram Language code: RegionDimension[ℛ]

Mesh Regions (4)

The dimension of a BoundaryMeshRegion:

Wolfram Language code: BoundaryMeshRegion[{{0}, {1}}, Point[{{1}, {2}}]]

Wolfram Language code: RegionDimension[%]

In 2D:

Wolfram Language code: ConvexHullMesh[RandomReal[1, {10, 2}]]

Wolfram Language code: RegionDimension[%]

In 3D:

Wolfram Language code: ConvexHullMesh[RandomReal[1, {20, 3}]]

Wolfram Language code: RegionDimension[%]

The dimension of a MeshRegion:

Wolfram Language code: DelaunayMesh[RandomReal[1, {10, 2}]]

Wolfram Language code: RegionDimension[%]

A 3D mesh in 3D:

Wolfram Language code: DelaunayMesh[RandomReal[1, {20, 3}]]

Wolfram Language code: RegionDimension[%]

A 1D mesh embedded in 2D:

Wolfram Language code: MeshRegion[{{0, 0}, {1, 0}, {2, -1}, {2, 1}}, {Line[{{1, 2, 3, 4, 2}}]}]

Wolfram Language code: RegionDimension[%]

A MeshRegion can have components of different dimension:

Wolfram Language code: MeshRegion[{{0, 0}, {1, 0}, {2, -1}, {2, 1}}, {Line[{{1, 2}}], Polygon[{{2, 3, 4}}]}]

The RegionDimension is the largest dimension:

Wolfram Language code: RegionDimension[%]

Derived Regions (4)

The dimension of a RegionIntersection:

Wolfram Language code: ℛ = RegionIntersection[Disk[{0, 0}, 1], Disk[{0, 1}, 1]];

Wolfram Language code: Region[ℛ]

Wolfram Language code: RegionDimension[ℛ]

The dimension of a TransformedRegion:

Wolfram Language code: ℛ = TransformedRegion[Disk[{0, 0}, 1], ScalingTransform[{3, 2}]];

Wolfram Language code: DiscretizeRegion[ℛ, {{-3, 3}, {-2, 2}}]

Wolfram Language code: RegionDimension[ℛ]

The dimension of a RegionBoundary:

Wolfram Language code: ℛ = RegionBoundary[Ball[]];

Wolfram Language code: Region[ℛ]

RegionBoundary for a full-dimensional region is less than the original dimension:

Wolfram Language code: {RegionDimension[ℛ], RegionDimension[Ball[]]}

RegionDimension for an intersection can be less than the original dimensions:

Wolfram Language code: {Subscript[ℛ, 1], Subscript[ℛ, 2]} = {Rectangle[{0, 0}, {1, 1}], Rectangle[{1, 0}, {2, 1}]};

Wolfram Language code: ℬ = RegionIntersection[Subscript[ℛ, 1], Subscript[ℛ, 2]];

Wolfram Language code: Graphics[{{LightBlue, Subscript[ℛ, 1]}, {LightRed, Subscript[ℛ, 2]}, Line[{{1, 0}, {1, 1}}]}]

Wolfram Language code: {RegionDimension[ℬ], RegionDimension[Subscript[ℛ, 1]], RegionDimension[Subscript[ℛ, 2]]}

The dimension can drop by more than one:

Wolfram Language code: {Subscript[ℛ, 1], Subscript[ℛ, 2]} = {Rectangle[{0, 0}, {1, 1}], Rectangle[{1, -1}, {2, 0}]};

Wolfram Language code: ℬ = RegionIntersection[Subscript[ℛ, 1], Subscript[ℛ, 2]];

Wolfram Language code: Graphics[{{LightBlue, Subscript[ℛ, 1]}, {LightRed, Subscript[ℛ, 2]}, Point[{1, 0}]}]

Wolfram Language code: {RegionDimension[ℬ], RegionDimension[Subscript[ℛ, 1]], RegionDimension[Subscript[ℛ, 2]]}

Geographic Regions (2)

Polygons with GeoPosition:

Wolfram Language code:

ℛ = Polygon[GeoPosition[{{{40.083441, -88.235716}, {40.083607, -88.257488}, {40.082603, -88.257149}, 
   {40.076136999999996, -88.25740499999999}, {40.076178, -88.270888}, {40.076516, -88.271558}, 
   {40.083686, -88.271512}, {40.083659999999995, -88.267046},  ... 33323}, {40.098112, -88.228687}, 
   {40.095216, -88.228627}, {40.095179, -88.238547}, {40.094480999999995, -88.238546}, 
   {40.094508999999995, -88.23267}, {40.094106, -88.232556}, {40.090666999999996, -88.232477}, 
   {40.090741, -88.235745}}}]];

Wolfram Language code: RegionDimension[ℛ]

Polygons with GeoPositionXYZ:

Wolfram Language code:

ℛ = Polygon[GeoPositionXYZ[{{{150451.6968462432, -4.884430486484052*^6, 4.085078564164219*^6}, 
   {148595.27532671497, -4.884475441490381*^6, 4.085092666620835*^6}, 
   {148626.35829777512, -4.884546311005128*^6, 4.0850073717259285*^6}, 
   {148618.5908634042 ... 7*^6, 4.0860187668081024*^6}, 
   {150697.56410771207, -4.8836599487428395*^6, 4.085984535480795*^6}, 
   {150711.88303095422, -4.883905546449982*^6, 4.0856924143435075*^6}, 
   {150433.15479548014, -4.883908845676418*^6, 4.0856987003255524*^6}}}]];

Wolfram Language code: RegionDimension[ℛ]

Polygons with GeoPositionENU:

Wolfram Language code:

ℛ = Polygon[GeoPositionENU[{{{3378.2547059731055, -3369.2234780923936, -0.7440009205072329}, 
   {1521.3211635380246, -3351.391253626573, -0.022340134218666208}, 
   {1550.2571145363192, -3462.8657556618973, -0.08899812728964207}, 
   {1528.5672303494055, -418 ... 63383291193, -0.37494203351275246}, 
   {3654.121991908476, -2566.7472331234085, -0.5214977847472255}, 
   {3375.420726854886, -2558.6597093173914, -0.3648706331350695}}}, 
 GeoPosition[{40.11379115639895, -88.2753251202516, -1.0415787873318691}]]];

Wolfram Language code: RegionDimension[ℛ]

Polygons with GeoGridPosition:

Wolfram Language code:

ℛ = Polygon[GeoGridPosition[{{{-0.9950503945490105, 1.2366760550756015}, 
   {-0.9952074890903578, 1.2369207053693891}, {-0.9952196732768064, 1.2369073327446167}, 
   {-0.9953160063787643, 1.236848436956935}, {-0.9954141759436825, 1.2369993898475449}, 
   {-0. ... 197645333103}, {-0.9949098578570917, 1.2368130881428654}, 
   {-0.9948663952535768, 1.2367477711687371}, {-0.9948714472169538, 1.2367426500757825}, 
   {-0.9949211061652593, 1.2367089232486177}, {-0.9949439717990124, 1.236746107097628}}}, "Bonne"]];

Wolfram Language code: RegionDimension[ℛ]

CSG Regions (1)

The dimension of a CSGRegion in 2D:

Wolfram Language code: ℛ = CSGRegion["Difference", {Disk[], Disk[{1 / 2, 1 / 2}]}]

Wolfram Language code: RegionDimension[ℛ]

3D:

Wolfram Language code: ℛ = CSGRegion["Difference", {Cube[2], Cylinder[{{1, 1, 1}, {1, -1, 1}}]}]

Wolfram Language code: RegionDimension[ℛ]

Subdivision Regions (1)

The dimension of a SubdivisionRegion in 2D:

Wolfram Language code: ℛ = SubdivisionRegion[Rectangle[]]

Wolfram Language code: RegionDimension[ℛ]

3D:

Wolfram Language code: ℛ = SubdivisionRegion[Tetrahedron[]]

Wolfram Language code: RegionDimension[ℛ]

Applications (8)

A zero-dimensional object is a collection of points:

Wolfram Language code: pts = Point[RandomReal[1, {70, 2}]];

Wolfram Language code: Region[pts]

Wolfram Language code: RegionDimension[pts]

A one-dimensional object is a collection of curves:

Wolfram Language code: lines = Table[Line[RandomReal[1, {2, 2}]], {40}];

Wolfram Language code: circles = Table[Circle[pt, 0.2], {pt, RandomReal[1, {10, 2}]}];

Wolfram Language code: curves = Join[lines, circles];

Wolfram Language code: Graphics[curves]

Wolfram Language code: RegionDimension[RegionUnion@@curves]

A two-dimensional object is a collection of surfaces:

Wolfram Language code: surfaces = {Disk[{-0.5, 0.5}, 0.3], Rectangle[{-1, 1}], Triangle[]};

Wolfram Language code: Graphics[surfaces]

Wolfram Language code: RegionDimension[RegionUnion@@surfaces]

Use RegionDimension to tell the difference between a volume and a surface:

Wolfram Language code: regs = {Ball[], Sphere[]};

Regions may be visually identical:

Wolfram Language code: Region /@ regs

But differ in dimensionality:

Wolfram Language code: RegionDimension /@ regs

Compute dimension of regions that cannot be visualized:

Wolfram Language code: ℛ = RegionProduct[Ball[], Cuboid[{0, 0, 0}, {1, 1, 1}]];

Wolfram Language code: RegionDimension[ℛ]

The unit for RegionMeasure is with the length unit and :

Wolfram Language code: len = 2;

Wolfram Language code: regs = {Line[{{0, 0}, {0, len}}], Rectangle[{0, 0}, {len, len}], Cuboid[{0, 0, 0}, {len, len, len}]};

Compute the measure of each region:

Wolfram Language code: dims = RegionDimension /@ regs

Wolfram Language code: len ^ dims

Compare with the result from RegionMeasure:

Wolfram Language code: RegionMeasure /@ regs

Extract MeshRegion primitives by dimension using MeshPrimitives:

Wolfram Language code: ℛ = MeshRegion[{{0, 0, 0}, {2, 0, 0}, {2, 2, 0}, {0, 2, 0}, {1, 1, 2}}, Tetrahedron[{{1, 2, 3, 5}, {1, 3, 4, 5}}]]

Wolfram Language code: prims = Table[MeshPrimitives[ℛ, d], {d, {0, 1, 2}}];

Wolfram Language code: Table[Graphics3D[p, Boxed -> False], {p, prims}]

Wolfram Language code: RegionDimension /@ RegionUnion@@@prims

Select only full-dimensional primitives:

Wolfram Language code: prims = {Line[{{1}, {3}}], Line[{{0, 0}, {1, 1}}], Circle[], Disk[]};

Wolfram Language code: Select[prims, RegionDimension[#] === RegionEmbeddingDimension[#]&]

Properties & Relations (8)

RegionDimension gives the largest dimension among parts of varying dimension:

Wolfram Language code: mr = MeshRegion[{{0, 0}, {1, 0}, {2, 0}, {3, -1 / 2}, {3, 1 / 2}}, {Point[{1}], Line[{2, 3}], Polygon[{3, 4, 5}]}]

The RegionDimension is the largest dimension:

Wolfram Language code: RegionDimension[mr]

RegionEmbeddingDimension is the dimension of the space in which a region exists:

Wolfram Language code: ℛ = Circle[];

Wolfram Language code: {RegionDimension[ℛ], RegionEmbeddingDimension[ℛ]}

It is always greater than or equal to RegionDimension:

Wolfram Language code: ℛ = Ball[{0, 0, 0, 0}, 1];

Wolfram Language code: {RegionDimension[ℛ], RegionEmbeddingDimension[ℛ]}

DimensionalMeshComponents separates a mesh in different dimensional parts:

Wolfram Language code: mr = MeshRegion[{{0, 0}, {1, 0}, {2, 0}, {3, -1 / 2}, {3, 1 / 2}}, {Point[{1}], Line[{2, 3}], Polygon[{3, 4, 5}]}]

Wolfram Language code: dmc = DimensionalMeshComponents[mr]

Wolfram Language code: RegionDimension /@ dmc

RegionMeasure and RegionCentroid are dimension dependent:

Wolfram Language code: p = {Line[{{0, 0}, {2, 2}}], Rectangle[{0, 0}, {2, 2}], Cuboid[{0, 0, 0}, {2, 2, 2}]};

Wolfram Language code: RegionDimension /@ p

Wolfram Language code: c = RegionCentroid /@ p

Wolfram Language code: m = RegionMeasure /@ p

Integration over a region is dimension dependent:

Wolfram Language code: ℛ = Sphere[{1, 2, 3}]

Wolfram Language code: RegionDimension[ℛ]

Since the dimension is 2, integration corresponds to a surface integral:

Wolfram Language code: Integrate[1, p∈ℛ]

Wolfram Language code: Area[ℛ]

The RegionDimension of a RegionBoundary is one less than that of the input:

Wolfram Language code: ℛ = Cuboid[{0, 0, 0}, {1, 1, 1}];

Wolfram Language code: RegionDimension /@ {ℛ, RegionBoundary[ℛ]}

The RegionDimension of a RegionUnion is equal to the largest input dimension:

Wolfram Language code: {r1, r2, r3} = {Disk[], Rectangle[], Line[{{4, 4}, {5, 5}}]};

Wolfram Language code: ℛ = RegionUnion[r1, r2, r3];

Wolfram Language code: RegionDimension[ℛ] == Max[RegionDimension /@ {r1, r2, r3}]

RegionDimension of a RegionIntersection is no larger than the smallest input dimension:

Wolfram Language code: ℛ = RegionIntersection[Disk[{0, 0}, 1], Disk[{0, 1}, 1]];

Wolfram Language code: Region[ℛ]

Wolfram Language code: RegionDimension[ℛ]

But it can be smaller:

Wolfram Language code: ℛ = RegionIntersection[Disk[{0, 0}, 1], Disk[{2, 0}, 1]];

Wolfram Language code: Graphics[{LightBlue, EdgeForm[Gray], Disk[{0, 0}, 1], Disk[{2, 0}, 1], Red, Point[{1, 0}]}]

Wolfram Language code: RegionDimension[ℛ]

Top

More Learning

Tech Support

Wolfram Solutions

Wolfram Solutions For Education

Get Started

Grow Your Skills

Work with Us

Educational Programs for Adults

Educational Programs for Youth

Read

RegionDimension

Details and Options

Examples

Basic Examples (4)

Scope (19)

Special Regions (4)

Formula Regions (3)

Mesh Regions (4)

Derived Regions (4)

Geographic Regions (2)

CSG Regions (1)

Subdivision Regions (1)

Applications (8)

Properties & Relations (8)

Text

CMS

APA

BibTeX

BibLaTeX

	0	points
	1	lines, curves, arcs, segments, intervals
	2	planes, surfaces
	3	solids, volumes

RegionDimension

Details and Options

Examples

Basic Examples (4)

Scope (19)

Special Regions (4)

Formula Regions (3)

Mesh Regions (4)

Derived Regions (4)

Geographic Regions (2)

CSG Regions (1)

Subdivision Regions (1)

Applications (8)

Properties & Relations (8)

See Also

Related Guides

History

Text

CMS

APA

BibTeX

BibLaTeX