CovarianceFunction
CovarianceFunction[data,hspec]
estimates the covariance function at lags hspec from data.
CovarianceFunction[proc,hspec]
represents the covariance function at lags hspec for the random process proc.
CovarianceFunction[proc,s,t]
represents the covariance function at times s and t for the random process proc.
Details
- CovarianceFunction is also known as autocovariance function.
- The following specifications can be given for hspec:
-
τ at time or lag τ {τmax} unit spaced from 0 to τmax {τmin,τmax} unit spaced from τmin to τmax {τmin,τmax,d τ} from τmin to τmax in steps of d τ {{τ1,τ2,…}} use explicit {τ1,τ2,…} - CovarianceFunction at lag h for data with mean
and data values xi is given by: -
(xi+h-
)(xi-
)for scalar-valued data 
for vector-valued data - When data is TemporalData containing an ensemble of paths, the output represents the average across all paths.
- CovarianceFunction for a process proc with mean function μ[t] and value x[t] at time t is given by:
-
Expectation[(x[s]-μ[s])(x[t]-μ[t])] for a scalar-valued process Expectation[(x[s]-μ[s])⊗(x[t]-μ[t])] for a vector-valued process - The symbol ⊗ represents KroneckerProduct.
- CovarianceFunction[proc,h] is defined only if proc is a weakly stationary process and is equivalent to CovarianceFunction[proc,h,0].
- The process proc can be any random process, such as ARMAProcess and WienerProcess.
Examples
open all close allBasic Examples (4)
Estimate the covariance function at lag 2:
CovarianceFunction[{2, 3, 4, 3}, 2]The sample covariance function for a random sample from an autoregressive time series:
data = RandomFunction[ARProcess[{.2, .3, .4}, 1], {1, 10 ^ 4}];ListPlot[CovarianceFunction[data, {20}], Filling -> Axis, PlotRange -> All]Calculate the covariance function for a discrete-time process:
CovarianceFunction[BinomialProcess[p], s, t]DiscretePlot3D[Evaluate[% /. {p -> 2 / 3}], {s, 0, 10}, {t, 0, 10}, ExtentSize -> 1 / 2, ColorFunction -> "Rainbow"]Calculate the covariance function for a continuous-time process:
CovarianceFunction[WienerProcess[μ, σ], s, t]Plot3D[Evaluate[% /. {μ -> 1, σ -> 2}], {s, 0, 10}, {t, 0, 10}, ColorFunction -> "Rainbow"]Scope (13)
Empirical Estimates (7)
Estimate the covariance function for some data at lag 9:
CovarianceFunction[Range[10], 9]Obtain empirical estimates of the covariance function up to lag 9:
CovarianceFunction[Range[10], {9}]Compute the covariance function for lags 1 to 9 in steps of 2:
CovarianceFunction[Range[10], {1, 9, 2}]Compute the covariance function for a time series:
ts = TemporalData[TimeSeries, {{{-2.9904395734335427, -1.5547517217370468, -2.007044987914736,
-0.7114933373063236, -1.5920036118254968, 0.23183536513859127, 0.056774681349179124,
0.32394041932443046, 0.10382798659711348, -0.684046765274114, - ... 1687325555,
3.410933732368106, 2.5200924558212163, 2.008558601261935, 0.43151331467691206,
0.6249727955196763}}, {{1, 1000, 1}}, 1, {"Continuous", 1}, {"Discrete", 1}, 1,
{ValueDimensions -> 1, ResamplingMethod -> None}}, False, 10.1];The covariance function of a time series for multiple lags is given as a time series:
cov = CovarianceFunction[ts, {100}]ListPlot[cov, Filling -> Axis]Estimate the covariance function for an ensemble of paths:
data = RandomFunction[ARProcess[{.8}, 1], {0, 500}, 25]cov = CovarianceFunction[data, {50}];ListPlot[cov, Filling -> 0]Compare empirical and theoretical covariance functions:
proc = MAProcess[{.4, .3, .5, .6, .3}, 1.];data = RandomFunction[proc, {0, 5000}];ListPlot[CovarianceFunction[#, {10}]& /@ {proc, data}, Filling -> {1 -> {2}}, PlotStyle -> PointSize[Medium], PlotLegends -> {"process covariance", "sample covariance"}]Plot the cross-covariance for vector data:
proc = ARProcess[{{{.3, .1}, {.6, .3}}}, {{1, .3}, {.3, .6}}];
data = RandomFunction[proc, {100}];
cov = CovarianceFunction[data, {-6, 6}];Table[ListPlot[cov["Values"][[All, i, j]], Filling -> 0, PlotLabel -> {i, j}], {i, 1, 2}, {j, 1, 2}]Random Processes (6)
The covariance function for a weakly stationary discrete-time process:
CovarianceFunction[ARProcess[{a}, σ^2], s, t]DiscretePlot3D[Evaluate[% /. {a -> 2 / 3, σ -> 1}], {s, 0, 10}, {t, 0, 10}, ExtentSize -> 1 / 2, ColorFunction -> "Rainbow"]The covariance function only depends on the antidiagonal 
:
CovarianceFunction[ARProcess[{a}, σ^2], h]DiscretePlot[Evaluate[% /. {a -> 2 / 3, σ -> 1}], {h, 0, 10}, ExtentSize -> 1 / 2, ColorFunction -> "Rainbow", AxesLabel -> {h, None}]The covariance function for a weakly stationary continuous-time process:
CovarianceFunction[OrnsteinUhlenbeckProcess[μ, σ, θ], s, t]Plot3D[Evaluate[% /. {μ -> 1, σ -> 2, θ -> 1 / 3}], {s, 0, 10}, {t, 0, 10}, ColorFunction -> "Rainbow"]The covariance function only depends on the antidiagonal 
:
CovarianceFunction[OrnsteinUhlenbeckProcess[μ, σ, θ], h]Plot[Evaluate[% /. {μ -> 1, σ -> 2, θ -> 1 / 3}], {h, 0, 10}, ColorFunction -> "Rainbow", Filling -> Axis, AxesLabel -> {h, None}]The covariance function for a non-weakly stationary discrete-time process:
CovarianceFunction[BinomialProcess[p], s, t]DiscretePlot3D[Evaluate[% /. p -> 1 / 3], {s, 0, 10}, {t, 0, 10},
ExtentSize -> 1 / 2, ColorFunction -> "Rainbow"]The covariance function depends on both time arguments:
antidiagonals = CovarianceFunction[BinomialProcess[1 / 3], t, t + h]DiscretePlot[Evaluate@Table[antidiagonals, {t, 1, 4}], {h, 0, 6}, ExtentSize -> 1 / 2, PlotLegends -> (Row[{"t = ", #}]& /@ Range[1, 4]), AxesLabel -> {h, None}]The covariance function for a non-weakly stationary continuous-time process:
CovarianceFunction[PoissonProcess[μ], s, t]Plot3D[Evaluate[% /. μ -> 3], {s, 0, 10}, {t, 0, 10}, ColorFunction -> "Rainbow"]The covariance function depends on both time arguments:
antidiagonals = CovarianceFunction[PoissonProcess[3], t, t + h]Plot[Evaluate@Table[antidiagonals, {t, 1, 4}], {h, 0, 6}, AxesLabel -> {h, None}, PlotLegends -> (Row[{"t = ", #}]& /@ Range[1, 4])]The covariance function for some time-series processes:
proc1 = ARProcess[{.8}, 1];
proc2 = MAProcess[{-.4, -.7, .6, -1}, 1];
proc3 = SARMAProcess[{}, {}, {3, {.6}, {.1}}, 1];
proc4 = FARIMAProcess[{}, 1 / 3, {}, 1];DiscretePlot[CovarianceFunction[#, h], {h, 0, 15}, ExtentSize -> 1 / 2, PlotRange -> All, PlotLabel -> Head[#]]& /@ {proc1, proc2, proc3, proc4}Cross-covariance plots for a vector ARProcess:
proc = ARProcess[{{{.3, .1}, {.6, .3}}}, {{1, .3}, {.3, .6}}];
cov = CovarianceFunction[proc, h];Table[DiscretePlot[cov[[i, j]], {h, -6, 6}, ExtentSize -> 1 / 2, PlotLabel -> {i, j}], {i, 1, 2}, {j, 1, 2}]Applications (1)
Determine whether the following data is best modeled with an MAProcess or an ARProcess:
ListLinePlot[data = TemporalData[TimeSeries, {{{-1.4735257611469446, -0.9158187257309729, -1.9060205147226934,
-1.6174582169404574, -2.633459084244463, -2.104839842098871, -2.8701276893108894,
-2.4118183939601607, -0.5125633448622677, -1.2356329399850385, 1. ... 26394036266876, -0.16380797769527589, 0.3559909972777121,
1.5343047104249412, 0.10763337590714506}}, {{0, 100, 1}}, 1, {"Continuous", 1},
{"Discrete", 1}, 1, {ResamplingMethod -> {"Interpolation", InterpolationOrder -> 1}}}, False,
10.1]]It is difficult to determine the underlying process from sample paths:
candidates = {MAProcess[{.5, .4}, 1], ARProcess[{.5, .4}, 1]};SeedRandom[2];ListLinePlot[RandomFunction[#, {0, 100}]]& /@ candidatesThe covariance function of the data decays slowly:
ListPlot[CovarianceFunction[data, {10}], Filling -> 0]ARProcess is clearly a better candidate model than MAProcess:
ListPlot[CovarianceFunction[#, {10}], PlotLabel -> Head[#], Filling -> 0]& /@ candidatesProperties & Relations (14)
Sample covariance function is a biased estimator for the process covariance function:
proc = ARMAProcess[1, {5 / 6, -1 / 6}, {2 / 3}, 1];
paths = RandomFunction[proc, {0, n = 10}, 10 ^ 3];Calculate the sample covariance function:
CovarianceFunction[paths, {10}]scov = TimeSeriesMapThread[#2(n + 1) / (n + 1 - #1)&, %]Covariance function for the process:
cov = CovarianceFunction[proc, {10}]ListPlot[{scov, cov}, Filling -> 0, PlotLegends -> {"sample covariance", "process covariance"}]Covariance function for a process is the off-diagonal entry in the Covariance matrix:
𝒫 = WienerProcess[μ, σ];Covariance[𝒫[{s, t}], 1, 2]CovarianceFunction[𝒫, s, t]Simplify[%% - %, 0 < s < t]Sample covariance function at lag 0 is a variance estimator:
data = Range[10];
evar1 = CovarianceFunction[data, 0]Compare to the estimate using Variance:
evar2 = Variance[data]The scaling factors are different:
(10 evar1) / (9evar2)Sample covariance function is related to CorrelationFunction:
data = Range[10];CovarianceFunction[data, {9}]Scaled sample correlation function:
CorrelationFunction[data, {9}] (CovarianceFunction[data, 0])% - %%Sample covariance function is related to AbsoluteCorrelationFunction:
data = Range[10];
n = Length[data];CovarianceFunction[data, {n - 1}]AbsoluteCorrelationFunction[data - Mean[data], {n - 1}]% - %%Use Expectation to calculate the covariance function:
𝒫 = WienerProcess[μ, σ];
m[s_] := Mean[𝒫[s]]Expectation[(x[s] - m[s])(x[t] - m[t]), x𝒫, Assumptions -> s > 0 && t > 0]CovarianceFunction[𝒫, s, t]Simplify[% - %%, 0 < s < t]Covariance function for equal times reduces to Variance:
𝒫 = OrnsteinUhlenbeckProcess[μ, σ, θ];CovarianceFunction[𝒫, t, t]Variance[𝒫[t]]% - %%The covariance function 
is related to the AbsoluteCorrelationFunction 
:
𝒫 = WienerProcess[μ, σ];AbsoluteCorrelationFunction[𝒫, s, t]
CovarianceFunction[𝒫, s, t] + Mean[𝒫[s]] Mean[𝒫[t]]% - %%The covariance function is related to the Covariance:
𝒫 = WienerProcess[μ, σ];CovarianceFunction[𝒫, s, t]It is the off-diagonal entry in the covariance matrix:
Covariance[𝒫[{s, t}], 1, 2]Simplify[%% - %, 0 < s < t]The covariance function 
is related to the CorrelationFunction 
:
𝒫 = PoissonProcess[μ];
sd[s_] := StandardDeviation[𝒫[s]]CorrelationFunction[𝒫, s, t]For 
, the standard deviation function is 
:
CovarianceFunction[𝒫, s, t] / (sd[s] sd[t])% - %%//FullSimplify[#, s > 0 && t > 0]&Covariance function is invariant for ToInvertibleTimeSeries:
TimeSeriesInvertibility[proc = MAProcess[{2, 4}, 1]]iproc = ToInvertibleTimeSeries@procCovarianceFunction[#, s, t]& /@ {proc, iproc}Covariance function is invariant to centralizing:
data = RandomFunction[ARIMAProcess[{}, 1, {}, 1], {0, 100}];Mean[data]newdata = Standardize[data, Mean, 1&];ListPlot[CovarianceFunction[#, {20}], Filling -> 0]& /@ {data, newdata}PowerSpectralDensity of a time series is a transform of the covariance function:
proc = ARProcess[c, {a}, σ^2];
cf = CovarianceFunction[proc, h]ft = FourierSequenceTransform[cf, h, z]Compare to the power spectrum:
PowerSpectralDensity[proc, z]FullSimplify[% - ft]PowerSpectralDensity of data is a transform of the sample covariance function:
sample = Range[20];
n = Length[sample];
cov = CovarianceFunction[sample, {n - 1}];
cov = Join[Reverse[Rest[cov]], cov];Apply ListFourierSequenceTransform:
ListFourierSequenceTransform[cov, w, -n + 1]//ExpToTrigCompare to SamplePowerSpectralDensity:
PowerSpectralDensity[sample, w]% - %%//FullSimplifyPossible Issues (1)
CovarianceFunction output may contain DifferenceRoot:
CovarianceFunction[ARProcess[{a, b}, σ^2], t] //Simplify[#, t > 0]&Use FunctionExpand to recover explicit powers:
%//FunctionExpandText
Wolfram Research (2012), CovarianceFunction, Wolfram Language function, https://reference.wolfram.com/language/ref/CovarianceFunction.html.
CMS
Wolfram Language. 2012. "CovarianceFunction." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/CovarianceFunction.html.
APA
Wolfram Language. (2012). CovarianceFunction. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/CovarianceFunction.html