BiorthogonalSplineWavelet
BiorthogonalSplineWavelet
represents a biorthogonal spline wavelet of order 4 and dual order 2.
BiorthogonalSplineWavelet[n,m]
represents a biorthogonal spline wavelet of order n and dual order m.
Details
- BiorthogonalSplineWavelet defines a family of biorthogonal wavelets.
- BiorthogonalSplineWavelet[n,m] is defined for positive integers m and n where m+n is even.
- The scaling function (
) and wavelet function (
) have compact support. The functions are symmetric. - BiorthogonalSplineWavelet can be used with such functions as DiscreteWaveletTransform, WaveletPhi, etc.
Examples
open all close allBasic Examples (6)
Plot[WaveletPhi[BiorthogonalSplineWavelet[2, 4], x], {x, -4, 4}, PlotRange -> All]Plot[WaveletPsi[BiorthogonalSplineWavelet[2, 4], x], {x, -2, 3}, PlotRange -> All]Plot[WaveletPhi[BiorthogonalSplineWavelet[2, 4], x, "Dual"], {x, -2, 2}, PlotRange -> All]Plot[WaveletPsi[BiorthogonalSplineWavelet[2, 4], x, "Dual"], {x, -2, 3}, PlotRange -> All]WaveletFilterCoefficients[BiorthogonalSplineWavelet[2, 4], {"PrimalLowpass", "PrimalHighpass"}, WorkingPrecision -> ∞]WaveletFilterCoefficients[BiorthogonalSplineWavelet[2, 4], {"DualLowpass", "DualHighpass"}, WorkingPrecision -> ∞]Scope (17)
Basic Uses (10)
Compute primal lowpass filter coefficients:
WaveletFilterCoefficients[BiorthogonalSplineWavelet[3, 3], "PrimalLowpass"]Dual lowpass filter coefficients:
WaveletFilterCoefficients[BiorthogonalSplineWavelet[3, 3], "DualLowpass"]Primal highpass filter coefficients:
WaveletFilterCoefficients[BiorthogonalSplineWavelet[3, 3], "PrimalHighpass"]Dual highpass filter coefficients:
WaveletFilterCoefficients[BiorthogonalSplineWavelet[3, 3], "DualHighpass"]WaveletFilterCoefficients[BiorthogonalSplineWavelet[3, 3], "LiftingFilter", WorkingPrecision -> ∞]%[{"LiftingMatrixForm", z}]Generate a function to compute lifting wavelet transform:
lf = WaveletFilterCoefficients[BiorthogonalSplineWavelet[3, 3], "LiftingFilter", WorkingPrecision -> ∞]lf["ForwardLiftingFunction"][Range[8]]lf["InverseLiftingFunction"][%]Plot[WaveletPhi[BiorthogonalSplineWavelet[2, 6], x], {x, -6, 6}, PlotRange -> All]Plot[WaveletPhi[BiorthogonalSplineWavelet[2, 6], x, "Dual"], {x, -1, 1}, PlotRange -> All]Plot scaling function using different levels of recursion:
Table[Plot[WaveletPhi[BiorthogonalSplineWavelet[2, 6], x, MaxRecursion -> i], {x, -4, 4}, PlotLabel -> i, PlotRange -> All], {i, 1, 8, 2}]Plot[WaveletPsi[BiorthogonalSplineWavelet[2, 6], x], {x, -3, 4}, PlotRange -> All]Plot[WaveletPsi[BiorthogonalSplineWavelet[2, 6], x, "Dual"], {x, -3, 4}, PlotRange -> All]Plot scaling function using different levels of recursion:
Table[Plot[WaveletPsi[BiorthogonalSplineWavelet[2, 6], x, MaxRecursion -> i], {x, -3, 4}, PlotLabel -> i, PlotRange -> All], {i, 1, 8, 2}]Wavelet Transforms (5)
Compute a DiscreteWaveletTransform:
data = Table[Sign[Cos[t^2]], {t, -2π, 2π, (4π/1023)}];ListLinePlot[data, PlotRange -> All]dwt = DiscreteWaveletTransform[data, BiorthogonalSplineWavelet[4, 4], 2]View the tree of wavelet coefficients:
dwt["TreeView"]Get the dimensions of wavelet coefficients:
dwt["Dimensions"]Plot the wavelet coefficients:
WaveletListPlot[dwt, PlotLayout -> "CommonXAxis"]Compute a DiscreteWaveletPacketTransform:
data = Table[Sign[Cos[t^2]], {t, -2π, 2π, (4π/1023)}];dwpt = DiscreteWaveletPacketTransform[data, BiorthogonalSplineWavelet[4, 4], 2]View the tree of wavelet coefficients:
dwpt["TreeView"]Get the dimensions of wavelet coefficients:
dwpt["Dimensions"]Plot the wavelet coefficients:
WaveletListPlot[dwpt, PlotLayout -> "CommonXAxis"]Compute a StationaryWaveletTransform:
data = Table[Sign[Cos[t^2]], {t, -2π, 2π, (4π/1023)}];swt = StationaryWaveletTransform[data, BiorthogonalSplineWavelet[4, 4], 2];View the tree of wavelet coefficients:
swt["TreeView"]Get the dimensions of wavelet coefficients:
swt["Dimensions"]Plot the wavelet coefficients:
WaveletListPlot[swt, PlotLayout -> "CommonXAxis"]Compute a StationaryWaveletPacketTransform:
data = Table[Sign[Cos[t^2]], {t, -2π, 2π, (4π/1023)}];swpt = StationaryWaveletPacketTransform[data, BiorthogonalSplineWavelet[4, 4], 2];View the tree of wavelet coefficients:
swpt["TreeView"]Get the dimensions of wavelet coefficients:
swpt["Dimensions"]Plot the wavelet coefficients:
WaveletListPlot[swpt, PlotLayout -> "CommonXAxis"]Compute a LiftingWaveletTransform:
data = Table[Sign[Cos[t^2]], {t, -2π, 2π, (4π/1023)}];lwt = LiftingWaveletTransform[data, BiorthogonalSplineWavelet[4, 4], 2];View the tree of wavelet coefficients:
lwt["TreeView"]Get the dimensions of wavelet coefficients:
lwt["Dimensions"]Plot the wavelet coefficients:
WaveletListPlot[lwt, PlotLayout -> "CommonXAxis"]Higher Dimensions (2)
Multivariate scaling and wavelet functions are products of univariate ones:
ϕ = WaveletPhi[BiorthogonalSplineWavelet[2, 6]];
ψ = WaveletPsi[BiorthogonalSplineWavelet[2, 6]];Plot3D[Evaluate[ϕ[x]ϕ[y]], {x, -6, 6}, {y, -6, 6}, PlotRange -> All, ColorFunction -> "SolarColors", Mesh -> None, Axes -> None]Plot3D[Evaluate[ϕ[x]ψ[y]], {x, -6, 6}, {y, -3, 4}, PlotRange -> All, ColorFunction -> "SolarColors", Mesh -> None, Axes -> None]Plot3D[Evaluate[ψ[x]ϕ[y]], {x, -3, 4}, {y, -6, 6}, PlotRange -> All, ColorFunction -> "SolarColors", Mesh -> None, Axes -> None]Plot3D[Evaluate[ψ[x]ψ[y]], {x, -3, 4}, {y, -3, 4}, PlotRange -> All, ColorFunction -> "SolarColors", Mesh -> None, Axes -> None]Multivariate dual scaling and wavelet functions are products of univariate ones:
Overscript[ϕ, ~] = Evaluate[WaveletPhi[BiorthogonalSplineWavelet[2, 6], #, "Dual"]]&;
Overscript[ψ, ~] = Evaluate[WaveletPsi[BiorthogonalSplineWavelet[2, 6], #, "Dual"]]&;Plot3D[Evaluate[Overscript[ϕ, ~][x]Overscript[ϕ, ~][y]], {x, -1, 1}, {y, -1, 1}, PlotRange -> All, ColorFunction -> "RustTones", Mesh -> None, Axes -> None]Plot3D[Evaluate[Overscript[ϕ, ~][x]Overscript[ψ, ~][y]], {x, -1, 1}, {y, -3, 4}, PlotRange -> All, ColorFunction -> "RustTones", Mesh -> None, Axes -> None]Plot3D[Evaluate[Overscript[ψ, ~][x]Overscript[ϕ, ~][y]], {x, -3, 4}, {y, -1, 1}, PlotRange -> All, ColorFunction -> "RustTones", Mesh -> None, Axes -> None]Plot3D[Evaluate[Overscript[ψ, ~][x]Overscript[ψ, ~][y]], {x, -3, 4}, {y, -3, 4}, PlotRange -> All, ColorFunction -> "RustTones", Mesh -> None, Axes -> None]Properties & Relations (18)
BiorthogonalSplineWavelet[1,1] is equivalent to HaarWavelet:
WaveletFilterCoefficients[HaarWavelet[]] == WaveletFilterCoefficients[BiorthogonalSplineWavelet[1, 1]]WaveletFilterCoefficients[HaarWavelet[]] == WaveletFilterCoefficients[BiorthogonalSplineWavelet[1, 1], "DualLowpass"]Lowpass filter coefficients sum to unity; 
:
Total@WaveletFilterCoefficients[BiorthogonalSplineWavelet[4, 2]][[All, 2]]Highpass filter coefficients sum to zero; 
:
Total@WaveletFilterCoefficients[BiorthogonalSplineWavelet[4, 2], "PrimalHighpass"][[All, 2]]Dual lowpass filter coefficients sum to unity; 
:
Total@WaveletFilterCoefficients[BiorthogonalSplineWavelet[4, 2], "DualLowpass"][[All, 2]]Dual highpass filter coefficients sum to zero; 
:
Total@WaveletFilterCoefficients[BiorthogonalSplineWavelet[4, 2], "DualHighpass"][[All, 2]]Scaling function integrates to unity; 
:
Integrate[WaveletPhi[BiorthogonalSplineWavelet[2, 2], x], {x, -∞, ∞}]Dual scaling function integrates to unity; 
:
Integrate[WaveletPhi[BiorthogonalSplineWavelet[2, 2], x, "Dual"], {x, -∞, ∞}]Wavelet function integrates to zero; 
:
Integrate[WaveletPsi[BiorthogonalSplineWavelet[2, 2], x], {x, -∞, ∞}]Dual wavelet function integrates to zero; 
:
Integrate[WaveletPsi[BiorthogonalSplineWavelet[2, 2], x, "Dual"], {x, -∞, ∞}]Scaling function 
has compact support {n1,n2}:
ϕ = WaveletPhi[BiorthogonalSplineWavelet[3, 3], x]{n1, n2} = {-3, 4};Dual scaling function 
has compact support {nd1,nd2}:
Overscript[ϕ, ~] = WaveletPhi[BiorthogonalSplineWavelet[3, 3], x, "Dual"]{nd1, nd2} = {-1, 2};Corresponding wavelet function 
has support ({n1-nd2+1)/2,(n2-nd1+1)/2}:
ψ = WaveletPsi[BiorthogonalSplineWavelet[3, 3], x]{(n1 - nd2 + 1/2), (n2 - nd1 + 1/2)}Dual wavelet function 
has support ({nd1-n2+1)/2,(nd2-n1+1)/2}:
Overscript[ψ, ~] = WaveletPsi[BiorthogonalSplineWavelet[3, 3], x, "Dual"]{(nd1 - n2 + 1/2), (nd2 - n1 + 1/2)}
satisfies the recursion equation 
:
ϕ = WaveletPhi[BiorthogonalSplineWavelet[1, 3]];a = WaveletFilterCoefficients[BiorthogonalSplineWavelet[1, 3], "PrimalLowpass"];Plot the components and the sum of the recursion:
scalet[x_, ϕ_, a_] := 2Table[a[[i, 2]]ϕ[2x - a[[i, 1]]], {i, Length[a]}]{Plot[Evaluate@scalet[x, ϕ, a], {x, -3, 4}, PlotRange -> All],
Plot[Total@scalet[x, ϕ, a], {x, -3, 4}, PlotRange -> All]}
satisfies the recursion equation 
:
ϕ = WaveletPhi[BiorthogonalSplineWavelet[1, 3]];b = WaveletFilterCoefficients[BiorthogonalSplineWavelet[1, 3], "PrimalHighpass"];Plot the components and the sum of the recursion:
wavelet[x_, ϕ_, b_] := 2Table[b[[i, 2]]ϕ[2x - b[[i, 1]]], {i, Length[b]}]{Plot[Evaluate@wavelet[x, ϕ, b], {x, -1, 2}, PlotRange -> All], Plot[Total@wavelet[x, ϕ, b], {x, -1, 2}, PlotRange -> All]}
satisfies the recursion equation 
:
Overscript[ϕ, ~] = (Evaluate[WaveletPhi[BiorthogonalSplineWavelet[3, 5], #, "Dual"]]&);Overscript[a, ~] = WaveletFilterCoefficients[BiorthogonalSplineWavelet[3, 5], "DualLowpass"];Plot the components and the sum of the recursion:
scalet[x_, ϕ_, a_] := 2Table[a[[i, 2]]ϕ[2x - a[[i, 1]]], {i, Length[a]}]{Plot[Evaluate@scalet[x, Overscript[ϕ, ~], Overscript[a, ~]], {x, -1, 2}, PlotRange -> All],
Plot[Total@scalet[x, Overscript[ϕ, ~], Overscript[a, ~]], {x, -1, 2}, PlotRange -> All]}
satisfies the recursion equation 
:
Overscript[ϕ, ~] = (Evaluate[WaveletPhi[BiorthogonalSplineWavelet[3, 5], #, "Dual"]]&);Overscript[b, ~] = WaveletFilterCoefficients[BiorthogonalSplineWavelet[3, 5], "DualHighpass"];Plot the components and the sum of the recursion:
wavelet[x_, ϕ_, b_] := 2Table[b[[i, 2]]ϕ[2x - b[[i, 1]]], {i, Length[b]}]{Plot[Evaluate@wavelet[x, Overscript[ϕ, ~], Overscript[b, ~]], {x, -3, 4}, PlotRange -> All],
Plot[Total@wavelet[x, Overscript[ϕ, ~], Overscript[b, ~]], {x, -3, 4}, PlotRange -> All]}Frequency response for 
is given by 
:
h[wav_, ω_] := With[{a = WaveletFilterCoefficients[wav]}, Sum[a[[i, 2]]Exp[-Ia[[i, 1]]ω], {i, Length[a]}]]The filter is a lowpass filter:
Plot[Abs[h[BiorthogonalSplineWavelet[2, 2], ω]], {ω, -π, π}, Ticks -> {{-π, -(π/2), 0, (π/2), π}, Automatic}, AxesLabel -> {ω, Abs[H[ω]]}]Fourier transform of 
is given by 
:
h[wav_, ω_] := With[{a = WaveletFilterCoefficients[wav]}, Sum[a[[i, 2]]Exp[-Ia[[i, 1]]ω], {i, Length[a]}]]fh[wav_, ω_, j_] := Abs[Product[h[wav, (ω/2^i)], {i, j}]]Plot[fh[BiorthogonalSplineWavelet[2, 2], ω, 10], {ω, -10Pi, 10Pi}, PlotRange -> All,
AxesLabel -> {ω, Abs[Overscript[ϕ, ^ ][ω]]}]Frequency response for 
is given by 
:
Overscript[h, ~][wav_, ω_] := With[{a = WaveletFilterCoefficients[wav, "DualLowpass"]}, Sum[a[[i, 2]]Exp[-Ia[[i, 1]]ω], {i, Length[a]}]]The filter is a dual lowpass filter:
Plot[Abs[Overscript[h, ~][BiorthogonalSplineWavelet[2, 2], ω]], {ω, -π, π}, Ticks -> {{-π, -(π/2), 0, (π/2), π}, Automatic}, AxesLabel -> {ω, Abs[Overscript[H, ~][ω]]}]Fourier transform of 
is given by 
:
Overscript[h, ~][wav_, ω_] := With[{a = WaveletFilterCoefficients[wav, "DualLowpass"]}, Sum[a[[i, 2]]Exp[-Ia[[i, 1]]ω], {i, Length[a]}]]fh[wav_, ω_, j_] := Abs[Product[Overscript[h, ~][wav, (ω/2^i)], {i, j}]]Plot[fh[BiorthogonalSplineWavelet[2, 2], ω, 10], {ω, -10Pi, 10Pi}, PlotRange -> All,
AxesLabel -> {ω, Abs[Overscript[Overscript[ϕ, ~], ^ ][ω]]}]Frequency response for 
is given by 
:
g[wav_, ω_] := With[{b = WaveletFilterCoefficients[wav, "PrimalHighpass"]}, Sum[b[[i, 2]]Exp[-Ib[[i, 1]]ω], {i, Length[b]}]
]The filter is a lowpass filter:
Plot[Abs[g[BiorthogonalSplineWavelet[2, 2], ω]], {ω, -π, π}, Ticks -> {{-π, -(π/2), 0, (π/2), π}, Automatic}, AxesLabel -> {ω, Abs[G[ω]]}]Fourier transform of 
is given by 
:
h[wav_, ω_] := With[{a = WaveletFilterCoefficients[wav]}, Sum[a[[i, 2]]Exp[-I a[[i, 1]]ω], {i, Length[a]}]]g[wav_, ω_] := With[{b = WaveletFilterCoefficients[wav, "PrimalHighpass"]}, Sum[b[[i, 2]]Exp[-Ib[[i, 1]]ω], {i, Length[b]}]]fg[wav_, ω_, j_] := Abs[g[wav, (ω/2)]Product[h[wav, (ω/2^i)], {i, 2, j}]]Plot[fg[BiorthogonalSplineWavelet[2, 2], ω, 10], {ω, -10Pi, 10Pi}, PlotRange -> All,
AxesLabel -> {ω, Abs[Overscript[ψ, ^ ][ω]]}]Frequency response for 
is given by 
:
Overscript[g, ~][wav_, ω_] := With[{b = WaveletFilterCoefficients[wav, "DualHighpass"]}, Sum[b[[i, 2]]Exp[-Ib[[i, 1]]ω], {i, Length[b]}]]The filter is a lowpass filter:
Plot[Abs[Overscript[g, ~][BiorthogonalSplineWavelet[2, 2], ω]], {ω, -π, π}, Ticks -> {{-π, -(π/2), 0, (π/2), π}, Automatic}, AxesLabel -> {ω, Abs[Overscript[G, ~][ω]]}]Fourier transform of 
is given by 
:
Overscript[h, ~][wav_, ω_] := With[{a = WaveletFilterCoefficients[wav, "DualLowpass"]}, Sum[a[[i, 2]]Exp[-Ia[[i, 1]]ω], {i, Length[a]}]]Overscript[g, ~][wav_, ω_] := With[{b = WaveletFilterCoefficients[wav, "DualHighpass"]}, Sum[b[[i, 2]]Exp[-Ib[[i, 1]]ω], {i, Length[b]}]]Overscript[fg, ~][wav_, ω_, j_] := Abs[Overscript[g, ~][wav, (ω/2)]Product[Overscript[h, ~][wav, (ω/2^i)], {i, 2, j}]]Plot[Overscript[fg, ~][BiorthogonalSplineWavelet[2, 2], ω, 10], {ω, -10Pi, 10Pi}, PlotRange -> All,
AxesLabel -> {ω, Abs[Overscript[Overscript[ψ, ~], ^ ][ω]]}]Neat Examples (2)
Plot translates and dilations of scaling function:
ϕ[x_, j_, k_] := 2^j / 2WaveletPhi[BiorthogonalSplineWavelet[1, 3], 2^jx - k]Plot[Evaluate@Table[ϕ[x, j, 0], {j, 0, 4}], {x, -1, 2}, Filling -> Axis, PlotRange -> All, Axes -> {True, False}]Plot[Evaluate@Table[ϕ[x, 2, k], {k, 0, 2^2 - 1}], {x, -0.5, 2}, Filling -> Axis, PlotRange -> All]Plot translates and dilations of wavelet function:
ψ[x_, j_, k_] := 2^j / 2WaveletPsi[BiorthogonalSplineWavelet[1, 3], 2^jx - k]Plot[Evaluate@Table[ψ[x, j, 0], {j, 0, 4}], {x, -0.5, 1}, Filling -> Axis, PlotRange -> All, Axes -> {True, False}]Plot[Evaluate@Table[ψ[x, 2, k], {k, 0, 2^2 - 1}], {x, -0.5, 1.5}, Filling -> Axis, PlotRange -> All]
Wolfram Research (2010), BiorthogonalSplineWavelet, Wolfram Language function, https://reference.wolfram.com/language/ref/BiorthogonalSplineWavelet.html.
Text
Wolfram Research (2010), BiorthogonalSplineWavelet, Wolfram Language function, https://reference.wolfram.com/language/ref/BiorthogonalSplineWavelet.html.
CMS
Wolfram Language. 2010. "BiorthogonalSplineWavelet." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/BiorthogonalSplineWavelet.html.
APA
Wolfram Language. (2010). BiorthogonalSplineWavelet. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/BiorthogonalSplineWavelet.html