WOLFRAM

Wolfram Language & System Documentation Center

CumulantGeneratingFunction[dist,t]

gives the cumulant-generating function for the distribution dist as a function of the variable t.

CumulantGeneratingFunction[dist,{t1,t2,…}]

gives the cumulant-generating function for the multivariate distribution dist as a function of the variables t1, t2, … .

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Applications  
Properties & Relations  
Possible Issues  
Neat Examples  
See Also
Related Guides
History
Cite this Page

CumulantGeneratingFunction

CumulantGeneratingFunction[dist,t]

gives the cumulant-generating function for the distribution dist as a function of the variable t.

CumulantGeneratingFunction[dist,{t1,t2,…}]

gives the cumulant-generating function for the multivariate distribution dist as a function of the variables t1, t2, … .

Details

Examples

open all close all

Basic Examples  (3)

Compute a cumulant-generating function (cgf) for a continuous univariate distribution:

Wolfram Language code: CumulantGeneratingFunction[NormalDistribution[μ, σ], t]

The cgf for a univariate discrete distribution:

Wolfram Language code: CumulantGeneratingFunction[PoissonDistribution[μ], t]

The cgf for a multivariate distribution:

Wolfram Language code: CumulantGeneratingFunction[BinormalDistribution[ρ], {t1, t2}]

Scope  (5)

Compute the cgf for a formula distribution:

Wolfram Language code: CumulantGeneratingFunction[ProbabilityDistribution[(3/4)Sqrt[(1 + x/2)], {x, -1, 1}], t]

Find the cgf for a function of random variates:

Wolfram Language code: CumulantGeneratingFunction[TransformedDistribution[u z, {uUniformDistribution[], zNormalDistribution[]}], t]

Compute the cgf for data distribution:

Wolfram Language code: hdist = HistogramDistribution[ExampleData[{"Statistics", "FatigueLifeFailures"}]]
Wolfram Language code: CumulantGeneratingFunction[hdist, t]

Find the cgf for a truncated distribution:

Wolfram Language code: CumulantGeneratingFunction[TruncatedDistribution[{-10, 10}, CauchyDistribution[0, 1]], t]

Find the cgf for the slice distribution of a random process:

Wolfram Language code: CumulantGeneratingFunction[PoissonProcess[μ][s], t]

Applications  (5)

The cumulant-generating function of a difference of two independent random variables is equal to the sum of their cumulant-generating functions with oppositive sign arguments:

Wolfram Language code: TransformedDistribution[x - y, {xPoissonDistribution[μ], yPoissonDistribution[λ]}]
Wolfram Language code: CumulantGeneratingFunction[SkellamDistribution[μ, λ], t]
Wolfram Language code: % == CumulantGeneratingFunction[PoissonDistribution[μ], t] + CumulantGeneratingFunction[PoissonDistribution[λ], -t]

Illustrate the central limit theorem:

Wolfram Language code: dist = LaplaceDistribution[μ, σ];

Find the cumulant-generating function for the standardized random variate:

Wolfram Language code: cgf[t_] = CumulantGeneratingFunction[TransformedDistribution[(x - Mean[dist]) / StandardDeviation[dist], xdist], t]

Find the moment-generating function for the sum of standardized random variates rescaled by :

Wolfram Language code: n * cgf[t / Sqrt[n]]

Find the large limit:

Wolfram Language code: Limit[n * cgf[t / Sqrt[n]], n -> Infinity]

Compare with the moment-generating function of a standard normal distribution:

Wolfram Language code: CumulantGeneratingFunction[NormalDistribution[], t]

Find the Esscher premium for insuring against losses following GammaDistribution:

Wolfram Language code: D[CumulantGeneratingFunction[GammaDistribution[α, β], h], h]

Compare with the definition:

Wolfram Language code: (Expectation[x Exp[h x], xGammaDistribution[α, β]]/Expectation[Exp[h x], xGammaDistribution[α, β]])

Construct a Bernstein–Chernoff bound for the survival function :

Wolfram Language code: dist = BinomialDistribution[n, 1 / 2]; ℐ[t_, x_] = t * x - CumulantGeneratingFunction[dist, t]; k = Mean[dist] + u StandardDeviation[dist]; assumps = t > 0∧n > 0∧k < n∧u > 0;
Wolfram Language code: {bound} = Simplify[Exp[-ℐ[t, k]] /. Solve[D[ℐ[t, k], t] == 0 && assumps, t, Reals], assumps]
Wolfram Language code: Table[LogPlot[{SurvivalFunction[dist, k], bound}, {u, 0, 5}, PlotPoints -> n], {n, {50, 100, 500, 1000}}]

Large approximation of the bound:

Wolfram Language code: Series[bound, {n, ∞, 2}]//Simplify

