WOLFRAM

Wolfram Language & System Documentation Center

ColumnKeyExistsQ[data,key]

returns True if the specified key exists in the tabular data, and False otherwise.

ColumnKeyExistsQ[key]

represents an operator form of ColumnKeyExistsQ that can be applied to an expression.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Data Forms  
Key Forms  
Properties & Relations  
See Also
Related Guides
History
Cite this Page

ColumnKeyExistsQ

ColumnKeyExistsQ[data,key]

returns True if the specified key exists in the tabular data, and False otherwise.

ColumnKeyExistsQ[key]

represents an operator form of ColumnKeyExistsQ that can be applied to an expression.

Details

Examples

open all close all

Basic Examples  (1)

Check whether a column key exists in a Tabular object:

Wolfram Language code: Tabular[{{1, 2, 3}, {4, 5, 6}}, {"a", "b", "c"}]
Wolfram Language code: ColumnKeyExistsQ[%, "b"]
Wolfram Language code: ColumnKeyExistsQ[%%, "d"]

Scope  (8)

Data Forms  (6)

Check the presence of a column key in a Tabular object:

Wolfram Language code: tab = Tabular[{{1.2, "a", True}, {-3.5, "f", False}}, {"col1", "col2", "col3"}]
Wolfram Language code: ColumnKeyExistsQ[tab, "col3"]
Wolfram Language code: ColumnKeyExistsQ[tab, "col"]

For a Tabular object without column keys, ColumnKeyExistsQ always returns False:

Wolfram Language code: tab = Tabular[{{1, 2, 3}, {4, 5, 6}}]
Wolfram Language code: ColumnKeyExistsQ[tab, 2]
Wolfram Language code: ColumnKeyExistsQ[tab, "2"]
Wolfram Language code: ColumnKeyExistsQ[tab, "Column2"]

Check the presence of a key in any of the associations of a list of them:

Wolfram Language code: assocs = {<|"a" -> 1, "b" -> 1.5|>, <|"a" -> 2, "c" -> 3.5|>};
Wolfram Language code: ColumnKeyExistsQ[assocs, "a"]
Wolfram Language code: ColumnKeyExistsQ[assocs, "b"]
Wolfram Language code: ColumnKeyExistsQ[assocs, "c"]
Wolfram Language code: ColumnKeyExistsQ[assocs, "d"]

ColumnKeyExistsQ effectively assumes Missing[…] values, as Tabular would do:

Wolfram Language code: Tabular[assocs]

Check the presence of a column key in a Dataset object:

Wolfram Language code: ds = Dataset[{<|"a" -> 1, "b" -> True|>, <|"a" -> 3, "b" -> False|>}]
Wolfram Language code: ColumnKeyExistsQ[ds, "b"]
Wolfram Language code: ColumnKeyExistsQ[ds, "c"]

Check the presence of a component key in an EventSeries object:

Wolfram Language code: EventSeries[{{1, "dog"}, {2, "cat"}, {4, "fox"}}, {{0, 0.1, 0.5}}, ComponentKeys -> {"number", "animal"}]
Wolfram Language code: ColumnKeyExistsQ[%, "animal"]
Wolfram Language code: ColumnKeyExistsQ[%%, "foo"]

Use ColumnKeyExistsQ as an operator form:

Wolfram Language code: Tabular[{{1.2, "a"}, {-3.5, "f"}}, {"col1", "col2"}]
Wolfram Language code: %//ColumnKeyExistsQ["col2"]
Wolfram Language code: %%//ColumnKeyExistsQ["COL2"]

Key Forms  (2)

Check whether a given column key is present in a Tabular object:

Wolfram Language code: tab = Tabular[{{1, "a", True}, {2, "b", False}}, {"col1", "col2", "col3"}]
Wolfram Language code: ColumnKeyExistsQ[tab, "col2"]

The key in ColumnKeyExistsQ[tab,key] can be wrapped in Key or ExtendedKey:

Wolfram Language code: ColumnKeyExistsQ[tab, Key["col2"]]
Wolfram Language code: ColumnKeyExistsQ[tab, ExtendedKey["col2"]]

Take a Tabular object with extended column keys:

Wolfram Language code: tab = Tabular[{{1, "a", 3.2}, {2, "b", 7.5}}, {ExtendedKey["col1", "number"], ExtendedKey["col1", "string"], ExtendedKey["col2", "number"]}]

Check whether a given extended key is present:

Wolfram Language code: ColumnKeyExistsQ[tab, ExtendedKey["col1", "string"]]
Wolfram Language code: ColumnKeyExistsQ[tab, ExtendedKey["col2", "string"]]

Extended keys can be addressed by their last argument if they are unique:

Wolfram Language code: ColumnKeyExistsQ[tab, "string"]
Wolfram Language code: ColumnKeyExistsQ[tab, "number"]

Properties & Relations  (2)

ColumnKeyExistsQ[tab,key] is equivalent to MemberQ[ColumnKeys[tab],key]:

Wolfram Language code: tab = Tabular[{{1, "a", True}, {2, "b", False}}, {"col1", "col2", "col3"}]
Wolfram Language code: {ColumnKeyExistsQ[tab, "col2"], ColumnKeyExistsQ[tab, "col4"]}
Wolfram Language code: keys = ColumnKeys[tab]
Wolfram Language code: {MemberQ[keys, "col2"], MemberQ[keys, "col4"]}

For a list assocs of associations, ColumnKeyExistsQ[assocs,key] is equivalent to using KeyExistsQ in the associations:

Wolfram Language code: assocs = {<|"a" -> 1, "b" -> True|>, <|"a" -> 4, "c" -> Today|>}
Wolfram Language code: ColumnKeyExistsQ["a"]@assocs
Wolfram Language code: KeyExistsQ["a"] /@ assocs

ColumnKeyExistsQ returns True if the key exists in any of the associations:

Wolfram Language code: ColumnKeyExistsQ["b"]@assocs
Wolfram Language code: KeyExistsQ["b"] /@ assocs
Wolfram Research (2025), ColumnKeyExistsQ, Wolfram Language function, https://reference.wolfram.com/language/ref/ColumnKeyExistsQ.html (updated 2026).

Text

Wolfram Research (2025), ColumnKeyExistsQ, Wolfram Language function, https://reference.wolfram.com/language/ref/ColumnKeyExistsQ.html (updated 2026).

CMS

Wolfram Language. 2025. "ColumnKeyExistsQ." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2026. https://reference.wolfram.com/language/ref/ColumnKeyExistsQ.html.

APA

Wolfram Language. (2025). ColumnKeyExistsQ. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ColumnKeyExistsQ.html

BibTeX

@misc{reference.wolfram_2026_columnkeyexistsq, author="Wolfram Research", title="{ColumnKeyExistsQ}", year="2026", howpublished="\url{https://reference.wolfram.com/language/ref/ColumnKeyExistsQ.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_columnkeyexistsq, organization={Wolfram Research}, title={ColumnKeyExistsQ}, year={2026}, url={https://reference.wolfram.com/language/ref/ColumnKeyExistsQ.html}, note=[Accessed: 13-June-2026]}