Wolfram Language & System Documentation Center

ConicHullRegion[{p₁,…,p_m+1}]

represents the m-dimensional affine hull region passing through points p_i.

ConicHullRegion[p,{v₁,…,v_m}]

represents the m-dimensional affine hull region passing through the point p and parallel to v_i.

ConicHullRegion[{p₁,…,p_m+1},{w₁,…,w_n}]

represents the m-dimensional affine hull plus the conic hull generated by the vectors w_j.

ConicHullRegion[p,{v₁,…,v_m},{w₁,…,w_n}]

represents the m-dimensional affine hull plus the conic hull generated by the vectors w_j.

ConicHullRegion

ConicHullRegion[{p₁,…,p_m+1}]

represents the m-dimensional affine hull region passing through points p_i.

ConicHullRegion[p,{v₁,…,v_m}]

represents the m-dimensional affine hull region passing through the point p and parallel to v_i.

ConicHullRegion[{p₁,…,p_m+1},{w₁,…,w_n}]

represents the m-dimensional affine hull plus the conic hull generated by the vectors w_j.

ConicHullRegion[p,{v₁,…,v_m},{w₁,…,w_n}]

represents the m-dimensional affine hull plus the conic hull generated by the vectors w_j.

Details

ConicHullRegion is also known as affine space, half-space, and affine hull in special cases.
ConicHullRegion can be used as a geometric region and graphics primitive.

The cases ConicHullRegion[{p₁,…,p_m+1}] and ConicHullRegion[p,{v₁,…,v_m}] represent an affine hull, which is commonly known as an infinite line, infinite plane, or infinite space.
The conic directions w_j represent a pure conic hull that is added to each point in the affine hull, also known as a Minkowski sum of an affine hull and a conic hull.
Parametric representations are given by:

	ConicHullRegion[{p₁,…,p_m+1}]
	ConicHullRegion[p,{v₁,…,v_m}]
	ConicHullRegion[{p₁,…,p_m+1},{w₁,…,w_n}]
	ConicHullRegion[p,{v₁,…,v_m},{w₁,…,w_n}]

Low-dimensional versions of ConicHullRegion have special representations:

	ConicHullRegion[{p₁,p₂}]	InfiniteLine[{p₁,p₂}]
	ConicHullRegion[{p₁,p₂,p₃}]	InfinitePlane[{p₁,p₂,p₃}]
	ConicHullRegion[{p₁},{w₁}]	HalfLine[p₁,w₁]
	ConicHullRegion[{p₁,p₂},{w₁}]	HalfPlane[{p₁,p₂},w₁]

ConicHullRegion[p,{v₁,…,v_m}] represents an m-dimensional region if the v_i are linearly independent.
ConicHullRegion can be used in Graphics and Graphics3D.
In graphics, the points p, p_i and vectors v_i, w_j can be Dynamic expressions.
Graphics rendering is affected by directives such as FaceForm, EdgeForm, Opacity, and color.

Examples

open all close all

Basic Examples (3)

A ConicHullRegion in 2D:

Wolfram Language code: Graphics[ConicHullRegion[{{0, 0}}, {{1, -1}, {1, 1}}]]

And in 3D:

Wolfram Language code: Graphics3D[ConicHullRegion[{{0, 0, 0}}, {{-10, 2, 3}, {1, 1, 0}}]]

Different styles applied to a conic hull region:

Wolfram Language code: ℛ = ConicHullRegion[{{0, 0}}, {{1, -1}, {1, 1}}];

Wolfram Language code:

{Graphics[{Pink, ℛ}], Graphics[{EdgeForm[Thick], Pink, ℛ}], Graphics[{EdgeForm[Dashed], Pink, ℛ}], Graphics[{EdgeForm[Directive[Thick, Dashed, Blue]], Pink, ℛ}]}

Determine if points belong to a given conic hull region:

Wolfram Language code: ℛ = ConicHullRegion[{{0, 0}}, {{1, -1}, {1, 1}}];

Wolfram Language code: {RegionMember[ℛ, {1, 0}], RegionMember[ℛ, {-1, 0}]}

Scope (25)

Graphics (15)

Specification (7)

Define an infinite line passing through {1,1} and {3,2}:

Wolfram Language code: ill = Graphics[{PointSize[Medium], Point[{{1, 1}, {3, 2}}]}, PlotRange -> {{0, 4}, {0, 3}}, Frame -> True];

Wolfram Language code: Show[ill, Graphics[ConicHullRegion[{{1, 1}, {3, 2}}]]]

Define the same line passing through {1,1} in the direction {2,1}:

Wolfram Language code:

ill = Graphics[{PointSize[Medium], Point[{{1, 1}}], Arrowheads[Medium], Thick, Arrow[{{1, 1}, {3, 2}}]}, PlotRange -> {{0, 4}, {0, 3}}, Frame -> True];

Wolfram Language code: Show[ill, Graphics[ConicHullRegion[{1, 1}, {{2, 1}}]]]

Define the upper half-plane using a point, a vector, and a conic direction:

Wolfram Language code:

ill = Graphics[{PointSize[Medium], Point[{{0, 0}}], Arrowheads[Medium], Thick, Arrow[{{0, 0}, {1, 0}}], Arrow[{{0, 0}, {0, 1}}]}];

Wolfram Language code: Show[Graphics[{Pink, ConicHullRegion[{0, 0}, {{1, 0}}, {{0, 1}}]}, PlotRange -> {{-1, 2}, {-1, 2}}, Frame -> True], ill]

Or a 2D infinite space using a point and two conic directions:

Wolfram Language code:

ill = Graphics[{PointSize[Medium], Point[{{0, 0}}], Arrowheads[Medium], Thick, Arrow[{{0, 0}, {1, 1}}], Arrow[{{0, 0}, {-1, 1}}]}];

Wolfram Language code:

Show[Graphics[{Pink, ConicHullRegion[{{0, 0}}, {{1, 1}, {-1, 1}}]}, PlotRange -> {{-2, 2}, {-1, 2}}, Frame -> True], ill]

Define an infinite line in 3D passing through the points and :

Wolfram Language code: ill = Graphics3D[{PointSize[Medium], Point[{{1, 1, 1}, {2, 3, 4}}]}, PlotRange -> 5, Axes -> True];

Wolfram Language code: Show[ill, Graphics3D[ConicHullRegion[{{1, 1, 1}, {2, 3, 4}}]]]

Define the same line using the point and a direction vector:

Wolfram Language code:

ill = Graphics3D[{PointSize[Medium], Point[{{1, 1, 1}}], Arrowheads[Medium], Thick, Arrow[{{1, 1, 1}, {2, 3, 4}}]}, PlotRange -> 5, Axes -> True];

Wolfram Language code: Show[ill, Graphics3D[ConicHullRegion[{1, 1, 1}, {{1, 2, 3}}]]]

Define the plane passing through the points , , and :

Wolfram Language code:

ill = Graphics3D[{PointSize[Medium], Point[{{0, 1, 3}, {1, 0, 1}, {1, 2, 3}}]}, PlotRange -> {{-1, 2}, {-1, 3}, {0, 4}}, Axes -> True];

Wolfram Language code: Show[ill, Graphics3D[{Opacity[0.5], ConicHullRegion[{{0, 1, 3}, {1, 0, 1}, {1, 2, 3}}]}]]

Define the same plane using a point and direction vectors:

Wolfram Language code:

ill = Graphics3D[{PointSize[Medium], Point[{{0, 1, 3}}], Arrowheads[Medium], Thick, Arrow[{{0, 1, 3}, {1, 0, 1}}], Arrow[{{0, 1, 3}, {1, 2, 3}}]}, PlotRange -> {{-1, 2}, {-1, 3}, {0, 4}}, Axes -> True];

Wolfram Language code: Show[ill, Graphics3D[{Opacity[0.5], ConicHullRegion[{0, 1, 3}, {{1, -1, -2}, {1, 1, 0}}]}]]

Define a 2D infinite cone with tip and directions and :

Wolfram Language code:

ill = Graphics3D[{PointSize[Medium], Point[{{0, 0, 0}}], Arrowheads[Medium], Thick, Arrow[{{0, 0, 0}, {0, 1, 2}}], Arrow[{{0, 0, 0}, {1, 2, 0}}]}, PlotRange -> {{-1, 3}, {-1, 3}, {-1, 3}}, Axes -> True];

