WOLFRAM

Wolfram Language & System Documentation Center

BrightnessEqualize[image]

adjusts the brightness across image, correcting uneven illumination.

BrightnessEqualize[image,flatfield]

uses the correction model given by flatfield, which models the variation in brightness across image.

BrightnessEqualize[image,flatfield,darkfield]

uses the dark environment model given by darkfield.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Data  
Parameters  
Options  
Masking  
Applications  
See Also
Tech Notes
Related Guides
History
Cite this Page

BrightnessEqualize

BrightnessEqualize[image]

adjusts the brightness across image, correcting uneven illumination.

BrightnessEqualize[image,flatfield]

uses the correction model given by flatfield, which models the variation in brightness across image.

BrightnessEqualize[image,flatfield,darkfield]

uses the dark environment model given by darkfield.

Details and Options

  • Local brightness adjustment is also known as flat fielding, and is used for removing image artifacts caused by nonuniform lighting or variations in sensor sensitivities.
  • BrightnessEqualize works with arbitrary 2D and 3D images, adjusting the lightness channel in the LABColor space.
  • A flatfield image is an image of a homogeneous signal like a plain well-lit white background. A darkfield is the same image obtained without lighting. The flat fielding of an image with an object in the same setting is given by (image-darkfield)xMean[flatfield-darkfield]/(flatfield-darkfield).
  • Possible settings for either flatfield or darkfield include:
  • vala constant value val
    corrimagea correction image (rescaled to the image dimensions)
    {scope,model}fit the data into a given model
  • The default flatfield consists of a 2nd order polynomial fit. The default darkfield is assumed to be 0.
  • Using {scope,model}, the flatfield or darkfield is estimated by fitting a function.
  • The scope parameter specifies whether to fit the entire image data or the image projections along each axis. Possible settings include:
  • "Global"fit the entire image to the model
    "Marginal"separately fit model to the projections along each axis
  • The model can be one of the following:
  • nan n-degree polynomial
    f,params,varsan arbitrary model f with parameters params and variables vars
  • The following options are available:
  • Masking Automaticthe regions to use for model estimation
    PerformanceGoalAutomaticaspects of performance to try to optimize
  • Using Masking->Automatic, over- and underexposed pixels are not used for the adjustment.
  • With partially transparent images, the alpha channel is multiplied with the mask.

Examples

open all close all

Basic Examples  (1)

Equalize brightness of a plain texture:

Wolfram Language code: BrightnessEqualize[[image]]

Scope  (7)

Data  (3)

Equalize a grayscale image of a scanned document:

Wolfram Language code: BrightnessEqualize[[image]]

Adjust brightness in an unevenly illuminated color photo:

Wolfram Language code: BrightnessEqualize[[image]]

Adjust brightness of a 3D CT scan image:

Wolfram Language code: BrightnessEqualize[\!\(\*Graphics3DBox[«13»]\)]

Parameters  (4)

Remove uneven illumination in a microscopy image by estimating the brightness distribution:

Wolfram Language code: img = [image];

Fitting a multivariate polynomial of first order on the entire image domain:

Wolfram Language code: BrightnessEqualize[img, {"Global", 1}]

Using a second-order polynomial:

Wolfram Language code: BrightnessEqualize[img, {"Global", 2}]

Fitting second-order univariate polynomials to the image marginals in each direction:

Wolfram Language code: BrightnessEqualize[img, {"Marginal", 2}]

Using a flatfield image:

Wolfram Language code: BrightnessEqualize[[image], [image]]

Remove a vignette effect by fitting the lightness channel to a given model:

Wolfram Language code: img = [image];

Assuming a rotationally symmetric, radial-dependent vignette:

Wolfram Language code: BrightnessEqualize[ img, {"Global", a + b(x^2 + y^2) + c(x^2 + y^2)^2 + d(x^2 + y^2)^3, {a, b, c, d}, {x, y}} ]

Assuming a Gaussian vignette:

Wolfram Language code: BrightnessEqualize[ img, {"Global", a Exp[-(x^2 + y^2) / σ^2], {a, σ}, {x, y}} ]

Perform a subtractive correction on an astronomical image by estimating the dark field:

Wolfram Language code: BrightnessEqualize[[image], 1, {"Global", 6}]

Options  (1)

Masking  (1)

By default, an automatic mask is used:

Wolfram Language code: img = [image];
Wolfram Language code: BrightnessEqualize[img, {"Global", 6}]

Equalize brightness based on the image background:

Wolfram Language code: mask = Erosion[Binarize[img], 1]
Wolfram Language code: BrightnessEqualize[img, {"Global", 6}, Masking -> mask]