Construct Daniel's saddle point approximation to PDF of VarianceGammaDistribution:

Wolfram Language code: vgd = VarianceGammaDistribution[7 / 3, 3, -1, 0]; cgf[t_] = CumulantGeneratingFunction[vgd, t]

Find the saddle point associated with the argument of probability density function :

Wolfram Language code: sol = Solve[cgf'[t] == x, t]

Select the solution that is valid for all real , including the origin:

Wolfram Language code: Limit[t /. sol, x -> 0]
Wolfram Language code: ts = Last[t /. sol]

The approximation is constructed using the cumulant-generating function at the saddle point:

Wolfram Language code: approxPDF[x_] = (1/Sqrt[2Pi cgf''[ts]])Exp[cgf[ts] - ts x]//FullSimplify

Find the normalization constant:

Wolfram Language code: norm = NIntegrate[approxPDF[x], {x, -Infinity, Infinity}]

Compare the approximation to the exact density:

Wolfram Language code: Plot[{approxPDF[x] / norm, PDF[vgd, x]}, {x, -4, 4}, PlotLegends -> {"Saddlepoint approximation", "Exact density"}]

Properties & Relations  (3)

Exponential of CumulantGeneratingFunction gives MomentGeneratingFunction:

Wolfram Language code: CumulantGeneratingFunction[NormalDistribution[μ, σ], t]
Wolfram Language code: Exp[%] == MomentGeneratingFunction[NormalDistribution[μ, σ], t]

CumulantGeneratingFunction is an exponential generating function for the sequence of cumulants:

Wolfram Language code: Cumulant[PoissonDistribution[μ], r]
Wolfram Language code: ExponentialGeneratingFunction[%, r, t]

Use CumulantGeneratingFunction directly:

Wolfram Language code: CumulantGeneratingFunction[PoissonDistribution[μ], t]

Cumulant is equivalent to :

Wolfram Language code: Cumulant[UniformDistribution[{0, 1}], 4]
Wolfram Language code: Limit[D[CumulantGeneratingFunction[UniformDistribution[{0, 1}], t], {t, 4}], t -> 0]

Use SeriesCoefficient formulation:

Wolfram Language code: With[{r = 4}, SeriesCoefficient[CumulantGeneratingFunction[UniformDistribution[{0, 1}], t], {t, 0, r}]r!]

Possible Issues  (2)

For some distributions with long tails, cumulants of only several low orders are defined:

Wolfram Language code: Table[Cumulant[ParetoDistribution[1, 4], r], {r, 5}]

Correspondingly, CumulantGeneratingFunction is undefined:

Wolfram Language code: CumulantGeneratingFunction[ParetoDistribution[1, 4], t]

CumulantGeneratingFunction is not always known in closed form:

Wolfram Language code: CumulantGeneratingFunction[LogNormalDistribution[μ, σ], t]

Use Cumulant to find cumulants directly:

Wolfram Language code: Cumulant[LogNormalDistribution[μ, σ], 3]

Neat Examples  (1)

Visualize cgf over complex plane for some univariate distributions:

Wolfram Language code: dists = {NegativeBinomialDistribution[10, 1 / 3], PoissonDistribution[3], BorelTannerDistribution[5 / 6, 10], ExponentialDistribution[1], BirnbaumSaundersDistribution[1, 1 / 3], HyperbolicDistribution[2, 1, 1, 2]};
Wolfram Language code: Table[Plot3D[Re[CumulantGeneratingFunction[𝒟, x + I y]]//Evaluate, {x, -2, 2}, {y, -4, 4}, Mesh -> None, ImageSize -> 200, PlotLabel -> 𝒟], {𝒟, dists}]
Wolfram Research (2010), CumulantGeneratingFunction, Wolfram Language function, https://reference.wolfram.com/language/ref/CumulantGeneratingFunction.html.

Text

Wolfram Research (2010), CumulantGeneratingFunction, Wolfram Language function, https://reference.wolfram.com/language/ref/CumulantGeneratingFunction.html.

CMS

Wolfram Language. 2010. "CumulantGeneratingFunction." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/CumulantGeneratingFunction.html.

APA

Wolfram Language. (2010). CumulantGeneratingFunction. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/CumulantGeneratingFunction.html

BibTeX

@misc{reference.wolfram_2026_cumulantgeneratingfunction, author="Wolfram Research", title="{CumulantGeneratingFunction}", year="2010", howpublished="\url{https://reference.wolfram.com/language/ref/CumulantGeneratingFunction.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_cumulantgeneratingfunction, organization={Wolfram Research}, title={CumulantGeneratingFunction}, year={2010}, url={https://reference.wolfram.com/language/ref/CumulantGeneratingFunction.html}, note=[Accessed: 13-June-2026]}