Wolfram Language & System Documentation Center

Fibonacci

Fibonacci[n]

gives the Fibonacci number .

Fibonacci[n,x]

gives the Fibonacci polynomial .

Details

Mathematical function, suitable for both symbolic and numerical manipulation.
The satisfy the recurrence relation with .
For any complex value of n, the are given by the general formula , where is the golden ratio.
The Fibonacci polynomial is the coefficient of in the expansion of .
The Fibonacci polynomials satisfy the recurrence relation .
FullSimplify and FunctionExpand include transformation rules for combinations of Fibonacci numbers with symbolic arguments when the arguments are specified to be integers using n∈Integers.
Fibonacci can be evaluated to arbitrary numerical precision.
Fibonacci automatically threads over lists.
Fibonacci can be used with Interval and CenteredInterval objects. »

Examples

open all close all

Basic Examples (6)

Compute Fibonacci numbers:

Wolfram Language code: Table[Fibonacci[n], {n, 20}]

Plot over a subset of the reals:

Wolfram Language code: Plot[Fibonacci[1 / 2, x], {x, -10, 10}]

Plot over a subset of the complexes:

Wolfram Language code: ComplexPlot3D[Fibonacci[5 / 3, z], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

Series expansion at the origin:

Wolfram Language code: Series[Fibonacci[1 / 2, x], {x, 0, 5}]

Series expansion at Infinity:

Wolfram Language code: Series[Fibonacci[1 / 2, x], {x, ∞, 5}]//FullSimplify

Series expansion at a singular point:

Wolfram Language code: Series[Fibonacci[1 / 2, x], {x, -2I, 3}, Assumptions -> x > 1]//Normal//FullSimplify

Scope (43)

Numerical Evaluation (6)

Evaluate numerically:

Wolfram Language code: Fibonacci[5.8, 3]

Wolfram Language code: Fibonacci[8]

Evaluate to high precision:

Wolfram Language code: N[Fibonacci[15 / 17], 50]

The precision of the output tracks the precision of the input:

Wolfram Language code: Fibonacci[0.2114411444411100011, 5]

Complex number inputs:

Wolfram Language code: N[Fibonacci[5, 8 - I]]

Evaluate efficiently at high precision:

Wolfram Language code: Fibonacci[4750, 5`100]//Timing

Wolfram Language code: Fibonacci[71.56, 5`100000];//Timing

Compute worst-case guaranteed intervals using Interval and CenteredInterval objects:

Wolfram Language code: Fibonacci[0.4, Interval[{0.5, 0.6}]]

Wolfram Language code: Fibonacci[1 / 3, CenteredInterval[1 / 2, 1 / 100]]

Or compute average-case statistical intervals using Around:

Wolfram Language code: Fibonacci[ Around[.2, 0.01]]

Compute the elementwise values of an array:

Wolfram Language code: Fibonacci[3, {{-1, 0}, {0, 5}}]

Or compute the matrix Fibonacci function using MatrixFunction:

Wolfram Language code: MatrixFunction[Fibonacci[3, #]&, {{-1, 0}, {0, 5}}]

Specific Values (6)

Values of Fibonacci at fixed points:

Wolfram Language code: Table[Fibonacci[3, x ], {x, 1, 5}]

Fibonacci polynomial for symbolic n and x:

Wolfram Language code: Fibonacci[n, x]//FunctionExpand

Values at zero:

Wolfram Language code: Fibonacci[1, 0]

Wolfram Language code: Fibonacci[0, 0]

Find the value of in which :

Wolfram Language code: xval = x /. FindRoot[Fibonacci[3, x ] == 5, {x, 3}]

Wolfram Language code: Plot[Fibonacci[3, x ], {x, 0, 5}, Epilog -> Style[Point[{xval, Fibonacci[3, xval ]}], PointSize[Large], Red]]

Compute the Fibonacci[7,x] polynomial:

Wolfram Language code: Fibonacci[7, x]

Compute Fibonacci[1/2,x]:

Wolfram Language code: Fibonacci[1 / 2, x]//FunctionExpand

Visualization (5)

Plot the Fibonacci function:

Wolfram Language code: Plot[Fibonacci[x], {x, -2, 2}]

Plot the Fibonacci polynomial for various orders:

Wolfram Language code: Plot[{Fibonacci[1, x], Fibonacci[2, x], Fibonacci[3, x], Fibonacci[4, x]}, {x, -2, 2}]

Plot the real part of :

Wolfram Language code: ComplexContourPlot[Re[Fibonacci[3, z]], {z, -1 - I, 1 + I}, Contours -> 24]

Plot the imaginary part of :

Wolfram Language code: ComplexContourPlot[Im[Fibonacci[3, z]], {z, -1 - I, 1 + I}, Contours -> 24]

Plot as real parts of two parameters vary:

Wolfram Language code: Plot3D[Re[Fibonacci[n, z]], {n, 0, 5}, {z, -1, 1}, PlotRange -> All]

Types 2 and 3 of Fibonacci polynomial have different branch cut structures:

Wolfram Language code: Plot3D[Im[Fibonacci[3, x + I y]], {x, -3, 3}, {y, -0.5, 0.5}, Exclusions -> {{y == 0, Abs[x] > 1}}]

Wolfram Language code: Plot3D[Im[Fibonacci[3, x + I y]], {x, -3, 3}, {y, -0.5, 0.5}, Exclusions -> {{y == 0, -1 < x < 1}}]

Function Properties (14)

Fibonacci is defined for all real values:

Wolfram Language code: FunctionDomain[Fibonacci[n, z], z]

Approximate function range of Fibonacci:

Wolfram Language code: FunctionRange[Fibonacci[2, x], x, y]

Wolfram Language code: FunctionRange[Fibonacci[2, z], z, y, Complexes]

Fibonacci polynomial of an even order is odd:

Wolfram Language code: Fibonacci[2, -x] == -Fibonacci[2, x]

Fibonacci polynomial of an odd order is even:

Wolfram Language code: Fibonacci[1, -x] == Fibonacci[1, x]

Fibonacci has the mirror property :

Wolfram Language code: Fibonacci[1, Conjugate[z]] == Conjugate[Fibonacci[1, z]]

Fibonacci threads elementwise over lists:

Wolfram Language code: Fibonacci[{1, 2, 3, 4, 5}]

Fibonacci is an analytic function of x:

Wolfram Language code: FunctionAnalytic[Fibonacci[n, x], x, Assumptions -> n∈ℝ]

Fibonacci is neither non-decreasing nor non-increasingfor odd values:

Wolfram Language code: FunctionMonotonicity[Fibonacci[5, x], x]

Fibonacci is non-decreasing for even values:

Wolfram Language code: FunctionMonotonicity[Fibonacci[2, x], x]

Fibonacci is not injective for odd values:

Wolfram Language code: Table[FunctionInjective[Fibonacci[n, x], x], {n, 4}]

Wolfram Language code: Plot[{Fibonacci[3, x], Fibonacci[4, x], 5}, {x, -3, 3}]

Fibonacci is not surjective for odd values:

Wolfram Language code: Table[FunctionSurjective[Fibonacci[n, x], x], {n, 4}]

Wolfram Language code: Plot[{Fibonacci[3, x], Fibonacci[4, x], -2}, {x, -3, 3}]

Fibonacci is non-negative for odd values:

Wolfram Language code: Table[FunctionSign[Fibonacci[n, x], x], {n, 4}]

Fibonacci has no singularities or discontinuities:

Wolfram Language code: FunctionSingularities[Fibonacci[n, x], x]

Wolfram Language code: FunctionDiscontinuities[Fibonacci[n, x], x]

Fibonacci is convex for odd values:

Wolfram Language code: Table[FunctionConvexity[Fibonacci[n, x], x], {n, 7}]

TraditionalForm formatting:

Wolfram Language code: Fibonacci[n]//TraditionalForm

Differentiation (3)

First derivatives with respect to n:

Wolfram Language code: D[Fibonacci[n], n]

Wolfram Language code: D[Fibonacci[n, x], n]

First derivative with respect to x:

Wolfram Language code: D[Fibonacci[n, x], x]

Higher derivatives with respect to n:

Wolfram Language code: Table[D[Fibonacci[n], {n, k}], {k, 1, 3}]//FullSimplify

Plot the higher derivatives with respect to n:

Wolfram Language code: Plot[%, {n, -5, 5}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative"}]

Formula for the derivative with respect to n:

Wolfram Language code: D[Fibonacci[n], {n, k}]//FullSimplify

Integration (3)

Compute the indefinite integral using Integrate:

Wolfram Language code: Integrate[Fibonacci[x], x]// FullSimplify

Definite integral:

Wolfram Language code: Integrate[Fibonacci[x], {x, 3, 15}]

More integrals:

Wolfram Language code: Integrate[Fibonacci[x]Fibonacci[5 - x], x]//FullSimplify

Wolfram Language code: Integrate[E ^ (-t)Fibonacci[t], {t, 0, Infinity}]

Series Expansions (4)

Find the Taylor expansion using Series:

Wolfram Language code: Series[Fibonacci[x], {x, 0, 2}]

Plots of the first three approximations around :

Wolfram Language code:

terms = Normal@Table[Series[Fibonacci[x], {x, 0, m}], {m, 1, 5, 2}];
Plot[{Fibonacci[x], terms}, {x, -5, 5}]

General term in the series expansion using SeriesCoefficient:

Wolfram Language code: SeriesCoefficient[Fibonacci[x], {x, 0, n}]

Find the series expansion at Infinity:

Wolfram Language code: Series[Fibonacci[x], {x, Infinity, 1}]//Normal

Taylor expansion at a generic point:

Wolfram Language code: Series[Fibonacci[x], {x, x0, 2}]//FullSimplify

Function Identities and Simplifications (2)

The ordinary generating function of Fibonacci:

Wolfram Language code: GeneratingFunction[Fibonacci[n], n, x]

Recurrence relation:

Wolfram Language code: Fibonacci[n + 1, x] == x Fibonacci[n, x] + Fibonacci[n - 1, x]//FullSimplify

Generalizations & Extensions (2)

Fibonacci polynomials:

Wolfram Language code: Table[Fibonacci[n, x], {n, 10}]

General series expansion at infinity:

Wolfram Language code: Series[Fibonacci[n, x], {x, Infinity, 5}]//FullSimplify

Applications (13)

Solve the Fibonacci recurrence equation:

Wolfram Language code: RSolve[{f[n] == f[n - 1] + f[n - 2], f[2] == f[1] == 1}, f[n], n]

Wolfram Language code: FullSimplify[Table[First[f[n] /. %], {n, 10}]]

Solve another Fibonacci recurrence equation:

Wolfram Language code: RSolve[{f[n] == f[n - 1] + f[n - 2], f[1] == a, f[2] == b}, f[n], n]

Wolfram Language code: FullSimplify[Table[First[f[n] /. %], {n, 10}]]

Find ratios of successive Fibonacci numbers:

Wolfram Language code: Table[Fibonacci[n + 1] / Fibonacci[n], {n, 15}]

Compare with continued fractions:

Wolfram Language code: Table[FromContinuedFraction[Table[1, {n}]], {n, 15}]

Convergence to the golden ratio:

Wolfram Language code: N[%]

Fibonacci substitution system:

Wolfram Language code: NestList[StringReplace[#, {"A" -> "AB", "B" -> "A"}]&, "A", 6]

Wolfram Language code: StringCount[%, "A"]

Fibonomial coefficients:

Wolfram Language code: Fibonomial[n_, k_] := Product[Fibonacci[n + j - k] / Fibonacci[j], {j, k}]

Wolfram Language code: Array[Fibonomial, {7, 7}]//Grid

Calculate the number of ways to write an integer as a sum of Fibonacci numbers :

Wolfram Language code:

fibonacciSumCount[n_] := SeriesCoefficient[Series[Product[1 + z ^ Fibonacci[k], {k, Ceiling[Log[GoldenRatio, n]] + 2}], {z, 0, n}], n]

Plot the counts for the first hundred integers:

Wolfram Language code: ListPlot[Table[fibonacciSumCount[n], {n, 100}]]

Lamé's theorem bounds the number of steps of the Euclidean algorithm for calculating :

Wolfram Language code: 𝒻[n_] := NestWhile[(# + 1)&, 1, Fibonacci[#] < n&] - 1

Wolfram Language code: maxEuclideanAlgorithmSteps[a_, b_] := Min[𝒻[Min[a, b]] - 1, 𝒻[Max[a, b]] - 2]

Plot the maximal number of steps:

Wolfram Language code: ListPlot3D[Table[maxEuclideanAlgorithmSteps[a, b], {a, 100}, {b, 100}]]

Find the first Fibonacci number above 1000000:

Wolfram Language code: NestWhile[(# + 1)&, 1, Fibonacci[#] <= 10 ^ 6&]

Wolfram Language code: Fibonacci[%]

Plot the discrete inverse of Fibonacci numbers:

Wolfram Language code: ListLinePlot[Table[NestWhile[(# + 1)&, 1, Fibonacci[#] <= n&], {n, 200}]]

Plot of the absolute value of Fibonacci over the complex plane:

Wolfram Language code: Plot3D[Abs[Fibonacci[x + I y]], {x, -5, 5}, {y, -1, 1}]

Find the number of factors of Fibonacci polynomials:

Wolfram Language code: ListPlot[Table[Length[FactorList[Fibonacci[n, x]]], {n, 50}]]

If divides , then divides :

Wolfram Language code: fm = Fibonacci[30]

Wolfram Language code: ffm = Fibonacci[fm];

Wolfram Language code: And@@Table[Divisible[ffm, Fibonacci[n]], {n, Divisors[fm]}]

This is a particular case of a more general identity :

Wolfram Language code:

{Table[GCD[Fibonacci[n], Fibonacci[k]], {n, 5}, {k, 5}]//MatrixForm, 
	Table[Fibonacci[GCD[n, k]], {n, 5}, {k, 5}]//MatrixForm}

The sequence of is periodic with respect to for a fixed natural number :

Wolfram Language code: DiscretePlot[Mod[Fibonacci[n], 7], {n, 0, 35}]

For , the period equals :

Wolfram Language code: Table[Mod[Fibonacci[n + 16] - Fibonacci[n], 7], {n, 0, 15}]

Build Zeckendorf's representation of a positive integer [MathWorld]:

Wolfram Language code:

ZeckendorfRepresentation[n_Integer ? Positive] := Reap[Module[{m = n, f = Fibonacci}, 
	While[m > 0, m -= f@Sow[NestWhile[# + 1&, 1, f[#] ≤ m&] - 1]]]][[2, -1]]

Wolfram Language code: ZeckendorfRepresentation[2011]

Wolfram Language code: Total[Fibonacci[%]]

Define Fibonacci multiplication for positive integers:

Wolfram Language code:

FibonacciTimes[n_, m_] := Total[Fibonacci[Outer[Plus, ZeckendorfRepresentation[n], ZeckendorfRepresentation[m]]], Infinity]

Fibonacci multiplication table:

Wolfram Language code: Outer[FibonacciTimes, Range[6], Range[6]]//Grid

Verify that the Fibonacci multiplication is associative:

Wolfram Language code:

Table[FibonacciTimes[FibonacciTimes[n, m], k] == FibonacciTimes[n, FibonacciTimes[m, k]], {n, 1, 6}, {m, 1, 6}, {k, 1, 6}]//Flatten//Union

Properties & Relations (15)

Fibonacci Numbers (13)

Expand in terms of elementary functions:

Wolfram Language code: FunctionExpand[Fibonacci[n]]

Wolfram Language code: FullSimplify[Table[%, {n, 10}]]

Limiting ratio:

Wolfram Language code: Limit[Fibonacci[n] / Fibonacci[n - 1], n -> Infinity]

Explicit recursive definition:

Wolfram Language code: f[n_] := f[n] = f[n - 1] + f[n - 2]

Wolfram Language code: f[1] = f[2] = 1;

Wolfram Language code: Table[f[n], {n, 20}]

Explicit state‐space recursive definition:

Wolfram Language code: g[0] = {1, 1};

Wolfram Language code: g[n_Integer ? Positive] := g[n] = {{1, 1}, {1, 0}}.g[n - 1]

Wolfram Language code: f[n_] := Last[g[n]]

Wolfram Language code: Table[f[n], {n, 0, 10}]

Closed‐form solution using MatrixPower:

Wolfram Language code: Table[Last[MatrixPower[{{1, 1}, {1, 0}}, n].{1, 1}], {n, 0, 10}]

Simplify expressions involving Fibonacci numbers:

Wolfram Language code: FullSimplify[Fibonacci[n + 1]Fibonacci[n - 1] - Fibonacci[n]^2, n > 0 && n∈Integers]

Symbolic summation:

Wolfram Language code: Underoverscript[∑, k = 0, n]Fibonacci[k]Fibonacci[n - k]

Generating function:

Wolfram Language code: Underoverscript[∑, k = 0, ∞]Fibonacci[k]x^k//FullSimplify

Fibonacci numbers as coefficients:

Wolfram Language code: Series[%, {x, 0, 10}]

Express a fractional Fibonacci number as an algebraic number:

Wolfram Language code: Fibonacci[1 / 3]//FunctionExpand//RootReduce

Fibonacci can be represented as a DifferenceRoot:

Wolfram Language code: DifferenceRootReduce[Fibonacci[k], k]

Wolfram Language code: DifferenceRootReduce[Fibonacci[k, x], k]

General term in the series expansion of Fibonacci:

Wolfram Language code: SeriesCoefficient[Fibonacci[x], {x, 0, n}]

The generating function for Fibonacci:

Wolfram Language code: GeneratingFunction[Fibonacci[n], n, x]

Wolfram Language code: Series[%, {x, 0, 10}]

FindSequenceFunction can recognize the Fibonacci sequence:

Wolfram Language code: Table[Fibonacci[n], {n, 10}]

Wolfram Language code: FindSequenceFunction[%, n]

The exponential generating function for Fibonacci:

Wolfram Language code: ExponentialGeneratingFunction[Fibonacci[n], n, x]

Fibonacci Polynomials (2)

Expand in terms of elementary functions:

Wolfram Language code: FunctionExpand[Fibonacci[n, x]]

Explicitly construct Fibonacci polynomials:

Wolfram Language code: Table[Underoverscript[∑, m = 0, Floor[(n - 1/2)]]Binomial[n - m - 1, m]x^n - 2 m - 1, {n, 5}]

Wolfram Language code: Table[Fibonacci[n, x], {n, 5}]

Possible Issues (3)

Large arguments can give results too large to be computed explicitly:

Wolfram Language code: Fibonacci[10 ^ 16.]

Results for integer arguments may not hold for non-integers:

Wolfram Language code: FullSimplify[Fibonacci[2n] == Fibonacci[n + 1]^2 - Fibonacci[n - 1]^2, n∈Integers]

Wolfram Language code: Fibonacci[2n] == Fibonacci[n + 1]^2 - Fibonacci[n - 1]^2 /. n -> 2.5

Matrix power representation is valid only for integers:

Wolfram Language code: MatrixPower[{{1, 1}, {1, 0}}, 2.5]

Wolfram Language code: Fibonacci[{{n + 1, n}, {n, n - 1}}] /. n -> 2.5

Neat Examples (8)

Fibonacci numbers modulo 10:

Wolfram Language code: Mod[Array[Fibonacci, 100], 10]

Wolfram Language code: ListLinePlot[Mod[Array[Fibonacci, 200], 10]]

Fibonacci modulo n [more info]:

Wolfram Language code: ListLinePlot[Table[Mod[Fibonacci[n], n], {n, 200}]]

Count the number of 1, 2, ..., 9, 0 digits in the 1,000,000 Fibonacci number:

Wolfram Language code: DigitCount[Fibonacci[10 ^ 6]]

Contours of vanishing real and imaginary parts of Fibonacci:

Wolfram Language code: ContourPlot[{Re[Fibonacci[x + I y]] == 0, Im[Fibonacci[x + I y]] == 0}, {x, -8, 8}, {y, -8, 8}]

LogPlot of positive and negative Fibonacci numbers:

Wolfram Language code: LogPlot[Abs[Fibonacci[x]] + 1, {x, -10, 10}]

While the Fibonacci numbers are nondecreasing for non-negative arguments, the Fibonacci function possesses a single local minimum:

Wolfram Language code: Plot[Fibonacci[n], {n, 0, 4}, Prolog -> {PointSize[0.02], Point[Table[{k, Fibonacci[k]}, {k, 0, 4}]]}]

Since the generating function is rational, these sums come out as rational numbers:

Wolfram Language code: Underoverscript[∑, k = 1, ∞]2^-kFibonacci[k]

Wolfram Language code: Underoverscript[∑, k = 1, ∞]10^-kFibonacci[k]

The parities of Fibonacci polynomial coefficients give a slanted Sierpiński gasket:

Wolfram Language code: ArrayPlot[Mod[Table[CoefficientList[Fibonacci[n, x], x], {n, 60}], 2]]

Top

More Learning

Tech Support

Wolfram Solutions

Wolfram Solutions For Education

Get Started

Grow Your Skills

Work with Us

Educational Programs for Adults

Educational Programs for Youth

Read

Fibonacci

Details

Examples

Basic Examples (6)

Scope (43)

Numerical Evaluation (6)

Specific Values (6)

Visualization (5)

Function Properties (14)

Differentiation (3)

Integration (3)

Series Expansions (4)

Function Identities and Simplifications (2)

Generalizations & Extensions (2)

Applications (13)

Properties & Relations (15)

Fibonacci Numbers (13)

Fibonacci Polynomials (2)

Possible Issues (3)

Neat Examples (8)

Text

CMS

APA

BibTeX

BibLaTeX

Fibonacci

Details

Examples

Basic Examples (6)

Scope (43)

Numerical Evaluation (6)

Specific Values (6)

Visualization (5)

Function Properties (14)

Differentiation (3)

Integration (3)

Series Expansions (4)

Function Identities and Simplifications (2)

Generalizations & Extensions (2)

Applications (13)

Properties & Relations (15)

Fibonacci Numbers (13)

Fibonacci Polynomials (2)

Possible Issues (3)

Neat Examples (8)

See Also

Tech Notes

Related Guides

Related Links

History

Text

CMS

APA

BibTeX

BibLaTeX