Wolfram Language code: Show[ill, Graphics3D[ConicHullRegion[{{0, 0, 0}}, {{0, 1, 2}, {1, 2, 0}}]]]

A 3D half-space can be defined with a point, two vectors, and a conic direction:

Wolfram Language code: Graphics3D[ConicHullRegion[{0, 0, 0}, {{1, 0, 0}, {0, 1, 0}}, {{0, 0, 1}}]]

A 3D infinite space can be defined with a point and some conic directions:

Wolfram Language code: Graphics3D[ConicHullRegion[{{0, 0, 0}}, {{1, 1, 0}, {0, 1, 1}, {1, 0, 1}}]]

Styling (7)

A 1D conic hull region with varying thickness:

Wolfram Language code: Table[Graphics[{Thickness[i], ConicHullRegion[{{0, 0}, {2, 1}}]}], {i, {Tiny, Small, Medium, Large}}]

Wolfram Language code: Table[Graphics[{t, ConicHullRegion[{{0, 0}, {2, 1}}]}], {t, {Thin, Thick}}]

Thickness in scaled size:

Wolfram Language code: Table[Graphics[{Thickness[i], ConicHullRegion[{{0, 0}, {2, 1}}]}], {i, {.005, .05, .1}}]

Thickness in printer's points:

Wolfram Language code: Table[Graphics[{AbsoluteThickness[i], ConicHullRegion[{{0, 0}, {2, 1}}]}], {i, {1, 5, 10}}]

1D conic hull regions can be rendered in dashed or dotted styles:

Wolfram Language code: Table[Graphics[{Dashing[i], ConicHullRegion[{{0, 0}, {2, 1}}]}], {i, {Tiny, Small, Medium, Large}}]

Wolfram Language code: Table[Graphics[{d, ConicHullRegion[{{0, 0}, {2, 1}}]}], {d, {Dotted, Dashed, DotDashed}}]

Color directives specify the edge color for 1D conic hull regions:

Wolfram Language code: Table[Graphics[{c, ConicHullRegion[{{0, 0}, {2, 1}}]}], {c, {Red, Green, Blue, Yellow}}]

Color directives specify the face color for higher-dimensional regions:

Wolfram Language code: Table[Graphics[{c, ConicHullRegion[{{0, 0}}, {{1, -1}, {1, 2}}]}], {c, {Red, Green, Blue, Yellow}}]

Wolfram Language code: Table[Graphics3D[{c, ConicHullRegion[{{1, 0, 0}, {1, 1, 1}, {0, 0, 1}}]}], {c, {Red, Green, Blue, Yellow}}]

FaceForm and EdgeForm can be used to specify the styles of the faces and edges:

Wolfram Language code: Graphics[{FaceForm[Pink], EdgeForm[Directive[Dashed, Thick, Blue]], ConicHullRegion[{{0, 0}}, {{1, -1}, {1, 2}}]}]

Wolfram Language code:

Graphics3D[{FaceForm[Pink], EdgeForm[Directive[Dashed, Thick, Blue]], ConicHullRegion[{{1, 0, 0}, {1, 1, 1}, {0, 0, 1}}]}]

In 3D, different properties can be specified for the front and back of faces using FaceForm:

Wolfram Language code: p = {FaceForm[Yellow, Blue], ConicHullRegion[{{0, 0, 0}}, {{1, -1, 0}, {1, 2, 0}}]};

Wolfram Language code: {Graphics3D[p, ViewPoint -> Top], Graphics3D[p, ViewPoint -> Bottom]}

Coordinates (1)

Scaled coordinates can be used in 2D:

Wolfram Language code: Graphics[ConicHullRegion[Scaled[{0, 0}], {Scaled[{1, 1}]}], Frame -> True]

And in 3D:

Wolfram Language code: Graphics3D[ConicHullRegion[Scaled[{0, 0, 0}], {Scaled[{1, 1, 0}], Scaled[{0, 1, 1}]}]]

Regions (10)

Embedding dimension is the dimension in which the ConicHullRegion lives:

Wolfram Language code:

line = ConicHullRegion[{0, 0}, {{1, 1}}];
hplane = ConicHullRegion[{0, 0}, {{1, 1}}, {{1, 0}}];

Wolfram Language code: RegionEmbeddingDimension /@ {line, hplane}

Geometric dimension is the dimension of the region itself:

Wolfram Language code: RegionDimension /@ {line, hplane}

Point membership test:

Wolfram Language code: ℛ = ConicHullRegion[{{0, 0, 0}, {1, 1, 1}}];

Wolfram Language code: {RegionMember[ℛ, {2, 2, 2}], RegionMember[ℛ, {2, 2, 3}]}

Get conditions for point membership:

Wolfram Language code: RegionMember[ℛ, {x, y, z}]

A ConicHullRegion has infinite measure:

Wolfram Language code: ℛ = ConicHullRegion[{{1, 2}, {3, 4}}];

Wolfram Language code: RegionMeasure[ℛ]

And indeterminate centroid:

Wolfram Language code: RegionCentroid[ℛ]

Distance from a point:

Wolfram Language code: ℛ = ConicHullRegion[{{2, 2}}, {{3, 1}, {1, 3}}];

Wolfram Language code: RegionDistance[ℛ, {0, 1}]

Distance to the nearest point:

Wolfram Language code:

{Plot3D[Evaluate@RegionDistance[ℛ, {x, y}], {x, 1, 3}, {y, 1, 3}, MeshFunctions -> {#3&}, Mesh -> 5, Exclusions -> None], ContourPlot[Evaluate@RegionDistance[ℛ, {x, y}], {x, 0, 4}, {y, 0, 4}, Contours -> {{0.5, Red}, {1, Green}, {1.5, Blue}}, Exclusions -> None]}

Signed distance from a point:

Wolfram Language code: ℛ = ConicHullRegion[{{0, 0}, {1, 0}}, {{0, 1}}];

Wolfram Language code: SignedRegionDistance[ℛ, {2, 3}]

Nearest point in the region:

Wolfram Language code: ℛ = ConicHullRegion[{{2, 2}, {3, 3}}];

Wolfram Language code: RegionNearest[ℛ, {5, 6}]

Visualize it:

Wolfram Language code:

pts = Table[{1, 2} + 5{Cos[k 2 π / 16], Sin[k 2π / 16]}, {k, 0., 15}];
nst = RegionNearest[ℛ, #]& /@ pts;

Wolfram Language code:

Legended[Graphics[{{Thick, Gray, ℛ}, {Thin, Gray, Line[Transpose[{pts, nst}]]}, {Red, Point[pts]}, {Blue, Point[nst]}}], PointLegend[{Red, Blue}, {"start", "nearest"}]]

A conic hull region is unbounded:

Wolfram Language code: ℛ = ConicHullRegion[{{0, 0, 0}, {1, 0, 0}}, {{0, 1, 0}}];

Wolfram Language code: BoundedRegionQ[ℛ]

But may not be unbounded in all dimensions:

Wolfram Language code: RegionBounds[ℛ]

Integrate over a ConicHullRegion:

Wolfram Language code: ℛ = ConicHullRegion[{0, 0}, {{1, 0}, {0, 1}}];

Wolfram Language code: Integrate[Exp[-(x^2 + y^2)], {x, y}∈ℛ]

Optimize over it:

Wolfram Language code: ℛ = ConicHullRegion[{{0, 1}, {1, 0}}, {{1, 1}}];

Wolfram Language code: Maximize[{-(x^2 + y^2), {x, y}∈ℛ}, {x, y}]

Solve equations over a conic hull:

Wolfram Language code: ℛ = ConicHullRegion[{{0, 0}}, {{0, 1}, {1 / 2, 1 / 2}}];

Wolfram Language code: Reduce[x^2 + y^2 == 1 && {x, y}∈ℛ, {x, y}]

Applications (4)

Define a region that occupies each quadrant:

Wolfram Language code: rl = Flatten[Table[ConicHullRegion[{{0, 0}}, {{x, 0}, {0, y}}], {x, {-1, 1}}, {y, {-1, 1}}]]

Wolfram Language code: Table[Graphics[{StandardBlue, r}, Axes -> True], {r, rl}]

Define a region that occupies each octant:

Wolfram Language code:

rl = Flatten[Table[ConicHullRegion[{{0, 0, 0}}, {{x, 0, 0}, {0, y, 0}, {0, 0, z}}], {x, {-1, 1}}, {y, {-1, 1}}, {z, {-1, 1}}]];

Wolfram Language code: Graphics3D /@ rl

Construct a conic hull region from a center point and points on a circle:

Wolfram Language code: rl = Table[ConicHullRegion[{{0, 0, -1}}, Table[{Cos[k 2π / n], Sin[k 2π / n], 1}, {k, 0., n - 1}]], {n, 3, 12, 3}];

Wolfram Language code: Table[Graphics3D[{Opacity[0.5], Yellow, r}, PlotRange -> {{-1, 1}, {-1, 1}, {-1, 1}}], {r, rl}]

Construct a conic hull region from a center point and points on a parametric curve:

Wolfram Language code:

o = {0, 0, 0};
f[t_] := {16Sin[t] ^ 3, 13Cos[t] - 5Cos[2t] - 2Cos[3t] - Cos[4t], 16};
pts = Table[f[t], {t, 0, 2π, 0.1}];

Wolfram Language code:

chr = ConicHullRegion[{o}, pts];
Graphics3D[chr, PlotRange -> {{-16, 16}, {-17, 12}, {0, 16}}]

Properties & Relations (5)

InfiniteLine is a special case of ConicHullRegion:

Wolfram Language code: pl = {{1, 2}, {3, 4}};

Wolfram Language code: Reduce[{x, y}∈ConicHullRegion[pl]⧦{x, y}∈InfiniteLine[pl], {x, y}, Reals]

HalfLine is a special case of ConicHullRegion:

Wolfram Language code:

Subscript[ℛ, 1] = ConicHullRegion[{{0, 0}}, {{1, 1}}];
Subscript[ℛ, 2] = HalfLine[{0, 0}, {1, 1}];

Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

InfinitePlane is a special case of ConicHullRegion:

Wolfram Language code:

Subscript[ℛ, 1] = ConicHullRegion[{0, 0, 0}, {{1, 0, 0}, {0, 1, 0}}];
Subscript[ℛ, 2] = InfinitePlane[{0, 0, 0}, {{1, 0, 0}, {0, 1, 0}}];

Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

HalfPlane is a special case of ConicHullRegion:

Wolfram Language code:

Subscript[ℛ, 1] = ConicHullRegion[{{0, 0}, {1, 0}}, {{0, 1}}];
Subscript[ℛ, 2] = HalfPlane[{{0, 0}, {1, 0}}, {0, 1}];

Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

ImplicitRegion can represent any ConicHullRegion:

Wolfram Language code: Subscript[ℛ, 1] = ImplicitRegion[-1 - x + y == 0, {x, y}];

Wolfram Language code: Subscript[ℛ, 2] = ConicHullRegion[{{1, 2}, {3, 4}}];

Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

Neat Examples (1)

A collection of random affine cones:

Wolfram Language code:

Graphics[{EdgeForm[Black], Table[{Hue[RandomReal[]], Opacity[0.1], ConicHullRegion[{RandomReal[1, 2]}, RandomReal[{-1, 1}, {2, 2}]]}, {75}]}]

Top

More Learning

Tech Support

Wolfram Solutions

Wolfram Solutions For Education

Get Started

Grow Your Skills

Work with Us

Educational Programs for Adults

Educational Programs for Youth

Read

ConicHullRegion

Details

Examples

Basic Examples (3)

Scope (25)

Graphics (15)

Specification (7)

Styling (7)

Coordinates (1)

Regions (10)

Applications (4)

Properties & Relations (5)

Neat Examples (1)

Text

CMS

APA

BibTeX

BibLaTeX

ConicHullRegion

Details

Examples

Basic Examples (3)

Scope (25)

Graphics (15)

Specification (7)

Styling (7)

Coordinates (1)

Regions (10)

Applications (4)

Properties & Relations (5)

Neat Examples (1)

See Also

Related Guides

History

Text

CMS

APA

BibTeX

BibLaTeX