WOLFRAM

Wolfram Language & System Documentation Center

Axes

is an option for graphics functions that specifies whether axes should be drawn.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Axes Positions  
Axes Styling  
Axes Labels and Ticks  
Properties & Relations  
Possible Issues  
Neat Examples  
See Also
Tech Notes
Related Guides
History
Cite this Page

Axes

Axes

is an option for graphics functions that specifies whether axes should be drawn.

Details

  • Axes->True draws all axes.
  • Axes->False draws no axes.
  • Axes->{False,True} draws a axis but no axis in two dimensions.
  • In two dimensions, axes are drawn to cross at the position specified by the option AxesOrigin. »
  • In three dimensions, axes are drawn on the edges of the bounding box specified by the option AxesEdge. »

Examples

open all close all

Basic Examples  (4)

Draw all the axes:

Wolfram Language code: Graphics[Circle[], Axes -> True]
Wolfram Language code: Graphics3D[Cylinder[], Axes -> True]

Draw the axis but no axis:

Wolfram Language code: Plot[Sin[x], {x, 0, 10}, Axes -> {True, False}]

Draw the axis only:

Wolfram Language code: Plot3D[Sin[x y], {x, 0, 3}, {y, 0, 3}, Axes -> {False, False, True}]

Specify overall axes style, including axes labels, ticks, and tick labels, using AxesStyle:

Wolfram Language code: Plot[Sinc[x], {x, 0, 10}, AxesLabel -> {x, y}, AxesStyle -> Directive[Orange, 12]]

Scope  (12)

Axes Positions  (5)

Determine AxesOrigin automatically:

Wolfram Language code: Graphics[Circle[], Axes -> True, AxesOrigin -> Automatic]
Wolfram Language code: Plot[Sin[x], {x, 0, 2Pi}, AxesOrigin -> Automatic]

Specify AxesOrigin explicitly:

Wolfram Language code: Graphics[Circle[], Axes -> True, AxesOrigin -> {0, -1}]
Wolfram Language code: Plot[Sin[x], {x, 0, 2Pi}, AxesOrigin -> {Pi, 0}]

In 3D, axes are drawn on the bounding box edges:

Wolfram Language code: Graphics3D[Cylinder[], Axes -> True]
Wolfram Language code: Plot3D[Sin[x y], {x, 0, Pi}, {y, 0, Pi}]

Choose the bounding box edges automatically to draw the axes:

Wolfram Language code: Graphics3D[Cylinder[], Axes -> True, AxesEdge -> Automatic]

Specify the edges explicitly, using AxesEdge:

Wolfram Language code: {Graphics3D[Cylinder[], Axes -> True, AxesEdge -> {{-1, 1}, None, None}], Graphics3D[Cylinder[], Axes -> True, AxesEdge -> {None, {1, -1}, None}], Graphics3D[Cylinder[], Axes -> True, AxesEdge -> {None, None, {1, -1}}]}

Axes Styling  (2)

Specify the style of each axis:

Wolfram Language code: Plot[Sinc[x], {x, 0, 10}, AxesStyle -> {Directive[Red, 12], Blue}]
Wolfram Language code: Graphics3D[Cylinder[], Axes -> True, AxesStyle -> {Red, Green, Blue}]

Display the axes without the bounding box:

Wolfram Language code: Graphics3D[Cylinder[], Axes -> True, Boxed -> False]

Axes Labels and Ticks  (5)

Specify a label for each axis:

Wolfram Language code: Plot[Sinc[x], {x, 0, 10}, AxesLabel -> {x, Sin[x]}]

Use labels based on variables specified in Plot3D:

Wolfram Language code: Plot3D[Sin[θ ρ], {θ, 0, 3}, {ρ, 0, 3}, AxesLabel -> Automatic]

Draw the axes but no tick marks:

Wolfram Language code: Plot[Sin[x], {x, 0, 10}, Ticks -> None]

Place tick marks automatically:

Wolfram Language code: Plot[Sin[x], {x, 0, 10}, Ticks -> Automatic]

Draw tick marks at the specified positions:

Wolfram Language code: Plot[Sin[x], {x, 0, 10}, Ticks -> {{0, Pi, 2Pi, 3Pi}, {-1, 1}}]
Wolfram Language code: Plot3D[Sin[x y], {x, 0, Pi}, {y, 0, Pi}, Ticks -> {{0, Pi / 2, Pi}, {0, Pi / 2, Pi}, {-1, 0, 1}}]

Properties & Relations  (5)

In 2D, the axes are drawn above the graphics:

Wolfram Language code: Graphics[{Pink, Disk[]}, Axes -> True]

Objects in Epilog are drawn on top of any graphics, including the axes:

Wolfram Language code: Graphics[{Pink, Disk[]}, Axes -> True, Epilog -> {Blue, Disk[{0, 0}, .5]}]

If the option Frame is set to True, the ticks are drawn on the edges of the frame:

Wolfram Language code: Graphics[Circle[], Frame -> True, Axes -> True]

GridLines puts grids across the image:

Wolfram Language code: Graphics[Circle[], GridLines -> Automatic, Axes -> True]

FaceGrids puts grids on the faces of the bounding box in 3D:

Wolfram Language code: Graphics3D[Cylinder[], FaceGrids -> All, Axes -> True]

By default, DensityPlot and related functions display the frame, instead of the axes:

Wolfram Language code: DensityPlot[x Sin[y], {x, -5, 5}, {y, -5, 5}]

Possible Issues  (1)

If Frame and Axes are both present, the axes ticks are suppressed:

Wolfram Language code: DensityPlot[x Sin[y], {x, -5, 5}, {y, -5, 5}, Axes -> True, Frame -> True, Ticks -> True]

Neat Examples  (1)

Move the axes using a locator:

Wolfram Language code: Manipulate[Labeled[Framed[Graphics[Circle[{0, 0}, 3], PlotRange -> 3, ImagePadding -> 20, Axes -> True, AxesOrigin -> p]], p], {{p, {0, 0}}, Locator}]
Wolfram Research (1988), Axes, Wolfram Language function, https://reference.wolfram.com/language/ref/Axes.html.

Text

Wolfram Research (1988), Axes, Wolfram Language function, https://reference.wolfram.com/language/ref/Axes.html.

CMS

Wolfram Language. 1988. "Axes." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/Axes.html.

APA

Wolfram Language. (1988). Axes. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Axes.html

BibTeX

@misc{reference.wolfram_2026_axes, author="Wolfram Research", title="{Axes}", year="1988", howpublished="\url{https://reference.wolfram.com/language/ref/Axes.html}", note=[Accessed: 15-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_axes, organization={Wolfram Research}, title={Axes}, year={1988}, url={https://reference.wolfram.com/language/ref/Axes.html}, note=[Accessed: 15-June-2026]}