CDFWavelet
represents a Cohen–Daubechies–Feauveau wavelet of type "9/7".
CDFWavelet["type"]
represents a Cohen–Daubechies–Feauveau wavelet of type "type".
Details
- CDFWavelet defines a set of biorthogonal wavelets.
- The following "type" forms can be used:
-
"5/3" used in lossless JPEG2000 compression "9/7" used in lossy JPEG2000 compression - The scaling function (
) and wavelet function (
) have compact support. The functions are symmetric. - CDFWavelet can be used with such functions as DiscreteWaveletTransform, WaveletPhi, etc.
Examples
open all close allBasic Examples (3)
Plot[WaveletPhi[CDFWavelet["9/7"], x], {x, -4, 4}, PlotRange -> All]WaveletPhi[CDFWavelet["9/7"], x]Plot[WaveletPsi[CDFWavelet["9/7"], x], {x, -3, 4}, PlotRange -> All]WaveletPsi[CDFWavelet["9/7"], x]WaveletFilterCoefficients[CDFWavelet["9/7"], {"PrimalLowpass", "PrimalHighpass"}]Scope (16)
Basic Uses (10)
Compute primal lowpass filter coefficients:
WaveletFilterCoefficients[CDFWavelet["9/7"], "PrimalLowpass"]Dual lowpass filter coefficients:
WaveletFilterCoefficients[CDFWavelet["9/7"], "DualLowpass"]Primal highpass filter coefficients:
WaveletFilterCoefficients[CDFWavelet["9/7"], "PrimalHighpass"]Dual highpass filter coefficients:
WaveletFilterCoefficients[CDFWavelet["9/7"], "DualHighpass"]WaveletFilterCoefficients[CDFWavelet["9/7"], "LiftingFilter"]%[{"LiftingMatrixForm", z}]Generate function to compute lifting wavelet transform:
lf = WaveletFilterCoefficients[CDFWavelet["9/7"], "LiftingFilter"]lf["ForwardLiftingFunction"][Range[8]]lf["InverseLiftingFunction"][%]Plot[WaveletPhi[CDFWavelet["9/7"], x], {x, -4, 4}, PlotRange -> All]Plot[WaveletPhi[CDFWavelet["9/7"], x, "Dual"], {x, -3, 3}, PlotRange -> All]Plot scaling function using different levels of recursion:
Table[Plot[WaveletPhi[CDFWavelet["9/7"], x, MaxRecursion -> i], {x, -4, 4}, PlotLabel -> i, PlotRange -> All], {i, 1, 8, 2}]Plot[WaveletPsi[CDFWavelet["5/3"], x], {x, -3, 4}, PlotRange -> All]Plot[WaveletPsi[CDFWavelet["5/3"], x, "Dual"], {x, -1, 2}, PlotRange -> All]Plot scaling function using different levels of recursion:
Table[Plot[WaveletPsi[CDFWavelet["5/3"], x, "Dual", MaxRecursion -> i], {x, -1, 2}, PlotLabel -> i, PlotRange -> All], {i, 1, 8, 2}]Wavelet Transforms (5)
Compute a DiscreteWaveletTransform:
dwt = DiscreteWaveletTransform[[image], CDFWavelet["9/7"], 2]View the tree of wavelet coefficients:
dwt["TreeView"]Get the dimensions of wavelet coefficients:
dwt["Dimensions"]Plot the wavelet coefficients:
WaveletImagePlot[dwt]Compute a DiscreteWaveletPacketTransform:
dwpt = DiscreteWaveletPacketTransform[[image], CDFWavelet["9/7"], 1]View the tree of wavelet coefficients:
dwpt["TreeView"]Get the dimensions of wavelet coefficients:
dwpt["Dimensions"]Plot the wavelet coefficients:
dwpt[All, "Image"]Compute a StationaryWaveletTransform:
swt = StationaryWaveletTransform[[image], CDFWavelet["9/7"], 2];View the tree of wavelet coefficients:
swt["TreeView"]Get the dimensions of wavelet coefficients:
swt["Dimensions"]Plot the wavelet coefficients:
swt[Automatic, "Image"]Compute a StationaryWaveletPacketTransform:
swpt = StationaryWaveletPacketTransform[[image], CDFWavelet["9/7"], 1];View the tree of wavelet coefficients:
swpt["TreeView"]Get the dimensions of wavelet coefficients:
swpt["Dimensions"]Plot the wavelet coefficients:
swpt[All, "Image"]Compute a LiftingWaveletTransform:
lwt = LiftingWaveletTransform[[image], CDFWavelet["9/7"], 2];View the tree of wavelet coefficients:
lwt["TreeView"]Get the dimensions of wavelet coefficients:
lwt["Dimensions"]Plot the wavelet coefficients:
WaveletImagePlot[lwt]Higher Dimensions (1)
Multivariate scaling and wavelet functions are products of univariate ones:
ϕ = WaveletPhi[CDFWavelet[]];
ψ = WaveletPsi[CDFWavelet[]];Plot3D[Evaluate[ϕ[x]ψ[y]], {x, -4, 4}, {y, -4, 4}, PlotRange -> All, ColorFunction -> "SolarColors", Mesh -> None, Axes -> None]Plot3D[Evaluate[ϕ[x]ψ[y]], {x, -4, 4}, {y, -3, 4}, PlotRange -> All, ColorFunction -> "SolarColors", Mesh -> None, Axes -> None]Plot3D[Evaluate[ψ[x]ϕ[y]], {x, -3, 4}, {y, -4, 4}, PlotRange -> All, ColorFunction -> "SolarColors", Mesh -> None, Axes -> None]Plot3D[Evaluate[ψ[x]ψ[y]], {x, -3, 4}, {y, -3, 4}, PlotRange -> All, ColorFunction -> "SolarColors", Mesh -> None, Axes -> None]Properties & Relations (16)
Lowpass filter coefficients sum to unity; 
:
Total@WaveletFilterCoefficients[CDFWavelet["9/7"]][[All, 2]]Highpass filter coefficients sum to zero; 
:
Total@WaveletFilterCoefficients[CDFWavelet["9/7"], "PrimalHighpass"][[All, 2]]Dual lowpass filter coefficients sum to unity; 
:
Total@WaveletFilterCoefficients[CDFWavelet["9/7"], "DualLowpass"][[All, 2]]Dual highpass filter coefficients sum to zero; 
:
Total@WaveletFilterCoefficients[CDFWavelet["9/7"], "DualHighpass"][[All, 2]]Scaling function integrates to unity; 
:
Integrate[WaveletPhi[CDFWavelet["5/3"], x], {x, -∞, ∞}]Dual scaling function integrates to unity; 
:
Integrate[WaveletPhi[CDFWavelet["5/3"], x, "Dual"], {x, -∞, ∞}]Wavelet function integrates to zero; 
:
Integrate[WaveletPsi[CDFWavelet["5/3"], x], {x, -∞, ∞}]Dual wavelet function integrates to zero; 
:
Integrate[WaveletPsi[CDFWavelet["5/3"], x, "Dual"], {x, -∞, ∞}]
satisfies the recursion equation 
:
ϕ = WaveletPhi[CDFWavelet["9/7"]];a = WaveletFilterCoefficients[CDFWavelet["9/7"], "PrimalLowpass"];Plot the components and the sum of the recursion:
scalet[x_, ϕ_, a_] := 2Table[a[[i, 2]]ϕ[2x - a[[i, 1]]], {i, Length[a]}]{Plot[Evaluate@scalet[x, ϕ, a], {x, -4, 4}, PlotRange -> All],
Plot[Total@scalet[x, ϕ, a], {x, -4, 4}, PlotRange -> All]}
satisfies the recursion equation 
:
ϕ = WaveletPhi[CDFWavelet["9/7"]];b = WaveletFilterCoefficients[CDFWavelet["9/7"], "PrimalHighpass"];Plot the components and the sum of the recursion:
wavelet[x_, ϕ_, b_] := 2Table[b[[i, 2]]ϕ[2x - b[[i, 1]]], {i, Length[b]}]{Plot[Evaluate@wavelet[x, ϕ, b], {x, -3, 4}, PlotRange -> All], Plot[Total@wavelet[x, ϕ, b], {x, -3, 4}, PlotRange -> All]}
satisfies the recursion equation 
:
Overscript[ϕ, ~] = ( Evaluate[WaveletPhi[CDFWavelet["9/7"], #, "Dual"]]&);Overscript[a, ~] = WaveletFilterCoefficients[CDFWavelet["9/7"], "DualLowpass"];Plot the components and the sum of the recursion:
scalet[x_, ϕ_, a_] := 2 Table[a[[i, 2]] ϕ[2 x - a[[i, 1]]], {i, Length[a]}]{Plot[Evaluate@scalet[x, Overscript[ϕ, ~], Overscript[a, ~]], {x, -3, 3}, PlotRange -> All],
Plot[Total@scalet[x, Overscript[ϕ, ~], Overscript[a, ~]], {x, -3, 3}, PlotRange -> All]}
satisfies the recursion equation 
:
Overscript[ϕ, ~] = ( Evaluate[WaveletPhi[CDFWavelet["9/7"], #, "Dual"]]&);Overscript[b, ~] = WaveletFilterCoefficients[CDFWavelet["9/7"], "DualHighpass"];Plot the components and the sum of the recursion:
wavelet[x_, ϕ_, b_] := 2Table[b[[i, 2]]ϕ[2x - b[[i, 1]]], {i, Length[b]}]{Plot[Evaluate@wavelet[x, Overscript[ϕ, ~], Overscript[b, ~]], {x, -3, 3}, PlotRange -> All],
Plot[Total@wavelet[x, Overscript[ϕ, ~], Overscript[b, ~]], {x, -3, 3}, PlotRange -> All]}Frequency response for 
is given by 
:
h[wav_, ω_] := With[{a = WaveletFilterCoefficients[wav]}, Sum[a[[i, 2]]Exp[-I a[[i, 1]]ω], {i, Length[a]}]]The filter is a lowpass filter:
Plot[Abs[h[CDFWavelet["9/7"], ω]], {ω, -π, π}, Ticks -> {{-π, -(π/2), 0, (π/2), π}, Automatic}, AxesLabel -> {ω, Abs[H[ω]]}]Fourier transform of 
is given by 
:
h[wav_, ω_] := With[{a = WaveletFilterCoefficients[wav]}, Sum[a[[i, 2]]Exp[-I a[[i, 1]]ω], {i, Length[a]}]]fh[wav_, ω_, j_] := Abs[Product[h[wav, (ω/2^i)], {i, j}]]Plot[fh[CDFWavelet["9/7"], ω, 10], {ω, -7Pi, 7Pi}, PlotRange -> All,
AxesLabel -> {ω, Abs[ Overscript[ϕ, ^ ][ω]]}]Frequency response for 
is given by 
:
Overscript[h, ~][wav_, ω_] := With[{a = WaveletFilterCoefficients[wav, "DualLowpass"]}, Sum[a[[i, 2]]Exp[-I a[[i, 1]]ω], {i, Length[a]}]]The filter is a dual lowpass filter:
Plot[Abs[Overscript[h, ~][CDFWavelet["9/7"], ω]], {ω, -π, π}, Ticks -> {{-π, -(π/2), 0, (π/2), π}, Automatic}, AxesLabel -> {ω, Abs[Overscript[H, ~][ω]]}]Fourier transform of 
is given by 
:
Overscript[h, ~][wav_, ω_] := With[{a = WaveletFilterCoefficients[wav, "DualLowpass"]}, Sum[a[[i, 2]]Exp[-I a[[i, 1]]ω], {i, Length[a]}]]fh[wav_, ω_, j_] := Abs[Product[Overscript[h, ~][wav, (ω/2^i)], {i, j}]]Plot[fh[CDFWavelet["9/7"], ω, 10], {ω, -7Pi, 7Pi}, PlotRange -> All,
AxesLabel -> {ω, Abs[ Overscript[Overscript[ϕ, ~], ^ ][ω]]}]Frequency response for 
is given by 
:
g[wav_, ω_] := With[{b = WaveletFilterCoefficients[wav, "PrimalHighpass"]}, Sum[b[[i, 2]]Exp[-I b[[i, 1]]ω], {i, Length[b]}]
]The filter is a lowpass filter:
Plot[Abs[g[CDFWavelet["9/7"], ω]], {ω, -π, π}, Ticks -> {{-π, -(π/2), 0, (π/2), π}, Automatic}, AxesLabel -> {ω, Abs[G[ω]]}]Fourier transform of 
is given by 
:
h[wav_, ω_] := With[{a = WaveletFilterCoefficients[wav]}, Sum[a[[i, 2]]Exp[-I a[[i, 1]]ω], {i, Length[a]}]]g[wav_, ω_] := With[{b = WaveletFilterCoefficients[wav, "PrimalHighpass"]}, Sum[b[[i, 2]]Exp[-I b[[i, 1]]ω], {i, Length[b]}]
]fg[wav_, ω_, j_] := Abs[g[wav, (ω/2)]Product[h[wav, (ω/2^i)], {i, 2, j}]]Plot[fg[CDFWavelet["9/7"], ω, 10], {ω, -7Pi, 7Pi}, PlotRange -> All,
AxesLabel -> {ω, Abs[Overscript[ψ, ^ ][ω]]}]Frequency response for 
is given by 
:
Overscript[g, ~][wav_, ω_] := With[{b = WaveletFilterCoefficients[wav, "DualHighpass"]}, Sum[b[[i, 2]]Exp[-I b[[i, 1]]ω], {i, Length[b]}]
]The filter is a lowpass filter:
Plot[Abs[Overscript[g, ~][CDFWavelet["9/7"], ω]], {ω, -π, π}, Ticks -> {{-π, -(π/2), 0, (π/2), π}, Automatic}, AxesLabel -> {ω, Abs[Overscript[G, ~][ω]]}]Fourier transform of 
is given by 
:
Overscript[h, ~][wav_, ω_] := With[{a = WaveletFilterCoefficients[wav, "DualLowpass"]}, Sum[a[[i, 2]]Exp[-I a[[i, 1]]ω], {i, Length[a]}]]Overscript[g, ~][wav_, ω_] := With[{b = WaveletFilterCoefficients[wav, "DualHighpass"]}, Sum[b[[i, 2]]Exp[-I b[[i, 1]]ω], {i, Length[b]}]
]Overscript[fg, ~][wav_, ω_, j_] := Abs[Overscript[g, ~][wav, (ω/2)]Product[Overscript[h, ~][wav, (ω/2^i)], {i, 2, j}]]Plot[Overscript[fg, ~][CDFWavelet["9/7"], ω, 10], {ω, -7Pi, 7Pi}, PlotRange -> All,
AxesLabel -> {ω, Abs[ Overscript[Overscript[ψ, ~], ^ ][ω]]}]Neat Examples (2)
Plot translates and dilations of scaling function:
ϕ[x_, j_, k_] := 2^j / 2WaveletPhi[CDFWavelet["9/7"], 2^jx - k]Plot[Evaluate@Table[ϕ[x, j, 0], {j, 0, 4}], {x, -2, 2}, Filling -> Axis, PlotRange -> All, Axes -> {True, False}]Plot[Evaluate@Table[ϕ[x, 2, k], {k, 0, 2^2 - 1}], {x, -0.5, 2}, Filling -> Axis, PlotRange -> All]Plot translates and dilations of wavelet function:
ψ[x_, j_, k_] := 2^j / 2WaveletPsi[CDFWavelet["9/7"], 2^jx - k]Plot[Evaluate@Table[ψ[x, j, 0], {j, 0, 4}], {x, -0.5, 1}, Filling -> Axis, PlotRange -> All, Axes -> {True, False}]Plot[Evaluate@Table[ψ[x, 2, k], {k, 0, 2^2 - 1}], {x, -0.5, 1.5}, Filling -> Axis, PlotRange -> All]Text
Wolfram Research (2010), CDFWavelet, Wolfram Language function, https://reference.wolfram.com/language/ref/CDFWavelet.html.
CMS
Wolfram Language. 2010. "CDFWavelet." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/CDFWavelet.html.
APA
Wolfram Language. (2010). CDFWavelet. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/CDFWavelet.html