WOLFRAM

Wolfram Language & System Documentation Center

WeakStationarity[proc]

gives conditions for the process proc to be weakly stationary.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Properties & Relations  
See Also
Related Guides
History
Cite this Page

WeakStationarity

WeakStationarity[proc]

gives conditions for the process proc to be weakly stationary.

Details

  • Weakly stationary processes are also known as wide-sense stationary or covariance stationary.
  • A random process proc is weakly stationary if its mean function is independent of time, and its covariance function is independent of time translation.

Examples

open all close all

Basic Examples  (3)

Check if a process is weakly stationary:

Wolfram Language code: WeakStationarity[WienerProcess[]]

Check if an autoregressive time series is weakly stationary:

Wolfram Language code: WeakStationarity[ARProcess[{.3, .1}, .2]]

Generate conditions for a time series to be weakly stationary:

Wolfram Language code: WeakStationarity[ARProcess[{a, b}, v]]

Scope  (6)

Check if an ARProcess is weakly stationary:

Wolfram Language code: WeakStationarity[ARProcess[{.8, .1}, .1]]

Check if the mean function is constant in time:

Wolfram Language code: Mean[ARProcess[{.8, .1}, .1][t]]

Check if the covariance function is a function of time difference:

Wolfram Language code: CovarianceFunction[ARProcess[{.8, .1}, .1], s, t]
Wolfram Language code: DiscretePlot3D[CovarianceFunction[ARProcess[{.8, .1}, .1], s, t], {s, 0, 10}, {t, 0, 10}, ExtentSize -> 1 / 2, ColorFunction -> "Rainbow"]

Compare covariance functions of stationary and nonstationary OrnsteinUhlenbeckProcess:

Wolfram Language code: plot = Plot3D[CovarianceFunction[#, s, t], {s, 0, 5}, {t, 0, 5}, ColorFunction -> "Rainbow"]&;
Wolfram Language code: {plot[OrnsteinUhlenbeckProcess[0, 1, 1 / 3]], plot[OrnsteinUhlenbeckProcess[0, 1, 1 / 3, 2]]}

Visualize conditions for an ARProcess to be weakly stationary:

Wolfram Language code: RegionPlot[Evaluate@WeakStationarity[ARProcess[{a, b}, v]], {a, -2, 2}, {b, -2, 2}, FrameLabel -> Automatic]

For three parameters:

Wolfram Language code: RegionPlot3D[Evaluate@WeakStationarity[ARProcess[{a, b, c}, v]], {a, -2, 2}, {b, -2, 2}, {c, -2, 2}, ViewPoint -> {0, -1, 2}, PlotPoints -> 50, AxesLabel -> Automatic]

Find a weakly stationary ARProcess:

Wolfram Language code: FindInstance[WeakStationarity[ARProcess[{a, b}, v]] && a ≠ 0 && b ≠ 0, {a, b}]

Check:

Wolfram Language code: WeakStationarity[ARProcess[{a, b}, v] /. %[[1]]]

Some processes known to be non-weakly stationary:

Wolfram Language code: WeakStationarity[WienerProcess[μ, σ]]
Wolfram Language code: WeakStationarity[GeometricBrownianMotionProcess[μ, σ, θ]]
Wolfram Language code: WeakStationarity[OrnsteinUhlenbeckProcess[μ, σ, θ, a]]

Some known weakly stationary processes:

Wolfram Language code: WeakStationarity[MAProcess[{a, b}, σ^2]]
Wolfram Language code: WeakStationarity[BernoulliProcess[p]]
Wolfram Language code: WeakStationarity[OrnsteinUhlenbeckProcess[μ, σ, θ]]
Wolfram Language code: Simplify[%, ProcessParameterAssumptions[OrnsteinUhlenbeckProcess[μ, σ, θ]]]

Properties & Relations  (4)

Every MAProcess without fixed initial conditions is weakly stationary:

Wolfram Language code: WeakStationarity[MAProcess[{Subscript[b, 1], Subscript[b, 2]}, v]]

Time series processes with fixed initial conditions are not weakly stationary:

Wolfram Language code: WeakStationarity@MAProcess[c, {b}, v, {x}]
Wolfram Language code: WeakStationarity@ARProcess[.3, {.1}, 1, {0}]

The conditions for an ARMAProcess to be weakly stationary depend only on the autoregressive parameters:

Wolfram Language code: WeakStationarity[ARMAProcess[{Subscript[a, 1], Subscript[a, 2]}, {Subscript[b, 1], Subscript[b, 2]}, v]]

ARIMAProcess may be weakly stationary:

Wolfram Language code: WeakStationarity[ARIMAProcess[{Subscript[a, 1], Subscript[a, 2]}, d, {Subscript[b, 1], Subscript[b, 2]}, v]]
Wolfram Research (2012), WeakStationarity, Wolfram Language function, https://reference.wolfram.com/language/ref/WeakStationarity.html.

Text

Wolfram Research (2012), WeakStationarity, Wolfram Language function, https://reference.wolfram.com/language/ref/WeakStationarity.html.

CMS

Wolfram Language. 2012. "WeakStationarity." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/WeakStationarity.html.

APA

Wolfram Language. (2012). WeakStationarity. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/WeakStationarity.html

BibTeX

@misc{reference.wolfram_2026_weakstationarity, author="Wolfram Research", title="{WeakStationarity}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/WeakStationarity.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_weakstationarity, organization={Wolfram Research}, title={WeakStationarity}, year={2012}, url={https://reference.wolfram.com/language/ref/WeakStationarity.html}, note=[Accessed: 13-June-2026]}