WOLFRAM

Wolfram Language & System Documentation Center

MomentGeneratingFunction[dist,t]

gives the moment-generating function for the distribution dist as a function of the variable t.

MomentGeneratingFunction[dist,{t1,t2,…}]

gives the moment-generating function for the multivariate distribution dist as a function of the variables t1, t2, … .

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Applications  
Properties & Relations  
Possible Issues  
Neat Examples  
See Also
Related Guides
History
Cite this Page

MomentGeneratingFunction

MomentGeneratingFunction[dist,t]

gives the moment-generating function for the distribution dist as a function of the variable t.

MomentGeneratingFunction[dist,{t1,t2,…}]

gives the moment-generating function for the multivariate distribution dist as a function of the variables t1, t2, … .

Details

Examples

open all close all

Basic Examples  (3)

Compute the moment-generating function (mgf) for a continuous univariate distribution:

Wolfram Language code: MomentGeneratingFunction[NormalDistribution[μ, σ], t]

The mgf for a univariate discrete distribution:

Wolfram Language code: MomentGeneratingFunction[PoissonDistribution[μ], t]

The mgf for a multivariate distribution:

Wolfram Language code: MomentGeneratingFunction[BinormalDistribution[ρ], {t1, t2}]

Scope  (5)

Compute the moment-generating function (mgf) for a formula distribution:

Wolfram Language code: MomentGeneratingFunction[ProbabilityDistribution[(BesselK[0, x]/Pi / 2), {x, 0, ∞}], t]

Find the mgf for a function of a random variate:

Wolfram Language code: MomentGeneratingFunction[TransformedDistribution[x ^ 2, xRiceDistribution[α, β]], t]

Find the mgf for a data distribution:

Wolfram Language code: hdist = HistogramDistribution[ExampleData[{"Statistics", "FatigueLifeFailures"}]]
Wolfram Language code: mgf = MomentGeneratingFunction[hdist, t]

Compute the mgf for a censored distribution:

Wolfram Language code: MomentGeneratingFunction[CensoredDistribution[{0, μ}, ExponentialDistribution[λ]], t]

Find the mgf for the slice distribution of a random process:

Wolfram Language code: MomentGeneratingFunction[PoissonProcess[μ][s], t]

Applications  (3)

Find the moment-generating function of the sum of random variates:

Wolfram Language code: Refine[MomentGeneratingFunction[TransformedDistribution[x + y, {xBinomialDistribution[Subscript[n, 1], Subscript[p, 1]], yBinomialDistribution[Subscript[n, 2], Subscript[p, 2]]}], t], Subscript[n, 1] > 0 && Subscript[n, 2] > 0]

Check that it is equal to the product of generating functions:

Wolfram Language code: MomentGeneratingFunction[BinomialDistribution[Subscript[n, 1], Subscript[p, 1]], t]MomentGeneratingFunction[BinomialDistribution[Subscript[n, 2], Subscript[p, 2]], t]

When it coincides with the mgf of BinomialDistribution:

Wolfram Language code: % /. {Subscript[p, 1] -> p, Subscript[p, 2] -> p}

Confirm with TransformedDistribution:

Wolfram Language code: TransformedDistribution[x + y, {xBinomialDistribution[Subscript[n, 1], p], yBinomialDistribution[Subscript[n, 2], p]}]

Reconstruct the PDF of a positive real random variate from its moment-generating function:

Wolfram Language code: mgf = (1 + t/(1 - 2 t)^5 / 2);
Wolfram Language code: pdf = Refine[InverseLaplaceTransform[mgf /. t -> -t, t, x], x > 0]

Check the result:

Wolfram Language code: MomentGeneratingFunction[ProbabilityDistribution[pdf, {x, 0, Infinity}], t] == mgf

Illustrate the central limit theorem on the example of PoissonDistribution:

Wolfram Language code: dist = PoissonDistribution[μ];

Find the moment-generating function for the standardized random variate:

Wolfram Language code: mgf[t_] = MomentGeneratingFunction[TransformedDistribution[(x - Mean[dist]) / StandardDeviation[dist], xdist], t]

Find the moment-generating function for the sum of standardized random variates rescaled by :

Wolfram Language code: mgf[t / Sqrt[n]] ^ n

Find the large limit:

Wolfram Language code: Limit[%, n -> ∞]

