AbsoluteCorrelation[dist,i,j]
gives the (i,j)
absolute correlation for the multivariate symbolic distribution dist.
AbsoluteCorrelation
AbsoluteCorrelation[v,w]
gives the absolute correlation between the vectors v and w.
AbsoluteCorrelation[a,b]
gives the absolute cross-correlation matrix for the matrices a and b.
gives the absolute correlation matrix for the matrix a.
AbsoluteCorrelation[dist]
gives the absolute correlation matrix for the multivariate symbolic distribution dist.
AbsoluteCorrelation[dist,i,j]
gives the (i,j)
absolute correlation for the multivariate symbolic distribution dist.
Details
- AbsoluteCorrelation[v,w] gives the unbiased estimate of the absolute correlation.
- For centralized (zero mean) vectors, AbsoluteCorrelation computes Covariance.
- For standardized (zero mean and unit variance) vectors, AbsoluteCorrelation computes Correlation.
- For vectors
and 
of length 
, the absolute correlation estimate AbsoluteCorrelation[v,w] is given by 
. - For matrices
and 
with dimensions 
and 
and columns indexed as 
and 
, respectively, AbsoluteCorrelation[a,b] is a 
matrix with elements given by 
. -
- For a matrix
with 
columns, AbsoluteCorrelation[a] is a 
matrix given by AbsoluteCorrelation[a, a]. - AbsoluteCorrelation works with any vector that is VectorQ or matrix that is MatrixQ.
- AbsoluteCorrelation[dist,i,j] gives Expectation[xixj,{x1,x2,…}∈dist].
- AbsoluteCorrelation[dist] gives an absolute correlation matrix with the (i,j)
entry given by AbsoluteCorrelation[dist,i,j].
Examples
open all close allBasic Examples (3)
Absolute correlation between two vectors:
AbsoluteCorrelation[{a, b}, {x, y}]Absolute correlation matrix for a matrix:
AbsoluteCorrelation[{{a, b}, {c, d}}]//MatrixFormAbsolute correlation matrix for two matrices:
AbsoluteCorrelation[{{a, b}, {c, d}}, {{x}, {y}}]//MatrixFormScope (10)
Data (6)
Exact input yields exact output:
AbsoluteCorrelation[{5, 3 / 4, 1}, {2, 1 / 2, 1}]AbsoluteCorrelation[{1, π, 2}, {2, 2, 1}]//SimplifyApproximate input yields approximate output:
AbsoluteCorrelation[{1.5, 3, 5, 10}, {2, 1.25, 15, 8}]AbsoluteCorrelation[N[{1, 2, 5, 6}, 20], N[{2, 3, 6, 8}, 20]]Absolute correlation between vectors of complexes:
AbsoluteCorrelation[{2 + I, 3 - 2I, 5 + 4I}, {I, 1 + 2I, 10 - 5I}]AbsoluteCorrelation[RandomReal[1, 10 ^ 7], RandomReal[1, 10 ^ 7]]A structured array can be used (see the guide):
AbsoluteCorrelation[SparseArray[{{2, 2} -> 1, {5, 3} -> 2}]]//MatrixFormAbsoluteCorrelation[IdentityMatrix[3]]//MatrixFormAbsoluteCorrelation[ToeplitzMatrix[4]]//MatrixFormAbsoluteCorrelation[QuantityArray[RandomReal[1, {20, 2}], "Meters"]]//MatrixFormWorks with data involving quantities:
{v, w} = Quantity[{{2.5, 3, 5, 10}, {2, 1.25, 15, 8}}, "Meters"];AbsoluteCorrelation[v, w]Distributions and Processes (4)
Absolute correlation for a continuous multivariate distribution:
AbsoluteCorrelation[BinormalDistribution[ρ]]//MatrixFormAbsoluteCorrelation[BinormalDistribution[ρ], 2, 1]Absolute correlation for a discrete multivariate distribution:
AbsoluteCorrelation[MultivariatePoissonDistribution[μ, {2, 3}]]//MatrixFormAbsoluteCorrelation[MultivariatePoissonDistribution[μ, {2, 3}], 2, 1]Absolute correlation for derived distributions:
AbsoluteCorrelation[ProductDistribution[ExponentialDistribution[1], NormalDistribution[3, 5]]]//MatrixForm𝒟 = CopulaDistribution[{"Frank", 2}, {UniformDistribution[{0, 1}], UniformDistribution[{0, 1}]}];AbsoluteCorrelation[𝒟]//MatrixForm𝒟 = HistogramDistribution[RandomVariate[BinormalDistribution[.75], 10 ^ 4]];AbsoluteCorrelation[𝒟]//MatrixFormAbsoluteCorrelation[BinormalDistribution[.75]]//MatrixFormAbsolute correlation matrix for a random process at times s and t:
Correlation[WienerProcess[][{s, t}]]//MatrixFormApplications (3)
Compute the absolute correlation of two financial time series:
AbsoluteCorrelation[FinancialData["^GSPC", "Open", {2009, 1, 1}, "Value"], FinancialData["^GSPC", "Close", {2009, 1, 1}, "Value"]]AbsoluteCorrelation can be used to measure linear association:
data = BlockRandom[SeedRandom[1];Table[RandomVariate[BinormalDistribution[i], 3000], {i, {-.99, -.75, -.25, -.5, 0., .25, .5, .75, .99}}]];Grid[Partition[Table[ListPlot[i, PlotStyle -> Directive[PointSize[Tiny]],
FrameTicks -> None, Frame -> True, Axes -> None, PlotLabel -> Row[{"ρ : ", AbsoluteCorrelation[i][[1, 2]]}]], {i, data}],
3]]AbsoluteCorrelation can only detect monotonic relationships:
uni = RandomReal[{-3, 3}, 3000];f[x_] := {{x, -Sqrt[Abs[x]] + RandomReal[.5]}, {x, .25x^2 + RandomReal[.5]}, {x, -Sinc[x] + RandomReal[.5]}, {Cos[x], Sin[x] + RandomReal[.5]}}data = f /@ uni;Table[ListPlot[data[[All, i]], Frame -> True, Axes -> None, PlotLabel -> Row[{"ρ : ", AbsoluteCorrelation[data[[All, i]]][[1, 2]]}], PlotStyle -> Directive[PointSize[Tiny]], FrameTicks -> None], {i, 4}]HoeffdingD can be used to detect a variety of dependence structures:
Table[HoeffdingD[data[[All, i]]][[1, 2]], {i, 4}]Properties & Relations (8)
The absolute correlation matrix is symmetric and positive semidefinite:
corr = AbsoluteCorrelation[RandomVariate[BinormalDistribution[1 / 3], 10 ^ 3]];SymmetricMatrixQ[corr]PositiveSemidefiniteMatrixQ[corr]Covariance and AbsoluteCorrelation are the same for a distribution with zero mean:
𝒟 = BinormalDistribution[ρ];Mean[𝒟]Covariance[𝒟]AbsoluteCorrelation[𝒟]Correlation and AbsoluteCorrelation agree for zero mean and unit marginal variances:
𝒟 = BinormalDistribution[ρ];Mean[𝒟]Variance[𝒟]Correlation[𝒟]AbsoluteCorrelation[𝒟]AbsoluteCorrelationFunction is the off-diagonal entry in the absolute correlation matrix:
𝒫 = WienerProcess[μ, σ];AbsoluteCorrelation[𝒫[{s, t}], 1, 2]AbsoluteCorrelationFunction[𝒫, s, t]Simplify[%% - %, 0 < s < t]AbsoluteCorrelationFunction for a list can be calculated using absolute correlation:
data = Range[10];
n = Length[data];Calculate absolute correlation function for the data:
AbsoluteCorrelationFunction[data, {n - 1}]n / Range[n, 1, -1]Table[AbsoluteCorrelation[Drop[data, i], Drop[RotateRight[data, i], i]], {i, 0, n - 1}]% - %%The absolute correlation tends to be large only on the diagonal of a random matrix:
ArrayPlot[AbsoluteCorrelation[RandomReal[{-1, 1}, {50, 50}]]]The absolute correlation of a list with itself is the second moment:
Moment[{a, b, c}, 2]AbsoluteCorrelation[{a, b, c}, {a, b, c}]//Simplify[#, {a, b, c}∈Reals]&%% - %//Simplifydata = RandomReal[1, 10 ^ 6];
Moment[data, 2] / AbsoluteCorrelation[data, data]The diagonal of an absolute correlation matrix is the second moment:
data = RandomReal[5, {20, 5}];
n = Length[data];Diagonal[AbsoluteCorrelation[data]]Moment[data, 2]% - %%Text
Wolfram Research (2012), AbsoluteCorrelation, Wolfram Language function, https://reference.wolfram.com/language/ref/AbsoluteCorrelation.html (updated 2023).
CMS
Wolfram Language. 2012. "AbsoluteCorrelation." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2023. https://reference.wolfram.com/language/ref/AbsoluteCorrelation.html.
APA
Wolfram Language. (2012). AbsoluteCorrelation. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/AbsoluteCorrelation.html