LucasL
Details
- Mathematical function, suitable for both symbolic and numerical manipulation.
- The
satisfy the recurrence relation 
with 
, 
. - For any complex value of n the
are given by the general formula 
, where 
is the golden ratio. - The Lucas polynomial
is the coefficient of 
in the expansion of 
. - The Lucas polynomials satisfy the recurrence relation
. - LucasL can be evaluated to arbitrary numerical precision.
- LucasL automatically threads over lists.
- LucasL can be used with Interval and CenteredInterval objects. »
Examples
open all close allBasic Examples (4)
Table[LucasL[n], {n, 20}]Plot over a subset of the reals:
Plot[LucasL[1 / 2, x], {x, -5, 5}]Plot over a subset of the complexes:
ComplexPlot3D[LucasL[2, z], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]Series expansion at the origin:
Series[LucasL[1 / 2, x], {x, 0, 5}]Scope (39)
Numerical Evaluation (6)
LucasL[143, 1]LucasL[-11.]N[LucasL[11 / 3], 50]The precision of the output tracks the precision of the input:
LucasL[2.3333333333333333333333333333]N[LucasL[1 + I / 2]]Evaluate efficiently at high precision:
LucasL[1 / 7`100]//TimingLucasL[1 / 16`10000];//TimingCompute worst-case guaranteed intervals using Interval and CenteredInterval objects:
LucasL[Interval[{0.5, 0.6}]]LucasL[CenteredInterval[1 / 2, 1 / 100]]Or compute average-case statistical intervals using Around:
LucasL[1, Around[2, 0.01]]Compute the elementwise values of an array:
LucasL[2, {{1 / 2, -1}, {0, 1 / 2}}]Or compute the matrix LucasL function using MatrixFunction:
MatrixFunction[LucasL[2, #]&, {{1 / 2, -1}, {0, 1 / 2}}]//FullSimplifySpecific Values (6)
Values of LucasL at fixed points:
Table[LucasL[10, x], {x, 1, 5}]LucasL for symbolic n:
Table[LucasL[n, x], {x, 0, 2}]//FunctionExpandLucasL[1, 0]LucasL[0, 0]Find the value of x in which LucasL[2,x]=5:
xval = x /. FindRoot[LucasL[2, x] == 5, {x, 2}]Plot[LucasL[2, x ], {x, 0, 5}, Epilog -> Style[Point[{xval, LucasL[2, xval]}], PointSize[Large], Red]]Compute the associated LucasL[7,x] polynomial:
LucasL[7, x]Compute the associated LucasL[1/2,x] polynomial for half-integer n:
LucasL[1 / 2, x]//FunctionExpandVisualization (4)
Plot the LucasL polynomial for various orders:
Plot[{LucasL[1, x], LucasL[2, x], LucasL[3, x], LucasL[4, x]}, {x, -2, 2}]](Files/LucasL.en/14.png "TemplateBox[{2}, LucasL](z)"){kind=small}
ComplexContourPlot[Re[LucasL[2, z]], {z, -1 - I, 1 + I}, Contours -> 24]](Files/LucasL.en/15.png "TemplateBox[{2}, LucasL](z)"){kind=small}
ComplexContourPlot[Im[LucasL[2, z]], {z, -1 - I, 1 + I}, Contours -> 24]Plot as real parts of two parameters vary:
Plot3D[Re[LucasL[n, z]], {n, 0, 5}, {z, -1, 1}, PlotRange -> All]Types 2 and 3 of LucasL function have different branch cut structures:
Plot3D[Im[LucasL[2, x + I y]], {x, -3, 3}, {y, -0.5, 0.5}, Exclusions -> {{y == 0, Abs[x] > 1}}]Plot3D[Im[LucasL[3, x + I y]], {x, -3, 3}, {y, -0.5, 0.5}, Exclusions -> {{y == 0, -1 < x < 1}}]Function Properties (14)
LucasL is defined for all real and complex values:
FunctionDomain[LucasL[1, z], z]FunctionDomain[LucasL[1, z], z, Complexes]The range of ![TemplateBox[{n, x}, LucasL2]](Files/LucasL.en/16.png "TemplateBox[{n, x}, LucasL2]"){kind=small}
is all real numbers for odd 
:
FunctionRange[LucasL[3, x], x, y]Its range over the complex plane is all complex numbers for any natural number 
:
FunctionRange[LucasL[2, z], z, y, Complexes]Lucas polynomial of an odd order is odd:
LucasL[1, -x] == -LucasL[1, x]Lucas polynomial of an even order is even:
LucasL[2, -x] == LucasL[2, x]LucasL has the mirror property ![TemplateBox[{n, {z, }}, LucasL2]=TemplateBox[{n, z}, LucasL2]](Files/LucasL.en/19.png "TemplateBox[{n, {z, }}, LucasL2]=TemplateBox[{n, z}, LucasL2]"){kind=small}
:
LucasL[1, Conjugate[z]] == Conjugate[LucasL[1, z]]LucasL threads elementwise over lists:
LucasL[{1, 2, 3, 4, 5}]![TemplateBox[{n, x}, LucasL2]](Files/LucasL.en/20.png "TemplateBox[{n, x}, LucasL2]"){kind=small}
FunctionAnalytic[LucasL[n, x], x, Assumptions -> n∈ℤ]LucasL is neither non-decreasing nor non-increasing for even values:
FunctionMonotonicity[LucasL[2, x], x]LucasL is non-decreasing for odd values:
FunctionMonotonicity[LucasL[5, x], x]LucasL is not injective for even values:
Table[FunctionInjective[LucasL[a, x], x], {a, 4}]Plot[{LucasL[3, x], LucasL[2, x], 5}, {x, -3, 3}]LucasL is not surjective for even values:
Table[FunctionSurjective[LucasL[a, x], x], {a, 4}]Plot[{LucasL[2, x], LucasL[4, x], -2}, {x, -3, 3}]LucasL is non-negative for even values:
Table[FunctionSign[LucasL[a, x], x], {a, 4}]LucasL does not have singularity nor discontinuity:
Table[FunctionSingularities[LucasL[a, x], x], {a, 4}]Table[FunctionDiscontinuities[LucasL[a, x], x], {a, 4}]LucasL is convex for even values:
Table[FunctionConvexity[LucasL[a, x], x], {a, 2, 8, 2}]TraditionalForm formatting:
LucasL[n]//TraditionalFormLucasL[n, x]//TraditionalFormDifferentiation (3)
First derivatives with respect to n:
D[LucasL[n], n]Simplify[%, Element[n, Integers] && n > 0]D[LucasL[n, x], n]Simplify[%, Element[n, Integers] && n > 0]First derivative with respect to x:
D[LucasL[n, x], x]Higher derivatives with respect to x:
Table[D[LucasL[n, x], {x, k}], {k, 1, 3}]//FullSimplifyPlot the higher derivatives with respect to x when n=4:
Plot[Evaluate[% /. n -> 4], {x, -5, 5}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative"}]Formula for the 
derivative with respect to x:
D[LucasL[n, x], {x, k}]// FullSimplifySeries Expansions (4)
Find the Taylor expansion using Series:
Series[LucasL[x], {x, 0, 3}]// NormalPlots of the first three approximations around 
:
terms = Normal@Table[Series[LucasL[x], {x, 0, m}], {m, 1, 5, 2}];
Plot[{LucasL[x], terms}, {x, -5, 5}]General term in the series expansion using SeriesCoefficient:
SeriesCoefficient[LucasL[x], {x, 0, n}]Find the series expansion at Infinity:
Series[Fibonacci[x], {x, LucasL, 1}]//Normal//FullSimplifyTaylor expansion at a generic point:
Series[LucasL[x], {x, x0, 2}]//Normal//FullSimplifyFunction Identities and Simplifications (2)
Lucas numbers are related to the Fibonacci numbers by the identities:
LucasL[n] == Fibonacci[n - 1] + Fibonacci[n + 1]//FullSimplifyFibonacci[n] == (LucasL[n - 1] + LucasL[n + 1]/5)//FullSimplifyThe ordinary generating function of LucasL:
GeneratingFunction[LucasL[n], n, x]Generalizations & Extensions (1)
Applications (6)
Solve the Fibonacci recurrence equation:
RSolve[{f[n] == f[n - 1] + f[n - 2], f[1] == a, f[2] == b}, f[n], n]FullSimplify[Table[First[f[n] /. %], {n, 10}]]Find ratios of successive Lucas numbers:
Table[LucasL[n + 1] / LucasL[n], {n, 15}]Compare with continued fractions:
Table[FromContinuedFraction[PadLeft[{3}, n, 1]], {n, 15}]Convergence to the Golden Ratio:
N[%]Calculate the number of ways to write an integer as a sum of Lucas numbers 
:
lucasSumCount[n_] := SeriesCoefficient[Series[Product[1 + z ^ LucasL[k], {k, Ceiling[Log[GoldenRatio, n]] + 2}], {z, 0, n}], n]Plot the counts for the first hundred integers:
ListPlot[Table[lucasSumCount[n], {n, 100}]]Find the first Lucas number above 1000000:
NestWhile[(# + 1)&, 1, LucasL[#] <= 10 ^ 6&]Select[Range[2, 10000], (!PrimeQ[#] && Divisible[LucasL[#] - 1, #])&]Exp[-NSum[ ((LucasL[n] - 1)/n)PrimeZetaP[n], {n, 2, Infinity}, WorkingPrecision -> 50, NSumTerms -> 200]]Properties & Relations (10)
Expand in terms of elementary functions:
FunctionExpand[LucasL[n]]FullSimplify[Table[%, {n, 10}]]Limit[LucasL[n + 1] / LucasL[n], n -> Infinity]Explicit recursive definition:
f[n_] := f[n] = f[n - 1] + f[n - 2]f[1] = 2;
f[2] = 1;Table[f[n], {n, 20}]Simplify some expressions involving Lucas numbers:
FullSimplify[LucasL[n + 1]LucasL[n - 1] - LucasL[n]^2, n > 0 && n∈Integers]Sum[LucasL[k]t^k, {k, Infinity}]Extract Lucas numbers as coefficients:
Series[%, {t, 0, 10}]LucasL can be represented as a DifferenceRoot:
DifferenceRootReduce[LucasL[k], k]DifferenceRootReduce[LucasL[3, k], k]General term in the series expansion of LucasL:
SeriesCoefficient[LucasL[x], {x, 0, n}]The generating function for LucasL:
GeneratingFunction[LucasL[n], n, x]Series[%, {x, 0, 10}]//FullSimplifyFindSequenceFunction can recognize the LucasL sequence:
Table[LucasL[n], {n, 10}]FindSequenceFunction[%, n]The exponential generating function for LucasL:
ExponentialGeneratingFunction[LucasL[n], n, x]Possible Issues (2)
Large arguments can give results too large to be computed explicitly:
LucasL[10 ^ 16.]
Results for integer arguments may not hold for non-integers:
FullSimplify[2LucasL[2n] == 5Fibonacci[n]^2 + LucasL[n]^2, n∈Integers]2LucasL[2n] == 5Fibonacci[n]^2 + LucasL[n]^2 /. n -> 2.5Related Links
MathWorldText
Wolfram Research (2007), LucasL, Wolfram Language function, https://reference.wolfram.com/language/ref/LucasL.html (updated 2008).
CMS
Wolfram Language. 2007. "LucasL." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2008. https://reference.wolfram.com/language/ref/LucasL.html.
APA
Wolfram Language. (2007). LucasL. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/LucasL.html