WOLFRAM

Wolfram Language & System Documentation Center

BernoulliProcess[p]

represents a Bernoulli process with event probability p.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Basic Uses  
Process Slice Properties  
Applications  
Properties & Relations  
Neat Examples  
See Also
Related Guides
History
Cite this Page

BernoulliProcess

BernoulliProcess[p]

represents a Bernoulli process with event probability p.

Details

Examples

open all close all

Basic Examples  (3)

Simulate a Bernoulli process:

Wolfram Language code: data = RandomFunction[BernoulliProcess[1 / 3], {0, 30}]
Wolfram Language code: ListPlot[data, Filling -> Axis]

Mean and variance functions:

Wolfram Language code: Mean[BernoulliProcess[p][t]]
Wolfram Language code: Variance[BernoulliProcess[p][t]]

Covariance function:

Wolfram Language code: CovarianceFunction[BernoulliProcess[p], s, t]
Wolfram Language code: DiscretePlot3D[CovarianceFunction[BernoulliProcess[.3], s, t], {s, 1, 10}, {t, 1, 10}, ExtentSize -> 1 / 2, ColorFunction -> "Rainbow"]

Scope  (11)

Basic Uses  (5)

Simulate an ensemble of paths:

Wolfram Language code: data = RandomFunction[BernoulliProcess[1 / 3], {0, 30}, 4]
Wolfram Language code: ListPlot[data, Filling -> Axis, PlotStyle -> PointSize[Medium]]

Compare paths for different values of the process parameter:

