Wolfram Language & System Documentation Center

AbsoluteCorrelationFunction

AbsoluteCorrelationFunction[data,hspec]

estimates the absolute correlation function at lags hspec from data.

AbsoluteCorrelationFunction[proc,hspec]

represents the absolute correlation function at lags hspec for the random process proc.

AbsoluteCorrelationFunction[proc,s,t]

represents the absolute correlation function at times s and t for the random process proc.

Details

AbsoluteCorrelationFunction is also known as the autocorrelation function.
The following specifications can be given for hspec:

	τ	at time or lag τ
	{τ_max}	unit spaced from 0 to τ_max
	{τ_min,τ_max}	unit spaced from τ_min to τ_max
	{τ_min,τ_max,dτ}	from τ_min to τ_max in steps of dτ
	{{τ₁,τ₂,…}}	use explicit {τ₁,τ₂,…}

AbsoluteCorrelationFunction[{x₁,…,x_n},h] is equivalent to .
When data is TemporalData containing an ensemble of paths, the output represents the average across all paths.
AbsoluteCorrelationFunction for a process proc with value x[t] at time t is given by:
Expectation[x[s] x[t]] for a scalar-valued process

Expectation[x[s]⊗x[t]] for a vector-valued process
The symbol ⊗ represents KroneckerProduct.
AbsoluteCorrelationFunction[proc,h] is defined only if proc is a weakly stationary process and is equivalent to AbsoluteCorrelationFunction[proc,h,0].
The process proc can be any random process such as ARMAProcess and WienerProcess.

Examples

open all close all

Basic Examples (4)

Estimate the absolute correlation function at lag 2:

Wolfram Language code: AbsoluteCorrelationFunction[{2, 3, 4, 3}, 2]

Sample the absolute correlation function for a random sample from an autoregressive time series:

Wolfram Language code: data = RandomFunction[ARProcess[{.2, .3, .4}, 1], {1, 10 ^ 4}];

Wolfram Language code: ListPlot[AbsoluteCorrelationFunction[data, {30}], Filling -> Axis, PlotRange -> All]

The absolute correlation function for a discrete-time process:

Wolfram Language code: AbsoluteCorrelationFunction[BinomialProcess[p], s, t]

Wolfram Language code: DiscretePlot3D[Evaluate[% /. {p -> 2 / 3}], {s, 0, 10}, {t, 0, 10}, ExtentSize -> 1 / 2, ColorFunction -> "Rainbow"]

The absolute correlation function for a continuous-time process:

Wolfram Language code: AbsoluteCorrelationFunction[WienerProcess[μ, σ], s, t]

Wolfram Language code: Plot3D[Evaluate[% /. {μ -> 1, σ -> 2}], {s, 0, 10}, {t, 0, 10}, ColorFunction -> "Rainbow"]

Scope (13)

Empirical Estimates (7)

Estimate the absolute correlation function for some data at lag 5:

Wolfram Language code: AbsoluteCorrelationFunction[Range[10], 5]

Obtain empirical estimates of the correlation function up to lag 9:

Wolfram Language code: AbsoluteCorrelationFunction[Range[10], {9}]

Compute the absolute correlation function for lags 1 to 9 in steps of 2:

Wolfram Language code: AbsoluteCorrelationFunction[Range[10], {1, 9, 2}]

Compute the absolute correlation function for a time series:

Wolfram Language code:

ts = TemporalData[TimeSeries, {{{-2.9904395734335427, -1.5547517217370468, -2.007044987914736, 
    -0.7114933373063236, -1.5920036118254968, 0.23183536513859127, 0.056774681349179124, 
    0.32394041932443046, 0.10382798659711348, -0.684046765274114, - ... 1687325555, 
    3.410933732368106, 2.5200924558212163, 2.008558601261935, 0.43151331467691206, 
    0.6249727955196763}}, {{1, 1000, 1}}, 1, {"Continuous", 1}, {"Discrete", 1}, 1, 
  {ValueDimensions -> 1, ResamplingMethod -> None}}, False, 10.1];

