Wolfram Language & System Documentation Center

HypergeometricU

HypergeometricU[a,b,z]

is the Tricomi confluent hypergeometric function .

Details

Mathematical function, suitable for both symbolic and numerical manipulation.
The function has the integral representation $TemplateBox[{a, b, z}, HypergeometricU]=1/TemplateBox[{a}, Gamma]int_0^inftye^(-zt)t^(a-1)(1+t)^(b-a-1) dt$ .
HypergeometricU[a,b,z] has a branch cut discontinuity in the complex plane running from to .
For certain special arguments, HypergeometricU automatically evaluates to exact values.
HypergeometricU can be evaluated to arbitrary numerical precision.
HypergeometricU automatically threads over lists.
HypergeometricU can be used with Interval and CenteredInterval objects. »

Examples

open all close all

Basic Examples (5)

Evaluate numerically:

Wolfram Language code: HypergeometricU[3, 2, 1.]

Plot over a subset of the reals:

Wolfram Language code: Plot[HypergeometricU[3, 2, x], {x, 0.5, 2}]

Plot over a subset of the complexes:

Wolfram Language code: ComplexPlot3D[HypergeometricU[3, 2, z], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

Series expansion at the origin:

Wolfram Language code: Series[HypergeometricU[3, 2, x], {x, ∞, 5}]

Series expansion at Infinity:

Wolfram Language code: Series[HypergeometricU[3, 2, x], {x, ∞, 8}]//Normal

Scope (39)

Numerical Evaluation (5)

Evaluate to high precision:

Wolfram Language code: N[ HypergeometricU[1 / 3, 2 / 3, 2], 50]

The precision of the output tracks the precision of the input:

Wolfram Language code: HypergeometricU[1 / 3, 2 / 3, 2.000000000000000000000000000000]

Evaluate for complex arguments:

Wolfram Language code: HypergeometricU[3 - I, 2I, 3.0]

Evaluate HypergeometricU efficiently at high precision:

Wolfram Language code: HypergeometricU[1 / 3, 2, 3`500]//Timing

Wolfram Language code: HypergeometricU[1 / 3, 2, 3`2000];//Timing

Compute worst-case guaranteed intervals using Interval and CenteredInterval objects:

Wolfram Language code: HypergeometricU[2 / 3, 1 / 2, Interval[{0.21, 0.22}]]

Wolfram Language code: HypergeometricU[2 / 3, 1 / 2, CenteredInterval[1 / 5, 1 / 100]]

Or compute average-case statistical intervals using Around:

Wolfram Language code: HypergeometricU[1 / 2, 1, Around[1 / 2, 0.01]]

Compute the elementwise values of an array:

Wolfram Language code: HypergeometricU[1 / 2, 1 / 2, {{1 / 2, 0}, {1, 1 / 2}}]

Or compute the matrix HypergeometricU function using MatrixFunction:

Wolfram Language code: MatrixFunction[HypergeometricU[1 / 2, 1 / 2, #]&, {{1 / 2, 0}, {1, 1 / 2}}]

Specific Values (3)

HypergeometricU automatically evaluates to simpler functions for certain parameters:

Wolfram Language code: HypergeometricU[1, 3, x]

Wolfram Language code: HypergeometricU[1 / 2, 1, x]

Limiting value at infinity:

Wolfram Language code: Limit[HypergeometricU[a, b, x], x -> Infinity]

Find a value of satisfying the equation :

Wolfram Language code:

f[x_] := HypergeometricU[3, 2, x] - 1;
xzero = Solve[f[x] == 0 && 0 < x < 0.5, x][[1, 1, 2]]//Quiet

Wolfram Language code: Plot[f[x], {x, 0, 1}, Epilog -> Style[Point[{xzero, f[xzero]}], PointSize[Large], Red]]

Visualization (3)

Plot the HypergeometricU function:

Wolfram Language code:

Plot[{HypergeometricU[-1 / 2, Sqrt[3], x], HypergeometricU[-1 / 2, Sqrt[5], x], HypergeometricU[1 / 2, Sqrt[3], x], HypergeometricU[1 / 2, Sqrt[5], x]}, {x, 0, 4}]

Plot HypergeometricU as a function of its second parameter:

Wolfram Language code:

Plot[{HypergeometricU[-Sqrt[5], b, 1], HypergeometricU[-Sqrt[2], b, 1], HypergeometricU[Sqrt[2], b, 1], HypergeometricU[Sqrt[5], b, 1]}, {b, -6, 6}]

Plot the real part of :

Wolfram Language code: ComplexContourPlot[Re[HypergeometricU[1 / 2, Sqrt[3], z]], {z, -10 - 10I, 10 + 10I}, Contours -> 24]

Plot the imaginary part of :

Wolfram Language code: ComplexContourPlot[Im[HypergeometricU[1 / 2, Sqrt[3], z]], {z, -10 - 10I, 10 + 10I}, Contours -> 24]

Function Properties (9)

Real domain of HypergeometricU:

Wolfram Language code: FunctionDomain[HypergeometricU [a, b, z], z]

Complex domain of HypergeometricU:

Wolfram Language code: FunctionDomain[HypergeometricU [a, b, z], z, Complexes]

is not an analytic function:

Wolfram Language code: FunctionAnalytic[HypergeometricU[Sqrt[3], Sqrt[2], z], z]

is neither non-decreasing nor non-increasing on its real domain:

Wolfram Language code: FunctionMonotonicity[HypergeometricU[Sqrt[3], Sqrt[2], z], z, PositiveReals]

is injective:

Wolfram Language code: FunctionInjective[HypergeometricU[Sqrt[3], Sqrt[2], z], z]

Wolfram Language code: Plot[{HypergeometricU[Sqrt[3], Sqrt[2], z], 2}, {z, 0, 2}]

is not surjective:

Wolfram Language code: FunctionSurjective[HypergeometricU[Sqrt[3], Sqrt[2], z], z]

Wolfram Language code: Plot[{HypergeometricU[Sqrt[3], Sqrt[2], z], -2}, {z, 0, 2}]

is positive on its real domain:

Wolfram Language code: FunctionSign[HypergeometricU[Sqrt[3], Sqrt[2], z], z, PositiveReals]

has both singularity and discontinuity for z≤0:

Wolfram Language code: FunctionSingularities[HypergeometricU[Sqrt[3], Sqrt[2], z], z]

Wolfram Language code: FunctionDiscontinuities[HypergeometricU[Sqrt[3], Sqrt[2], z], z]

is convex on its real domain:

Wolfram Language code: FunctionConvexity[{HypergeometricU[Sqrt[3], Sqrt[2], z], z > 0}, z]

TraditionalForm formatting:

Wolfram Language code: HypergeometricU[a, b, z]//TraditionalForm

Differentiation (3)

First derivative:

Wolfram Language code: D[HypergeometricU[a, b, x], x]

Higher derivatives:

Wolfram Language code: derivs = Table[D[HypergeometricU[a, b, x], {x, n}], {n, 1, 4}]

Plot higher derivatives for and :

Wolfram Language code:

Plot[Evaluate[derivs /. {a -> 1 / 2, b -> Sqrt[3]}], {x, 0, 3}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]

Formula for the derivative:

Wolfram Language code: D[HypergeometricU[a, b, x], {x, n}]

Integration (3)

Indefinite integral HypergeometricU:

Wolfram Language code: Integrate[HypergeometricU[a, b, x], x]

Definite integral of HypergeometricU:

Wolfram Language code: Integrate[HypergeometricU[1, Sqrt[2], x], {x, 0, 1}]

More integrals:

Wolfram Language code: Integrate[x ^ (α - 1)HypergeometricU[a, b, x], x]

Wolfram Language code: Integrate[x ^ (α - 1)HypergeometricU[a, b, x], {x, 0, Infinity}, Assumptions -> Max[0, Re[b] - 1] < Re[α] < Re[a]]

Series Expansions (3)

Series expansion for HypergeometricU:

Wolfram Language code: Series[HypergeometricU[a, b, x], {x, 0, 3}]

Plot the first three approximations for around :

Wolfram Language code:

terms = Normal@Table[Series[HypergeometricU[1 / 2, Sqrt[3], x], {x, 0, m}], {m, 0, 2}];
Plot[{HypergeometricU[1 / 2, Sqrt[3], x], terms}, {x, 0, 2}]

Expand HypergeometricU in series around infinity:

Wolfram Language code: Series[HypergeometricU[a, b, x], {x, Infinity, 2}]

Apply HypergeometricU to a power series:

Wolfram Language code: HypergeometricU[1 / 7, 3 / 7, Log[1 + z] + O[z] ^ 2]

Integral Transforms (3)

Compute the Laplace transform using LaplaceTransform:

Wolfram Language code: LaplaceTransform[HypergeometricU[a, b, t], t, s]

MellinTransform:

Wolfram Language code: MellinTransform[HypergeometricU[a, b, r], r, s]

HankelTransform:

Wolfram Language code: HankelTransform[HypergeometricU[a, b, r], r, s]

Function Identities and Simplifications (2)

Argument simplification:

Wolfram Language code: z^1 - b HypergeometricU[a - b + 1, 2 - b, z]//FullSimplify

Recurrence identities:

Wolfram Language code:

HypergeometricU[a, b, z] == (2 + 2 a - b + z) HypergeometricU[1 + a, b, z] - (1 + a) (2 + a - b) HypergeometricU[2 + a, b, z]//FullSimplify

Wolfram Language code: (a - b)HypergeometricU[a, b, z] == z HypergeometricU[a, b + 2, z] - (b + z) HypergeometricU[a, b + 1, z]//FullSimplify

Function Representations (5)

Primary definition:

Wolfram Language code: (1/Gamma[a])Integrate[Exp[-z t]t^a - 1(1 + t)^b - a - 1, {t, 0, Infinity}, Assumptions -> Re[z] > 0 && Re[a] > 0]

Representation through Gamma and Hypergeometric1F1:

Wolfram Language code:

(Gamma[1 - b]/Gamma[a - b + 1]) Hypergeometric1F1[a, b, z] + (Gamma[b - 1]/Gamma[a]) z^1 - b Hypergeometric1F1[a - b + 1, 2 - b, z]//FullSimplify

HypergeometricU can be represented in terms of MeijerG:

Wolfram Language code: MeijerGReduce[HypergeometricU[a, b, x], x]

Wolfram Language code: Activate[%]

HypergeometricU can be represented as a DifferentialRoot:

Wolfram Language code: DifferentialRootReduce[HypergeometricU[a, b, x], x]

TraditionalForm formatting:

Wolfram Language code: HypergeometricU[a, b, z]//TraditionalForm

Applications (3)

Solve the confluent hypergeometric differential equation:

Wolfram Language code: DSolve[z w''[z] + (b - z) w'[z] - a w[z] == 0, w[z], z]

Borel summation of the divergent series for the function gives HypergeometricU:

Wolfram Language code: Sum[z^-a(Pochhammer[a, k]Pochhammer[1 + a - b, k]/k!)(-(1/z))^k (t^k/k!), {k, 0, ∞}]

Wolfram Language code: Integrate[% Exp[-t], {t, 0, ∞}, Assumptions -> z > 0]

The same result can be obtained using the Regularization option of Sum:

Wolfram Language code: Sum[z^-a(Pochhammer[a, k]Pochhammer[1 + a - b, k]/k!)(-(1/z))^k, {k, 0, ∞}, Regularization -> "Borel"]

Define distribution for scaled condition number of a WishartMatrixDistribution:

Wolfram Language code:

n = 200;
wmd = WishartMatrixDistribution[n, IdentityMatrix[n, SparseArray]];
cn𝒟 = MatrixPropertyDistribution[(1/n)Sqrt[(Max[#]/Min[#])]&[Eigenvalues[𝓂]], 𝓂wmd];

Sample the scaled condition number of a large matrix and check that it agrees with asymptotic closed-form distribution:

Wolfram Language code: asymp𝒟 = ProbabilityDistribution[(2κ + 4/κ^3)Exp[-(2/κ) - (2/κ^2)], {κ, 0, Infinity}];

Wolfram Language code: data = RandomVariate[cn𝒟, 2000];

Wolfram Language code:

Show[
	Histogram[data, {0.8}, PDF], 
	Plot[PDF[asymp𝒟, κ], {κ, 0.1, 30}, PlotRange -> All]]

The asymptotic scaled condition number distribution has infinite mean:

Wolfram Language code: generalizedMean = Expectation[κ^α, κasymp𝒟, Assumptions -> 0 < α < 1]

Wolfram Language code: meanScaledCN = Limit[generalizedMean, α -> 1, Direction -> 1]

Properties & Relations (4)

Use FunctionExpand to expand HypergeometricU into simpler functions:

Wolfram Language code: HypergeometricU[3 / 2, 1 / 2, x]

Wolfram Language code: FunctionExpand[%]

Integrate may give results involving HypergeometricU:

Wolfram Language code: Integrate[t^1 / 3 (t + 1)^2 / 3 Exp[-t], {t, 0, Infinity}]

HypergeometricU can be represented as a DifferentialRoot:

Wolfram Language code: DifferentialRootReduce[HypergeometricU[a, b, z], z]

HypergeometricU can be represented as a DifferenceRoot:

Wolfram Language code: DifferenceRootReduce[HypergeometricU[k, 1, 2], k]

Wolfram Language code: DifferenceRootReduce[HypergeometricU[z, k, y], k]

Possible Issues (1)

The default setting of $MaxExtraPrecision can be insufficient to obtain requested precision:

Wolfram Language code: N[HypergeometricU[10 ^ 4, 1 / 3, 1], 20]

A larger setting for $MaxExtraPrecision may be needed:

Wolfram Language code: Block[{$MaxExtraPrecision = 100}, N[HypergeometricU[10 ^ 4, 1 / 3, 1], 20]]

Neat Examples (2)

Visualize the confluency relation $TemplateBox[{TemplateBox[{a, {a, -, b, +, 1}, c, {1, -, {c, /, z}}}, Hypergeometric2F1], c, infty}, Limit2Arg]z^(-a)=TemplateBox[{a, b, z}, HypergeometricU]$ :

Wolfram Language code:

Block[{a = 3 / 2, b = 1, z = 1 / 2}, Plot[Abs[Hypergeometric2F1[a, a - b + 1, E ^ t, 1 - E ^ t / z] / z ^ a / HypergeometricU[a, b, z]], {t, 5, 10}]]

Plot the Riemann surface of :

Wolfram Language code:

With[{a = 1 / 2, b = 2 / 3, ε = 1*^-12}, 
	Show[Table[ParametricPlot3D[{r Cos[φ], r Sin[φ], Im[Exp[-2π I b k]HypergeometricU[a, b, r Exp[I φ]] + (2π I/Gamma[a - b + 1])Exp[-π I b k]ChebyshevU[k - 1, Cos[π b]]Hypergeometric1F1Regularized[a, b, r Exp[I φ]]]}, {r, 0, 3}, {φ, -π + ε, π - ε}, Mesh -> None, PlotPoints -> 21, PlotStyle -> Directive[Hue[0.85], Opacity[0.6]]], {k, -1, 1}], BoxRatios -> {1, 1, 3}, PlotRange -> {All, All, {-5, 5}}]]

Top

More Learning

Tech Support

Wolfram Solutions

Wolfram Solutions For Education

Get Started

Grow Your Skills

Work with Us

Educational Programs for Adults

Educational Programs for Youth

Read

HypergeometricU

Details

Examples

Basic Examples (5)

Scope (39)

Numerical Evaluation (5)

Specific Values (3)

Visualization (3)

Function Properties (9)

Differentiation (3)

Integration (3)

Series Expansions (3)

Integral Transforms (3)

Function Identities and Simplifications (2)

Function Representations (5)

Applications (3)

Properties & Relations (4)

Possible Issues (1)

Neat Examples (2)

Text

CMS

APA

BibTeX

BibLaTeX

HypergeometricU

Details

Examples

Basic Examples (5)

Scope (39)

Numerical Evaluation (5)

Specific Values (3)

Visualization (3)

Function Properties (9)

Differentiation (3)

Integration (3)

Series Expansions (3)

Integral Transforms (3)

Function Identities and Simplifications (2)

Function Representations (5)

Applications (3)

Properties & Relations (4)

Possible Issues (1)

Neat Examples (2)

See Also

Tech Notes

Related Guides

Related Links

History

Text

CMS

APA

BibTeX

BibLaTeX