Applications  (7)

Achieve a constant luminosity of the Moon surface:

Wolfram Language code: moon = [image];
Wolfram Language code: BrightnessEqualize[moon, {"Global", 4}, Masking -> Binarize[moon]]

Equalize brightness of a microscopy image:

Wolfram Language code: img = [image];

Identify the background:

Wolfram Language code: mask = ColorNegate@AlphaChannel@RemoveBackground[img]

Equalize brightness distribution assuming a homogeneous background:

Wolfram Language code: BrightnessEqualize[img, Masking -> mask]

Equalize color distribution by handling each channel separately:

Wolfram Language code: ColorCombine[BrightnessEqualize[#, Masking -> mask]& /@ ColorSeparate[img]]

Remove uneven illumination from a scanned document:

Wolfram Language code: scan = [image];

Create a mask to omit text in the subsequent equilibration:

Wolfram Language code: mask = ColorNegate@Closing[Binarize[BottomHatTransform[scan, 12]], 1]

Equalize brightness distribution fitting a sixth-order polynomial:

Wolfram Language code: BrightnessEqualize[scan, {"Global", 6}, Masking -> mask]

This improves the text recognition result:

Wolfram Language code: TextRecognize[%]

Equalize the brightness distribution without a mask applying a horizontal fit:

Wolfram Language code: BrightnessEqualize[scan, {"Marginal", {6, 0}}]

This also improves the text recognition result:

Wolfram Language code: TextRecognize[%]

Reduce the vignette effect of a photograph:

Wolfram Language code: img = [image];

Compute a mask for the background that is expected to have even illumination:

Wolfram Language code: mask = ColorNegate@AlphaChannel@RemoveBackground[img]

Equalize image brightness:

Wolfram Language code: BrightnessEqualize[img, {"Global", 3}, Masking -> mask]

Remove CCD artifacts from an image taken by a low-quality camera with many pixel defects.

Flat-field image of the camera:

Wolfram Language code: flatfield = [image];

Microscopy image of a tear drop:

Wolfram Language code: image = [image];

Flat-field correction:

Wolfram Language code: BrightnessEqualize[image, flatfield]

Correct uneven illumination in an MR scan:

Wolfram Language code: img = [image];

Use only muscle tissue for brightness estimation:

Wolfram Language code: mask = Opening[Binarize[img, {.12, .3}], 1]
Wolfram Language code: BrightnessEqualize[img, Masking -> mask] // ImageAdjust

Correct uneven brightness in a 3D magnetic resonance volume:

Wolfram Language code: knee = [image];

Note the reduced brightness toward the perimeter of the volume:

Wolfram Language code: Image3D[knee, ColorFunction -> "GrayLevelAlpha", ClipRange -> {All, {0, 23}, All}, Boxed -> True]

Select the muscle tissue to estimate the brightness distribution:

Wolfram Language code: ImageHistogram[knee]
Wolfram Language code: mask = Erosion[Binarize[knee, {.05, .3}], 1]

Estimate the brightness distribution by a polynomial in cylindrical coordinates of even orders up to 4:

Wolfram Language code: knee2 = BrightnessEqualize[knee, {"Global", {1, x^2 + y^2, z^2, (x^2 + y^2)^2, z^4, (x^2 + y^2)z^2}, {x, y, z}}, Masking -> mask];

Compare the initial volume and the result with equalized brightness:

Wolfram Language code: Map[Image3D[#, ColorFunction -> "GrayLevelAlpha", ClipRange -> {All, {0, 23}, All}, Boxed -> True]&, {knee, knee2}]//GraphicsRow
Wolfram Research (2017), BrightnessEqualize, Wolfram Language function, https://reference.wolfram.com/language/ref/BrightnessEqualize.html.

Text

Wolfram Research (2017), BrightnessEqualize, Wolfram Language function, https://reference.wolfram.com/language/ref/BrightnessEqualize.html.

CMS

Wolfram Language. 2017. "BrightnessEqualize." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/BrightnessEqualize.html.

APA

Wolfram Language. (2017). BrightnessEqualize. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/BrightnessEqualize.html

BibTeX

@misc{reference.wolfram_2026_brightnessequalize, author="Wolfram Research", title="{BrightnessEqualize}", year="2017", howpublished="\url{https://reference.wolfram.com/language/ref/BrightnessEqualize.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_brightnessequalize, organization={Wolfram Research}, title={BrightnessEqualize}, year={2017}, url={https://reference.wolfram.com/language/ref/BrightnessEqualize.html}, note=[Accessed: 13-June-2026]}