The absolute correlation function of a time series for multiple lags is given as a time series:

Wolfram Language code: abscorr = AbsoluteCorrelationFunction[ts, {100}]

Wolfram Language code: ListPlot[abscorr, Filling -> Axis]

Estimate the absolute correlation function for an ensemble of paths:

Wolfram Language code: data = RandomFunction[ARProcess[{.8}, 1], {0, 500}, 10]

Wolfram Language code: abscorr = AbsoluteCorrelationFunction[data, {12}];

Wolfram Language code: ListPlot[abscorr, Filling -> 0]

Compare empirical and theoretical absolute correlation functions:

Wolfram Language code: proc = MAProcess[{.4, .3, .5, .6, .3}, 1.];

Wolfram Language code: data = RandomFunction[proc, {0, 100}];

Wolfram Language code:

ListPlot[AbsoluteCorrelationFunction[#, {10}]& /@ {proc, data}, Filling -> {1 -> {2}}, PlotStyle -> PointSize[Medium], PlotLegends -> {"process absolute correlation", "sample absolute correlation"}]

Plot the absolute cross-correlation for vector data:

Wolfram Language code:

proc = ARProcess[{{{.3, .1}, {.6, .3}}}, {{1, .3}, {.3, .6}}];
data = RandomFunction[proc, {100}];
cov = AbsoluteCorrelationFunction[data, {-6, 6}];

Wolfram Language code: Table[ListPlot[cov["Values"][[All, i, j]], Filling -> 0, PlotLabel -> {i, j}], {i, 1, 2}, {j, 1, 2}]

Random Processes (6)

The absolute correlation function for a weakly stationary discrete-time process:

Wolfram Language code: AbsoluteCorrelationFunction[ARProcess[{a}, σ^2], s, t]

Wolfram Language code:

DiscretePlot3D[Evaluate[% /. {a -> 2 / 3, σ -> 1}], {s, 0, 10}, {t, 0, 10}, ExtentSize -> 1 / 2, ColorFunction -> "Rainbow"]

The absolute correlation function only depends on the antidiagonal :

Wolfram Language code: AbsoluteCorrelationFunction[ARProcess[{a}, σ^2], h]

Wolfram Language code:

DiscretePlot[Evaluate[% /. {a -> 2 / 3, σ -> 1}], {h, 0, 10}, ExtentSize -> 1 / 2, ColorFunction -> "Rainbow", AxesLabel -> {h, None}]

The absolute correlation function for a weakly stationary continuous-time process:

Wolfram Language code: AbsoluteCorrelationFunction[OrnsteinUhlenbeckProcess[μ, σ, θ], s, t]

Wolfram Language code: Plot3D[Evaluate[% /. {μ -> 1, σ -> 2, θ -> 1 / 3}], {s, 0, 10}, {t, 0, 10}, ColorFunction -> "Rainbow"]

The absolute correlation function only depends on the antidiagonal :

Wolfram Language code: AbsoluteCorrelationFunction[OrnsteinUhlenbeckProcess[μ, σ, θ], h]

Wolfram Language code:

Plot[Evaluate[% /. {μ -> 1, σ -> 2, θ -> 1 / 3}], {h, 0, 10}, ColorFunction -> "Rainbow", Filling -> Axis, AxesLabel -> {h, None}]

The absolute correlation function for a non-weakly stationary discrete-time process:

Wolfram Language code: AbsoluteCorrelationFunction[BinomialProcess[p], s, t]

Wolfram Language code: DiscretePlot3D[Evaluate[% /. p -> 1 / 3], {s, 0, 10}, {t, 0, 10}, ExtentSize -> 1 / 2, ColorFunction -> "Rainbow"]

The absolute correlation function depends on both time arguments:

Wolfram Language code: antidiagonals = AbsoluteCorrelationFunction[BinomialProcess[1 / 3], t, t + h]

Wolfram Language code:

DiscretePlot[Evaluate@Table[antidiagonals, {t, 1, 4}], {h, 0, 6}, ExtentSize -> 1 / 2, AxesLabel -> {h, None}, PlotLegends -> (Row[{"t =", #}]& /@ Range[1, 4])]

The absolute correlation function for a non-weakly stationary continuous-time process:

Wolfram Language code: AbsoluteCorrelationFunction[PoissonProcess[μ], s, t]

Wolfram Language code: Plot3D[Evaluate[% /. μ -> 3], {s, 0, 10}, {t, 0, 10}, ColorFunction -> "Rainbow"]

The absolute correlation function depends on both time arguments:

Wolfram Language code: antidiagonals = AbsoluteCorrelationFunction[PoissonProcess[3], t, t + h]

Wolfram Language code:

Plot[Evaluate@Table[antidiagonals, {t, 1, 4}], {h, 0, 6}, AxesLabel -> {h, None}, PlotLegends -> (Row[{"t =", #}]& /@ Range[1, 4])]

The correlation function for some time series processes:

Wolfram Language code:

proc1 = ARProcess[{.8}, 1];
proc2 = MAProcess[{-.4, -.7, .6, -1}, 1];
proc3 = SARMAProcess[{}, {}, {3, {.6}, {.1}}, 1];
proc4 = FARIMAProcess[{}, 1 / 3, {}, 1];

Wolfram Language code:

DiscretePlot[AbsoluteCorrelationFunction[#, h], {h, 0, 15}, ExtentSize -> 1 / 2, PlotRange -> All, PlotLabel -> Head[#]]& /@ {proc1, proc2, proc3, proc4}

Absolute cross-correlation plots for a vector ARProcess:

Wolfram Language code:

proc = ARProcess[{{{.3, .1}, {.6, .3}}}, {{1, .3}, {.3, .6}}];
cov = AbsoluteCorrelationFunction[proc, h];

Wolfram Language code: Table[DiscretePlot[cov[[i, j]], {h, -6, 6}, ExtentSize -> 1 / 2, PlotLabel -> {i, j}], {i, 1, 2}, {j, 1, 2}]

Applications (2)

Determine whether the following data is best modeled with an MAProcess or an ARProcess:

Wolfram Language code:

ListLinePlot[data = TemporalData[TimeSeries, {{{-1.4735257611469446, -0.9158187257309729, -1.9060205147226934, 
    -1.6174582169404574, -2.633459084244463, -2.104839842098871, -2.8701276893108894, 
    -2.4118183939601607, -0.5125633448622677, -1.2356329399850385, 1. ... 26394036266876, -0.16380797769527589, 0.3559909972777121, 
    1.5343047104249412, 0.10763337590714506}}, {{0, 100, 1}}, 1, {"Continuous", 1}, 
  {"Discrete", 1}, 1, {ResamplingMethod -> {"Interpolation", InterpolationOrder -> 1}}}, False, 
 10.1]]

It is difficult to determine the underlying process from sample paths:

Wolfram Language code: candidates = {MAProcess[{.5, .4}, 1], ARProcess[{.5, .4}, 1]};

Wolfram Language code:

SeedRandom[2];
ListLinePlot[RandomFunction[#, {0, 100}]]& /@ candidates

The absolute correlation function of the data decays slowly:

Wolfram Language code: ListPlot[AbsoluteCorrelationFunction[data, {10}], Filling -> 0]

ARProcess is clearly a better candidate model than MAProcess:

Wolfram Language code: ListPlot[AbsoluteCorrelationFunction[#, {10}], PlotLabel -> Head[#], Filling -> 0]& /@ candidates

Use the absolute correlation function to determine if a process is mean ergodic:

Wolfram Language code: proc = OrnsteinUhlenbeckProcess[0, σ, θ];

The process is weakly stationary:

Wolfram Language code: WeakStationarity[proc]

Calculate the absolute correlation function:

Wolfram Language code: abscorr[h_] = AbsoluteCorrelationFunction[proc, h]

Find the value of the strip integral:

Wolfram Language code: int[t_] = 1 / (2 * t)Integrate[(1 - Abs[u] / (2 * t))abscorr[u], {u, -2 * t, 2 * t}, Assumptions -> t > 0]

Check if the limit of the integral is 0 to conclude mean ergodicity:

Wolfram Language code: Limit[int[t], t -> ∞, Assumptions -> σ > 0 && θ > 0]

Properties & Relations (13)

Sample absolute correlation function is a biased estimator for the process absolute correlation function:

Wolfram Language code:

proc = ARMAProcess[1, {5 / 6, -1 / 6}, {2 / 3}, 1];
paths = RandomFunction[proc, {0, n = 10}, 10 ^ 4];

Calculate the sample absolute correlation function:

Wolfram Language code: AbsoluteCorrelationFunction[paths, {10}]

Wolfram Language code: sacf = TimeSeriesMapThread[(#2(n + 1) / (n + 1 - #1))&, %]

Absolute correlation function for the process:

Wolfram Language code: acf = AbsoluteCorrelationFunction[proc, {10}]

Plot both functions:

Wolfram Language code: ListPlot[{sacf, acf}, Filling -> 0, PlotLegends -> {"sample absolute correlation", "process absolute correlation"}]

Absolute correlation function for a list can be calculated using AbsoluteCorrelation:

Wolfram Language code:

data = Range[10];
n = Length[data];

Calculate absolute correlation function for the data:

Wolfram Language code: AbsoluteCorrelationFunction[data, {n - 1}] / (Range[n, 1, -1] / n)

Use absolute correlation:

Wolfram Language code: Table[ AbsoluteCorrelation[Drop[data, i], Drop[RotateRight[data, i], i]], {i, 0, n - 1}]

Wolfram Language code: % - %%

AbsoluteCorrelationFunction is the off-diagonal entry in the absolute correlation matrix:

Wolfram Language code: 𝒫 = WienerProcess[μ, σ];

Wolfram Language code: AbsoluteCorrelation[𝒫[{s, t}], 1, 2]

Wolfram Language code: AbsoluteCorrelationFunction[𝒫, s, t]

Wolfram Language code: Simplify[%% - %, 0 < s < t]

Sample absolute correlation function at lag 0 estimates the second Moment:

Wolfram Language code:

data = Range[10];
AbsoluteCorrelationFunction[data, 0]

Wolfram Language code: Moment[data, 2]

Wolfram Language code: % - %%

Sample absolute correlation function is related to CovarianceFunction:

Wolfram Language code:

data = Range[10];
n = Length[data];

Wolfram Language code: AbsoluteCorrelationFunction[data - Mean[data], {n - 1}]

Wolfram Language code: CovarianceFunction[data, {n - 1}]

Wolfram Language code: % - %%

Sample absolute correlation function is related to CorrelationFunction:

Wolfram Language code:

data = Range[10];
n = Length[data];

Wolfram Language code: AbsoluteCorrelationFunction[data - Mean[data], {n - 1}]

Scale by the first element:

Wolfram Language code: % / First[%]

Compare to the sample correlation function:

Wolfram Language code: CorrelationFunction[data, {n - 1}]

Wolfram Language code: % - %%

Use Expectation to calculate the absolute correlation function:

Wolfram Language code: 𝒫 = WienerProcess[μ, σ];

Wolfram Language code: Expectation[x[s] x[t], x𝒫, Assumptions -> s > 0 && t > 0]

Wolfram Language code: AbsoluteCorrelationFunction[𝒫, s, t]

Wolfram Language code: Simplify[% - %%, s < t]

The absolute correlation function is related to the Moment function:

Wolfram Language code: 𝒫 = GeometricBrownianMotionProcess[μ, σ, θ];

Wolfram Language code: AbsoluteCorrelationFunction[𝒫, t, t]

Verify equality , where is the moment function:

Wolfram Language code: Moment[𝒫[t], 2]

Wolfram Language code: % - %%//Simplify

The absolute correlation function is related to the CovarianceFunction :

Wolfram Language code: 𝒫 = WienerProcess[μ, σ];

Wolfram Language code: CovarianceFunction[𝒫, s, t]

Verify equality , where is the mean function:

Wolfram Language code: AbsoluteCorrelationFunction[𝒫, s, t] - Mean[𝒫[s]] Mean[𝒫[t]]

Wolfram Language code: % - %%

The absolute correlation function equals CovarianceFunction when the mean of the process is zero:

Wolfram Language code: AbsoluteCorrelationFunction[WienerProcess[], s, t]

Wolfram Language code: CovarianceFunction[WienerProcess[], s, t]

Wolfram Language code: % - %%

The absolute correlation function is invariant for ToInvertibleTimeSeries:

Wolfram Language code: proc = MAProcess[{2, 4}, 1];

Wolfram Language code: TimeSeriesInvertibility[proc]

Wolfram Language code: iproc = ToInvertibleTimeSeries@proc

Wolfram Language code: AbsoluteCorrelationFunction[#, s, t]& /@ {proc, iproc}

The absolute correlation function is not invariant to centralizing:

Wolfram Language code:

data = TemporalData[EventSeries, {{{-0.5997948200136711, -0.6119370022135471, -2.181570597470531, 
    -3.0852015062413294, -2.5597554304014736, -2.724339030053185, -2.1990400702572104, 
    -2.2335014895051946, -1.0488409388108924, -0.1005536745721749, 2 ... 63267114671374, 22.486986202712714, 21.766625417091756, 
    22.44341047189002, 22.079788501970878, 23.102713685532592}}, {{0, 100, 1}}, 1, 
  {"Continuous", 1}, {"Discrete", 1}, 1, {ResamplingMethod -> None, ValueDimensions -> 1}}, False, 
 10.1];

The data has nonzero mean:

Wolfram Language code: Mean[data]

Centralize data:

Wolfram Language code: newdata = Standardize[data, Mean, 1&];

Compare absolute correlation functions:

Wolfram Language code: ListPlot[AbsoluteCorrelationFunction[#, {20}], Filling -> 0]& /@ {data, newdata}

PowerSpectralDensity is a transform of the absolute correlation function for mean zero processes:

Wolfram Language code:

proc = ARProcess[{a}, σ^2];
cf = AbsoluteCorrelationFunction[proc, h]

Use FourierSequenceTransform with appropriate parameters:

Wolfram Language code: ft = FourierSequenceTransform[cf, h, z]

Compare to the power spectrum:

Wolfram Language code: PowerSpectralDensity[proc, z]

Wolfram Language code: FullSimplify[% - ft]

Possible Issues (1)

AbsoluteCorrelationFunction output may contain DifferenceRoot:

Wolfram Language code: AbsoluteCorrelationFunction[ARProcess[{a, b}, σ^2], t] //Simplify[#, t > 0]&

Use FunctionExpand to recover explicit powers:

Wolfram Language code: %//FunctionExpand

Top

More Learning

Tech Support

Wolfram Solutions

Wolfram Solutions For Education

Get Started

Grow Your Skills

Work with Us

Educational Programs for Adults

Educational Programs for Youth

Read

AbsoluteCorrelationFunction

Details

Examples

Basic Examples (4)

Scope (13)

Empirical Estimates (7)

Random Processes (6)

Applications (2)

Properties & Relations (13)

Possible Issues (1)

Text

CMS

APA

BibTeX

BibLaTeX

	Expectation[x[s] x[t]]	for a scalar-valued process
	Expectation[x[s]⊗x[t]]	for a vector-valued process

AbsoluteCorrelationFunction

Details

Examples

Basic Examples (4)

Scope (13)

Empirical Estimates (7)

Random Processes (6)

Applications (2)

Properties & Relations (13)

Possible Issues (1)

See Also

Related Guides

History

Text

CMS

APA

BibTeX

BibLaTeX