WOLFRAM

Wolfram Language & System Documentation Center

DimensionalMeshComponents[mr]

gives a list {r0,r1,…} of regions such that rd has dimension d for a mesh region mr.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Properties & Relations  
See Also
Related Guides
History
Cite this Page

DimensionalMeshComponents

DimensionalMeshComponents[mr]

gives a list {r0,r1,…} of regions such that rd has dimension d for a mesh region mr.

Details and Options

Examples

open all close all

Basic Examples  (2)

Separate parts of a mesh that have different dimensional elements:

Wolfram Language code: mr = DiscretizeGraphics[Graphics[{Circle[{-1, 0}], Disk[{1, 0}]}]]
Wolfram Language code: ml = DimensionalMeshComponents[mr]

The geometric dimensions of each component with cells are different:

Wolfram Language code: Map[RegionDimension, ml]

The embedding dimension is the same:

Wolfram Language code: Map[RegionEmbeddingDimension, ml]

Separate dimensional components in 3D:

Wolfram Language code: mr = MeshRegion[{{0, 0, 0}, {1, 0, 0}, {2, 0, 0}, {3, 0, -1 / 2}, {3, 0, 1 / 2}, {4, -1 / 2, 0}, {4, 1 / 2, 0}}, {Point[1], Line[{2, 3}], Triangle[{3, 4, 5}], Tetrahedron[{4, 6, 5, 7}]}]
Wolfram Language code: ml = DimensionalMeshComponents[mr]

The geometric dimensions of each component with cells are different:

Wolfram Language code: Map[RegionDimension, ml]

The embedding dimension is the same:

Wolfram Language code: Map[RegionEmbeddingDimension, ml]

Scope  (3)

A MeshRegion in 1D can have components that are 0D or 1D:

Wolfram Language code: mr = MeshRegion[{{0}, {1}, {2}}, {Point[{1}], Line[{2, 3}]}]
Wolfram Language code: ml = DimensionalMeshComponents[mr]

The RegionDimension of each component:

Wolfram Language code: RegionDimension /@ ml

A MeshRegion in 2D can have components that are 0D, 1D, or 2D:

Wolfram Language code: mr = MeshRegion[{{0, 0}, {1, 0}, {2, 0}, {3, -1 / 2}, {3, 1 / 2}}, {Point[{1}], Line[{2, 3}], Polygon[{3, 4, 5}]}]
Wolfram Language code: ml = DimensionalMeshComponents[mr]

The RegionDimension of each component:

Wolfram Language code: RegionDimension /@ ml

A MeshRegion in 3D can have components that are 0D, 1D, 2D, or 3D:

Wolfram Language code: mr = MeshRegion[{{0, 0, 0}, {1, 0, 0}, {2, 0, 0}, {3, 0, -1 / 2}, {3, 0, 1 / 2}, {4, -1 / 2, 0}, {4, 1 / 2, 0}}, {Point[1], Line[{2, 3}], Triangle[{3, 4, 5}], Tetrahedron[{4, 6, 5, 7}]}]
Wolfram Language code: ml = DimensionalMeshComponents[mr]

The RegionDimension of each component:

Wolfram Language code: RegionDimension /@ ml

Properties & Relations  (5)

Every element of DimensionalMeshComponents will be a MeshRegion or an EmptyRegion:

Wolfram Language code: mr = MeshRegion[{{1, 0}, {2, 0}, {3, -1 / 2}, {3, 1 / 2}}, {Line[{1, 2}], Polygon[{2, 3, 4}]}]

This mesh has components in dimensions 1 and 2 but not 0:

Wolfram Language code: ml = DimensionalMeshComponents[mr]

The 0D component is EmptyRegion, while the 1D and 2D components are MeshRegion:

Wolfram Language code: MeshRegionQ /@ ml

A BoundaryMeshRegion has only a full-dimensional component:

Wolfram Language code: bmr = ConvexHullMesh[RandomReal[1, {10, 2}]]

The lower-dimensional components are EmptyRegion:

Wolfram Language code: DimensionalMeshComponents[bmr]

The output of DelaunayMesh has only a full-dimensional component:

Wolfram Language code: mr = DelaunayMesh[RandomReal[1, {10, 2}]]
Wolfram Language code: DimensionalMeshComponents[mr]

The output of VoronoiMesh has only a full-dimensional component:

Wolfram Language code: mr = VoronoiMesh[RandomReal[1, {10, 2}]]
Wolfram Language code: DimensionalMeshComponents[mr]

The output of TriangulateMesh has only a full-dimensional component:

Wolfram Language code: mr = MeshRegion[{{1, 0}, {2, 0}, {3, -1 / 2}, {3, 1 / 2}}, {Line[{1, 2}], Polygon[{2, 3, 4}]}]

The lower-dimensional components are ignored when triangulating:

Wolfram Language code: mr2 = TriangulateMesh[mr]

So only a full-dimensional component remains:

Wolfram Language code: DimensionalMeshComponents[mr2]
Wolfram Research (2014), DimensionalMeshComponents, Wolfram Language function, https://reference.wolfram.com/language/ref/DimensionalMeshComponents.html.

Text

Wolfram Research (2014), DimensionalMeshComponents, Wolfram Language function, https://reference.wolfram.com/language/ref/DimensionalMeshComponents.html.

CMS

Wolfram Language. 2014. "DimensionalMeshComponents." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/DimensionalMeshComponents.html.

APA

Wolfram Language. (2014). DimensionalMeshComponents. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/DimensionalMeshComponents.html

BibTeX

@misc{reference.wolfram_2026_dimensionalmeshcomponents, author="Wolfram Research", title="{DimensionalMeshComponents}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/DimensionalMeshComponents.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_dimensionalmeshcomponents, organization={Wolfram Research}, title={DimensionalMeshComponents}, year={2014}, url={https://reference.wolfram.com/language/ref/DimensionalMeshComponents.html}, note=[Accessed: 12-June-2026]}