Wolfram Language code: sample[p_] := (SeedRandom[3];RandomFunction[BernoulliProcess[p], {0, 30}])
Wolfram Language code: pars = {.1, .4, .7};
Wolfram Language code: ListPlot[sample[#], Filling -> Axis, PlotLabel -> StringJoin["p = ", ToString[#]]]& /@ pars

Process parameter estimation:

Wolfram Language code: sample = RandomFunction[BernoulliProcess[.3], {0, 10 ^ 3}];

Estimate the distribution parameter from sample data:

Wolfram Language code: edist = EstimatedProcess[sample, BernoulliProcess[p]]

Correlation function:

Wolfram Language code: CorrelationFunction[BernoulliProcess[p], s, t]

Absolute correlation function:

Wolfram Language code: AbsoluteCorrelationFunction[BernoulliProcess[p], s, t]

Process Slice Properties  (6)

Univariate SliceDistribution:

Wolfram Language code: SliceDistribution[BernoulliProcess[p], t]

Univariate slice probability density:

Wolfram Language code: PDF[BernoulliProcess[p][t], x]

Multi-time slice distribution:

Wolfram Language code: SliceDistribution[BernoulliProcess[p], {1, 3, 7}]

Higher-order PDF:

Wolfram Language code: PDF[BernoulliProcess[p][{1, 3, 7}], {x, y, z}]

Compute the expectation of an expression:

Wolfram Language code: Expectation[x[t] + x[t] ^ 2, xBernoulliProcess[p]]

Calculate the probability of an event:

Wolfram Language code: Probability[3x[t] ^ 2 + 2x[t] < 3, xBernoulliProcess[p]]

Skewness does not depend on time:

Wolfram Language code: Plot[Skewness[BernoulliProcess[p][t]], {p, 0, 1}]
Wolfram Language code: Skewness[BernoulliProcess[p][t]]

The limiting values:

Wolfram Language code: Limit[Skewness[BernoulliProcess[p][t]], p -> 0]
Wolfram Language code: Limit[Skewness[BernoulliProcess[p][t]], p -> 1, Direction -> 1]

BernoulliProcess is symmetric for p=1/2:

Wolfram Language code: Solve[Skewness[BernoulliProcess[p][t]] == 0, p]

Kurtosis does not depend on time:

Wolfram Language code: Plot[Kurtosis[BernoulliProcess[p][t]], {p, 0, 1}]
Wolfram Language code: Kurtosis[BernoulliProcess[p][t]]

The limiting values:

Wolfram Language code: Limit[Kurtosis[BernoulliProcess[p][t]], p -> 0]
Wolfram Language code: Limit[Kurtosis[BernoulliProcess[p][t]], p -> 1, Direction -> 1]

The minimum value of kurtosis:

Wolfram Language code: FindMinimum[Kurtosis[BernoulliProcess[p][t]] && 0 < p < 1, {p, 1 / 3}]

Moment of order r:

Wolfram Language code: Moment[BernoulliProcess[p][t], r]

Generating functions:

Wolfram Language code: CharacteristicFunction[BernoulliProcess[p][t], w]
Wolfram Language code: MomentGeneratingFunction[BernoulliProcess[p][t], w]

CentralMoment and its generating function:

Wolfram Language code: CentralMoment[BernoulliProcess[p][t], r]
Wolfram Language code: CentralMomentGeneratingFunction[BernoulliProcess[p][t], w]

FactorialMoment has no closed form for symbolic order:

Wolfram Language code: FactorialMoment[BernoulliProcess[p][t], 3]
Wolfram Language code: FactorialMomentGeneratingFunction[BernoulliProcess[p][t], w]

Cumulant and its generating function:

Wolfram Language code: Cumulant[BernoulliProcess[p][t], r]
Wolfram Language code: CumulantGeneratingFunction[BernoulliProcess[p][t], w]

Applications  (1)

Generate a sequence of fair coin tosses:

Wolfram Language code: RandomFunction[BernoulliProcess[1 / 2], {0, 20}]["Path"] /. {{x_, 0} :> {x, H}, {x_, 1} :> {x, T}}

Properties & Relations  (5)

Bernoulli process is weakly stationary:

Wolfram Language code: WeakStationarity[BernoulliProcess[p]]

Bernoulli process has a well-defined StationaryDistribution:

Wolfram Language code: StationaryDistribution[BernoulliProcess[p]]

Transition probability does not depend on the current state:

Wolfram Language code: Probability[(x[t2] == x2)(x[t1] == x1), xBernoulliProcess[p]]

A BinomialProcess is the sum of a BernoulliProcess with :

Wolfram Language code: SeedRandom[3];bernoulli = RandomFunction[BernoulliProcess[p = 17 / 32], {20}];
Wolfram Language code: ListPlot[bernoulli, Filling -> Axis]

Accumulate the sample:

Wolfram Language code: accumulated = Accumulate[bernoulli]
Wolfram Language code: ListPlot[accumulated, Filling -> Axis]

Compare to the BinomialProcess:

Wolfram Language code: SeedRandom[3]; sample = RandomFunction[BinomialProcess[p], {1, 21}];

Align time stamps:

Wolfram Language code: binomial = TimeSeriesShift[sample, -1];
Wolfram Language code: ListPlot[{binomial, accumulated}, Filling -> Axis, PlotStyle -> {PointSize[.05], PointSize[0.02]}, PlotLegends -> {"binomial", "accumulated Bernoulli"}]

Bernoulli process satisfies the law of large numbers:

Wolfram Language code: proc = BernoulliProcess[1 / 3];

The mean function is constant:

Wolfram Language code: m = Mean[proc[t]]

Find sample mean:

Wolfram Language code: sample = Mean[RandomFunction[proc, {10 ^ 7}]["Values"]]
Wolfram Language code: m - %//N

Neat Examples  (1)

Simulate paths from a Bernoulli process:

Wolfram Language code: data = RandomFunction[BernoulliProcess[.7], {20}, 500];

Take a slice at 20 and visualize its distribution:

Wolfram Language code: sd = data["SliceData", 20];
Wolfram Language code: cf = ColorData["DarkBands"]; sliced = BarChart[Last[#], Axes -> False, BarOrigin -> Left, AspectRatio -> 4, ChartStyle -> (cf /@ First[#]), ImageSize -> 40]&[HistogramList[sd, {-0.5, 1.5, 1}]];

Plot paths and histogram distribution of the slice distribution at 20:

Wolfram Language code: ListStepPlot[data, ImageSize -> 400, PlotRange -> All, AspectRatio -> 3 / 4, Epilog -> Inset[sliced, {20.5, .5}, {0, 1.5}], PlotStyle -> (cf /@ sd), BaseStyle -> Directive[Thin, Opacity[0.5]], PlotRangePadding -> {{0, 10}, {.5, 1}}]
Wolfram Research (2012), BernoulliProcess, Wolfram Language function, https://reference.wolfram.com/language/ref/BernoulliProcess.html.

Text

Wolfram Research (2012), BernoulliProcess, Wolfram Language function, https://reference.wolfram.com/language/ref/BernoulliProcess.html.

CMS

Wolfram Language. 2012. "BernoulliProcess." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/BernoulliProcess.html.

APA

Wolfram Language. (2012). BernoulliProcess. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/BernoulliProcess.html

BibTeX

@misc{reference.wolfram_2026_bernoulliprocess, author="Wolfram Research", title="{BernoulliProcess}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/BernoulliProcess.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_bernoulliprocess, organization={Wolfram Research}, title={BernoulliProcess}, year={2012}, url={https://reference.wolfram.com/language/ref/BernoulliProcess.html}, note=[Accessed: 12-June-2026]}