WOLFRAM

Wolfram Language & System Documentation Center

WhittakerW[k,m,z]

gives the Whittaker function TemplateBox[{k, m, z}, WhittakerW].

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Numerical Evaluation  
Specific Values  
Visualization  
Function Properties  
Differentiation  
Series Expansions  
Applications  
Properties & Relations  
Neat Examples  
See Also
Tech Notes
Related Guides
Related Links
History
Cite this Page

WhittakerW

WhittakerW[k,m,z]

gives the Whittaker function TemplateBox[{k, m, z}, WhittakerW].

Details

  • Mathematical function, suitable for both symbolic and numerical manipulation.
  • WhittakerW is related to the Tricomi confluent hypergeometric function by TemplateBox[{k, m, z}, WhittakerW]=e^(-z/2)z^(m+1/2)TemplateBox[{{m, -, k, +, {1, /, 2}}, {1, +, {2, m}}, z}, HypergeometricU].
  • TemplateBox[{k, m, z}, WhittakerW] is infinite at for integer .
  • For certain special arguments, WhittakerW automatically evaluates to exact values.
  • WhittakerW can be evaluated to arbitrary numerical precision.
  • WhittakerW automatically threads over lists.
  • WhittakerW[k,m,z] has a branch cut discontinuity in the complex plane running from to .
  • WhittakerW can be used with Interval and CenteredInterval objects. »

Examples

open all close all

Basic Examples  (6)

Evaluate numerically:

Wolfram Language code: WhittakerW[2, 3, 4.5]

Use FunctionExpand to expand in terms of hypergeometric functions:

Wolfram Language code: FunctionExpand[WhittakerW[k, m, x]]

Plot over a subset of the reals:

Wolfram Language code: Plot[WhittakerW[2, 1 / 2, x], {x, 0, 15}]

Plot over a subset of the complexes:

Wolfram Language code: ComplexPlot3D[WhittakerW[2, 1 / 2, z], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

Series expansion at the origin:

Wolfram Language code: Series[WhittakerW[2, 1 / 2, x], {x, 0, 6}]

Series expansion at Infinity:

Wolfram Language code: Series[WhittakerW[2, 1 / 2, x], {x, ∞, 5}]//Normal

Scope  (35)

Numerical Evaluation  (6)

Evaluate numerically:

Wolfram Language code: WhittakerW[6, 4, 1.7]
Wolfram Language code: WhittakerW[2, 0.5, 0]

Evaluate to high precision:

Wolfram Language code: N[WhittakerW[3 / 5, 1 / 3, 1 / 7], 100]//Chop

The precision of the output tracks the precision of the input:

Wolfram Language code: WhittakerW[2, 1.2222222222222222222, 1]//Chop

Complex number input:

Wolfram Language code: N[WhittakerW[1 / 5, 2 - I, 2]]

Evaluate efficiently at high precision:

Wolfram Language code: WhittakerW[5, 1 / 11, 1 / 7`100]//Timing//Chop
Wolfram Language code: WhittakerW[2, 7 / 3, 4 / 7`1000];//Timing

WhittakerW can be used with Interval and CenteredInterval objects:

Wolfram Language code: WhittakerW[0.3, 0.4, Interval[{0.5, 0.6}]]
Wolfram Language code: WhittakerW[1, 2, CenteredInterval[3, 1 / 100]]

Compute the elementwise values of an array:

Wolfram Language code: WhittakerW[1, 3.1, {{2, 3}, {1, 2}}]

Or compute the matrix WhittakerW function using MatrixFunction:

Wolfram Language code: MatrixFunction[WhittakerW[1.3, 3, #]&, {{2, 0}, {1.2, -2}}]

Specific Values  (7)

WhittakerW for symbolic parameters:

Wolfram Language code: WhittakerW[k, m, 3]//FunctionExpand

Values at zero:

Wolfram Language code: WhittakerW[0, 1, 0]
Wolfram Language code: WhittakerW[0, 0, 0]

Evaluate symbolically at the origin:

Wolfram Language code: WhittakerW[k, 1 / 2, 0]

Find the first positive maximum of WhittakerW[3,1/2,x]:

Wolfram Language code: xmax = x /. FindRoot[D[WhittakerW[3, 1 / 2, x ], x] == 0, {x, 0.5}]
Wolfram Language code: Plot[WhittakerW[3, 1 / 2, x ], {x, 0, 10}, Epilog -> Style[Point[{xmax, WhittakerW[3, 1 / 2, xmax ]}], PointSize[Large], Red]]

Compute the associated WhittakerW[3,1/2,x] function:

Wolfram Language code: WhittakerW[3, 1 / 2, x]//FunctionExpand

Compute the associated WhittakerW function for half-integer parameters:

Wolfram Language code: WhittakerW[-1 / 2, 1 / 2, x]//FunctionExpand

Different cases of WhittakerW give different symbolic forms:

Wolfram Language code: Table[WhittakerW[k, m, x], {k, {-1 / 2, 1 / 2}}, {m, {-1, 0, 1}}]//FunctionExpand

Visualization  (3)

Plot the WhittakerW function for various orders:

Wolfram Language code: Plot[{WhittakerW[1, 1 / 2, x], WhittakerW[2, 1 / 2, x], WhittakerW[3, 1 / 2, x], WhittakerW[4, 1 / 2, x]}, {x, 0, 3}]

Plot the real part of :

Wolfram Language code: ComplexContourPlot[Re[WhittakerW[10, 1 / 2, z]], {z, -2 - 2I, 2 + 2I}, Contours -> 24]

Plot the imaginary part of :

Wolfram Language code: ComplexContourPlot[Im[WhittakerW[10, 1 / 2, z]], {z, -2 - 2I, 2 + 2I}, Contours -> 24]

Plot as real parts of two parameters vary:

Wolfram Language code: Plot3D[Re[WhittakerW[k, 1 / 2, z]], {k, 0, 3}, {z, 0, 2}]

Function Properties  (11)

Real domain of TemplateBox[{2, 0, x}, WhittakerW]:

Wolfram Language code: FunctionDomain[WhittakerW[2, 0, x], x]

Complex domain of WhittakerW:

Wolfram Language code: FunctionDomain[WhittakerW[k, m, z], z, Complexes]

Approximate range of TemplateBox[{2, 0, x}, WhittakerW]:

Wolfram Language code: FunctionRange[WhittakerW[2, 0, x], x, y]//Quiet

WhittakerW may reduce to simpler functions:

Wolfram Language code: WhittakerW[-1 / 4, 1 / 4, x ^ 2]//FunctionExpand
Wolfram Language code: WhittakerW[n / 2 + 1 / 4, -1 / 4, 1 / 2z ^ 2]//FunctionExpand

WhittakerW threads elementwise over lists:

Wolfram Language code: WhittakerW[2, 3, {1.5, 2.5, 3.5}]

WhittakerW is not an analytic function:

Wolfram Language code: FunctionAnalytic[WhittakerW[2, 0, x], x]

Nor is it meromorphic:

Wolfram Language code: FunctionMeromorphic[WhittakerW[2, 0, x], x]

TemplateBox[{2, 0, x}, WhittakerW] is neither non-decreasing nor non-increasing on its real domain:

Wolfram Language code: FunctionMonotonicity[{WhittakerW[2, 0, x], x > 0}, x]

TemplateBox[{2, 0, x}, WhittakerW] is not injective:

Wolfram Language code: FunctionInjective[WhittakerW[2, 0, x], x]
Wolfram Language code: Plot[{WhittakerW[2, 0, x], .2}, {x, 0, 15}]

TemplateBox[{2, 0, x}, WhittakerW] is neither non-negative nor non-positive on its real domain:

Wolfram Language code: FunctionSign[{WhittakerW[2, 0, x], x > 0}, x]

WhittakerW has both singularity and discontinuity in (-∞,0]:

Wolfram Language code: FunctionSingularities[WhittakerW[k, m, x], x]
Wolfram Language code: FunctionDiscontinuities[WhittakerW[k, m, x], x]

TemplateBox[{2, 0, x}, WhittakerW] is neither convex nor concave on its real domain:

Wolfram Language code: FunctionConvexity[{WhittakerW[2, 0, x], x > 0}, x]

TraditionalForm formatting:

Wolfram Language code: WhittakerW[m, k, x]//TraditionalForm

Differentiation  (3)

First derivative with respect to z:

Wolfram Language code: D[WhittakerW[k, m, z] , z]

Higher derivatives with respect to z when k=1/3 and m=1/2:

Wolfram Language code: Table[D[WhittakerW[1 / 3, 1 / 2, z], {z, n}], {n, 1, 3}]//FullSimplify

Plot the higher derivatives with respect to z when k=1/3 and m=1/2:

Wolfram Language code: Plot[%, {z, 0, 10}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative"}]

Formula for the ^(th) derivative with respect to z:

Wolfram Language code: D[WhittakerW[k, m, z], {z, k}]// FullSimplify

Series Expansions  (5)

Find the Taylor expansion using Series:

Wolfram Language code: Series[WhittakerW[k, m, x], {x, 0, 3}]// FullSimplify

Plots of the first three approximations around :

Wolfram Language code: terms = Normal@Table[Series[WhittakerW[2, 1 / 2, x], {x, 0, m}], {m, 1, 5, 2}]; Plot[{WhittakerM[2, 1 / 2, x], terms}, {x, 0, 6}, PlotRange -> {-2, 2}]

General term in the series expansion using SeriesCoefficient:

Wolfram Language code: SeriesCoefficient[WhittakerW[k, m, x], {x, 1, n}]

Find the series expansion at Infinity:

Wolfram Language code: Series[WhittakerW[k, m, x], {x, Infinity, 2}]

Find series expansion for an arbitrary symbolic direction :

Wolfram Language code: Series[WhittakerW[k, m, x], {x, DirectedInfinity[z], 1}, Assumptions -> x > 0]// FullSimplify

Taylor expansion at a generic point:

Wolfram Language code: Series[WhittakerW[k, m, x], {x, x0, 2}]// FullSimplify

Applications  (1)

Green's function of the 3D Coulomb potential:

Wolfram Language code: gf[r1_, r2_, e_] := Module[{ν, a1, a2, δ, 𝓋ℓ = Sqrt[Total[#1 ^ 2]]&}, ν = e ^ (-1 / 2);δ = 𝓋ℓ[r2 - r1];{a1, a2} = 𝓋ℓ[r2] + 𝓋ℓ[r1] + {δ, -δ};(-Gamma[1 - I ν]/4 π δ)Det[(| | | | ------------------------------------------- | ------------------------------------------- | | WhittakerW[I ν, (1/2), -(I a2/ν)] | WhittakerM[I ν, (1/2), -(I a1/ν)] | | WhittakerW^(0, 0, 1)[I ν, (1/2), -(I a2/ν)] | WhittakerM^(0, 0, 1)[I ν, (1/2), -(I a1/ν)] |)]]
Wolfram Language code: Plot[gf[{1, 0, 0}, {0, 0, 1}, e], {e, -2, .01}]

Properties & Relations  (4)

Use FunctionExpand to expand WhittakerW into other functions:

Wolfram Language code: FunctionExpand[WhittakerW[5, 1 / 2, x]]
Wolfram Language code: FunctionExpand[WhittakerW[-1 / 4, 1 / 4, x]]
Wolfram Language code: FunctionExpand[WhittakerW[0, m, x]]

Integrate expressions involving Whittaker functions:

Wolfram Language code: Integrate[x^aWhittakerM[k, m, x]WhittakerW[-k, m, x], {x, 0, ∞}, Assumptions -> k > 1 / 2 && m > 0 && 2k - 1 > a >= 0]

WhittakerW can be represented as a DifferentialRoot:

Wolfram Language code: DifferentialRootReduce[WhittakerW[n, m, x], x]

WhittakerW can be represented as a DifferenceRoot:

Wolfram Language code: DifferenceRootReduce[WhittakerW[k, y, z], k]
Wolfram Language code: DifferenceRootReduce[WhittakerW[y, k, z], k]

Neat Examples  (1)

Plot the Riemann surface of TemplateBox[{{3, /, 5}, {1, /, 3}, z}, WhittakerW]:

Wolfram Language code: With[{n = 3 / 5, m = 1 / 3, ε = 1*^-12}, Show[Table[ParametricPlot3D[{r Cos[φ], r Sin[φ], Im[(-1)^kExp[-2π I m k]WhittakerW[n, m, r Exp[I φ]] + ((-1)^k + 12π I ChebyshevU[k - 1, Cos[2π m]]/Gamma[(1/2) - m - n]Gamma[2m + 1])WhittakerM[n, m, r Exp[I φ]]]}, {r, 0, 3}, {φ, -π + ε, π - ε}, Mesh -> None, PlotPoints -> 21, PlotStyle -> Directive[Hue[0.85], Opacity[0.6]]], {k, -1, 1}], BoxRatios -> {1, 1, 3}, PlotRange -> {All, All, {-5, 5}}]]
Wolfram Research (2007), WhittakerW, Wolfram Language function, https://reference.wolfram.com/language/ref/WhittakerW.html.

Text

Wolfram Research (2007), WhittakerW, Wolfram Language function, https://reference.wolfram.com/language/ref/WhittakerW.html.

CMS

Wolfram Language. 2007. "WhittakerW." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/WhittakerW.html.

APA

Wolfram Language. (2007). WhittakerW. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/WhittakerW.html

BibTeX

@misc{reference.wolfram_2026_whittakerw, author="Wolfram Research", title="{WhittakerW}", year="2007", howpublished="\url{https://reference.wolfram.com/language/ref/WhittakerW.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_whittakerw, organization={Wolfram Research}, title={WhittakerW}, year={2007}, url={https://reference.wolfram.com/language/ref/WhittakerW.html}, note=[Accessed: 13-June-2026]}