Compare with the moment-generating function of a standard normal distribution:

Wolfram Language code: MomentGeneratingFunction[NormalDistribution[], t]

Properties & Relations  (5)

MomentGeneratingFunction is equivalent to Expectation of :

Wolfram Language code: MomentGeneratingFunction[NormalDistribution[μ, σ], t]
Wolfram Language code: Expectation[Exp[t x], xNormalDistribution[μ, σ]]
Wolfram Language code: %% - %

MomentGeneratingFunction is an exponential generating function for the sequence of moments:

Wolfram Language code: ExponentialGeneratingFunction[Moment[BetaDistribution[a, b], r], r, t]
Wolfram Language code: MomentGeneratingFunction[BetaDistribution[a, b], t]
Wolfram Language code: %% - %

Use SeriesCoefficient to find moment :

Wolfram Language code: SeriesCoefficient[MomentGeneratingFunction[BetaDistribution[a, b], t]r!, {t, 0, r}]//FunctionExpand

Use Moment directly:

Wolfram Language code: Moment[BetaDistribution[a, b], r]
Wolfram Language code: % / %%//FullSimplify[#, r ≥ 0 && a > 0 && b > 0]&

MomentGeneratingFunction is a LaplaceTransform for positive random variables:

Wolfram Language code: MomentGeneratingFunction[HalfNormalDistribution[1], t]
Wolfram Language code: LaplaceTransform[PDF[HalfNormalDistribution[1], x], x, -t]
Wolfram Language code: %% - %

MomentGeneratingFunction is a ZTransform for discrete positive random variates:

Wolfram Language code: MomentGeneratingFunction[GeometricDistribution[p], t]
Wolfram Language code: ZTransform[PDF[GeometricDistribution[p], k], k, Exp[-t]]//Simplify
Wolfram Language code: %% - %//Simplify

Possible Issues  (2)

For some distributions with long tails, moments of only several low orders are defined:

Wolfram Language code: Moment[BetaPrimeDistribution[a, b], r]

Correspondingly, MomentGeneratingFunction is undefined:

Wolfram Language code: MomentGeneratingFunction[BetaPrimeDistribution[a, b], t]

Analytic continuation of CharacteristicFunction can sometimes be defined:

Wolfram Language code: CharacteristicFunction[BetaPrimeDistribution[a, b], -I t]

MomentGeneratingFunction is not always known in closed form:

Wolfram Language code: MomentGeneratingFunction[LogNormalDistribution[μ, σ], t]

Use Moment to evaluate particular moments:

Wolfram Language code: Moment[LogNormalDistribution[μ, σ], r]

Neat Examples  (1)

Visualize mgf over complex plane for some univariate distributions:

Wolfram Language code: dists = {NegativeBinomialDistribution[10, 2 / 3], PoissonDistribution[3], BorelTannerDistribution[5 / 6, 10], ExponentialDistribution[1], BirnbaumSaundersDistribution[1, 3], HyperbolicDistribution[2, 1, 1, 2]};
Wolfram Language code: Table[Plot3D[Re[MomentGeneratingFunction[𝒟, x + I y]]//Evaluate, {x, -2, 2}, {y, -4, 4}, Mesh -> None, ImageSize -> 200, PlotLabel -> 𝒟], {𝒟, dists}]
Wolfram Research (2010), MomentGeneratingFunction, Wolfram Language function, https://reference.wolfram.com/language/ref/MomentGeneratingFunction.html.

Text

Wolfram Research (2010), MomentGeneratingFunction, Wolfram Language function, https://reference.wolfram.com/language/ref/MomentGeneratingFunction.html.

CMS

Wolfram Language. 2010. "MomentGeneratingFunction." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/MomentGeneratingFunction.html.

APA

Wolfram Language. (2010). MomentGeneratingFunction. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/MomentGeneratingFunction.html

BibTeX

@misc{reference.wolfram_2026_momentgeneratingfunction, author="Wolfram Research", title="{MomentGeneratingFunction}", year="2010", howpublished="\url{https://reference.wolfram.com/language/ref/MomentGeneratingFunction.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_momentgeneratingfunction, organization={Wolfram Research}, title={MomentGeneratingFunction}, year={2010}, url={https://reference.wolfram.com/language/ref/MomentGeneratingFunction.html}, note=[Accessed: 13-June-2026]}