WOLFRAM

Wolfram Language & System Documentation Center

FilledTorus[{x,y,z},{rinner,router}]

represents a filled torus centered at {x,y,z} with inner radius rinner and outer radius router.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Graphics  
Specification  
Styling  
Coordinates  
Regions  
Applications  
Properties & Relations  
Neat Examples  
See Also
Related Guides
History
Cite this Page

FilledTorus

FilledTorus[{x,y,z},{rinner,router}]

represents a filled torus centered at {x,y,z} with inner radius rinner and outer radius router.

Details and Options

Examples

open all close all

Basic Examples  (2)

The standard filled torus at the origin:

Wolfram Language code: Graphics3D[{Opacity[0.5], FilledTorus[]}]

Volume and centroid:

Wolfram Language code: Volume[FilledTorus[{Subscript[c, 1], Subscript[c, 2], Subscript[c, 3]}, {Subscript[r, inner], Subscript[r, outer]}]]
Wolfram Language code: RegionCentroid[FilledTorus[{Subscript[c, 1], Subscript[c, 2], Subscript[c, 3]}, {Subscript[r, inner], Subscript[r, outer]}]]

Scope  (18)

Graphics  (9)

Specification  (4)

The standard filled torus:

Wolfram Language code: Graphics3D[{Opacity[0.5], FilledTorus[{0, 0, 0}, {1 / 2, 1}]}]

Filled tori with different outer radii:

Wolfram Language code: Graphics3D[{Opacity[0.5], FilledTorus[{0, 0, 0}, {1 / 2, 1}], FilledTorus[{3, 0, 0}, {1 / 2, 2}]}]

Filled tori with different inner radii:

Wolfram Language code: Graphics3D[{FaceForm[Yellow, Blue], FilledTorus[{0, 0, 0}, {1 / 2, 1}], FaceForm[Yellow, Blue], FilledTorus[{2, 0, 0}, {1 / 4, 1}]}, PlotRange -> {{-1, 3}, {-.2, 1}, {-1, 1}}]

Short form for a filled torus with radii at the origin:

Wolfram Language code: Graphics3D[{Opacity[0.5], FilledTorus[]}, Axes -> True]

Styling  (4)

Colored filled tori:

Wolfram Language code: Table[Graphics3D[{Opacity[0.5], c, FilledTorus[]}], {c, {Red, Green, Blue, Yellow}}]

Different properties can be specified for the front and back of faces using FaceForm:

Wolfram Language code: Graphics3D[{FaceForm[Yellow, Blue], FilledTorus[]}, PlotRange -> {{-1, 1}, {-.3, 1}, {-1, 1}}]

Filled tori with different specular exponents:

Wolfram Language code: Table[Graphics3D[{Orange, Specularity[White, n], Opacity[0.5], FilledTorus[]}], {n, {5, 20, 100}}]

White filled torus that glows red:

Wolfram Language code: Graphics3D[{Glow[Red], White, Opacity[0.5], FilledTorus[]}]

Opacity specifies the face opacity:

Wolfram Language code: Table[Graphics3D[{Opacity[o], FilledTorus[]}], {o, {0.3, 0.5, 0.9}}]

Coordinates  (1)

Points can be Dynamic:

Wolfram Language code: DynamicModule[{x}, {Slider[Dynamic[x], {-0.5, 0.5}], Graphics3D[{FilledTorus[], FilledTorus[Dynamic[{x, 1, 1}], {1 / 8, 1 / 4}]}]}]

Regions  (9)

Embedding dimension is the dimension of the space in which the filled torus lives:

Wolfram Language code: RegionEmbeddingDimension[FilledTorus[{Subscript[c, 1], Subscript[c, 2], Subscript[c, 3]}, {Subscript[``r``, ``inner``], Subscript[``r``, ``outer``]}]]

Geometric dimension is the dimension of the shape itself:

Wolfram Language code: RegionDimension[FilledTorus[{Subscript[c, 1], Subscript[c, 2], Subscript[c, 3]}, {Subscript[``r``, ``inner``], Subscript[``r``, ``outer``]}]]

Membership testing:

Wolfram Language code: ℛ = FilledTorus[{0, 0, 0}, {1 / 2, 1}];
Wolfram Language code: {RegionMember[ℛ, {1, 0, 0}], RegionMember[ℛ, {0, 0, 0}], RegionMember[ℛ, {1, 1, 1}]}

Get conditions for point membership:

Wolfram Language code: RegionMember[FilledTorus[{Subscript[c, 1], Subscript[c, 2], Subscript[c, 3]}, {Subscript[``r``, ``inner``], Subscript[``r``, ``outer``]}], {x, y, z}]

Volume:

Wolfram Language code: ℛ = FilledTorus[{0, 0, 0}, {1 / 2, 1}];
Wolfram Language code: {Volume[ℛ], RegionMeasure[ℛ]}

Centroid:

Wolfram Language code: c = RegionCentroid[ℛ]
Wolfram Language code: Graphics3D[{{Opacity[0.5], LightBlue, ℛ}, {PointSize[Large], Red, Point[c]}}]

Distance from a point:

Wolfram Language code: ℛ = FilledTorus[{0, 0, 0}, {3 / 4, 1}];
Wolfram Language code: {RegionDistance[ℛ, {1, 0, 0}], RegionDistance[ℛ, {0, 0, 0}], RegionDistance[ℛ, {1, 1, 1}]}

The equidistance contours for a filled torus:

Wolfram Language code: ContourPlot3D[Evaluate@RegionDistance[ℛ, {x, y, z}], {x, -2, 2}, {y, 0, 2}, {z, -2, 2}, Mesh -> None, Contours -> {0.25, 0.5, 1}, BoxRatios -> Automatic]

Signed distance from a point:

Wolfram Language code: ℛ = FilledTorus[{0, 0, 0}, {1 / 2, 1}];
Wolfram Language code: {SignedRegionDistance[ℛ, {1, 0, 0}], SignedRegionDistance[ℛ, {1 / 2, 1 / 2, 0}], SignedRegionDistance[ℛ, {1, 1, 1}]}

Nearest point in the region:

Wolfram Language code: ℛ = FilledTorus[{0, 0, 0}, {1 / 2, 1}];
Wolfram Language code: {RegionNearest[ℛ, {1, 0, 0}], RegionNearest[ℛ, {1 / 2, 1 / 2, 1 / 2}]}

Nearest points to an enclosing sphere:

Wolfram Language code: spherePoints[{n_, m_}, c_, r_] := Flatten[Table[c + r{Cos[k 2π / n]Sin[l π / m], Sin[k 2π / n]Sin[l π / m], Cos[l π / m]}, {k, 0., n - 1}, {l, 0., m - 1}], 1];
Wolfram Language code: pl = spherePoints[{16, 8}, RegionCentroid[ℛ], 2]; npl = Table[RegionNearest[ℛ, p], {p, pl}];
Wolfram Language code: Legended[Graphics3D[{ℛ, {Thin, Gray, Line[Transpose[{pl, npl}]]}, {Red, Point[pl]}, {PointSize[Medium], Blue, Point[npl]}}, Lighting -> "Neutral", Boxed -> False], PointLegend[{Red, Blue}, {"start", "nearest"}]]

A filled torus is bounded:

Wolfram Language code: BoundedRegionQ[FilledTorus[{Subscript[c, 1], Subscript[c, 2], Subscript[c, 3]}, {Subscript[``r``, ``inner``], Subscript[``r``, ``outer``]}]]
Wolfram Language code: RegionBounds[FilledTorus[{0, 0, 0}, {Subscript[``r``, ``inner``], Subscript[``r``, ``outer``]}]]
Wolfram Language code: ℛ = FilledTorus[{0, 0, 0}, {1 / 2, 1}];
Wolfram Language code: BoundedRegionQ[ℛ]

Find its range:

Wolfram Language code: b = RegionBounds[ℛ]
Wolfram Language code: Graphics3D[{{EdgeForm[White], Opacity[0.2, Yellow], Cuboid@@Transpose[b]}, ℛ}, Boxed -> False]

Optimize over a filled torus region:

Wolfram Language code: ℛ = FilledTorus[{1, 2, 3}, {2, 4}];
Wolfram Language code: MinValue[{x y z - x y, {x, y, z}∈ℛ}, {x, y, z}]

Solve equations in a filled torus region:

Wolfram Language code: ℛ = FilledTorus[{1, 2, 1}, 3];
Wolfram Language code: Reduce[x^2 + y^2 + z^2 == 9 && z^2 == x y + (1/4) && {x, y, z}∈ℛ, {x, y, z}]

Applications  (2)

Find the minimum surface area for a filled torus with volume :

Wolfram Language code: ℛ = FilledTorus[{0, 0, 0}, {r / 2, r}];
Wolfram Language code: Minimize[{SurfaceArea[ℛ], Volume[ℛ] == 2π && r > 0}, {r}]

Find the mass of caffeine in a filled torus with a radius of 3 centimeters:

Wolfram Language code: ℛ = FilledTorus[{0, 0, 0}, Quantity[3, "Centimeters"]];

Density of caffeine:

Wolfram Language code: d = ChemicalData["Caffeine", "Density"]

Volume of filled torus:

Wolfram Language code: v = Volume[ℛ]

Mass of caffeine in the filled torus:

Wolfram Language code: FormulaData["MassDensity", {"ρ" -> d, "V" -> N[v]}]

Properties & Relations  (1)

Torus is the RegionBoundary of FilledTorus:

Wolfram Language code: RegionBoundary[FilledTorus[{x, y, z}, r]]

Neat Examples  (3)

Random filled torus collections:

Wolfram Language code: Graphics3D[Table[{Opacity[.5, Hue[RandomReal[]]], Rotate[FilledTorus[RandomReal[2, {3}], RandomReal[1]], RandomReal[{0, 2 Pi}], RandomReal[{-1, 1}, 3]]}, {50}]]

Double helix:

Wolfram Language code: Graphics3D[{Specularity[White, 30], Table[With[{x = 2Cos[t], y = 2Sin[t], p = 2Sin[t + Pi], q = 2Sin[t + Pi]}, {Hue[t / (5Pi)], Arrowheads[0], Arrow[Tube[{{x, y, t}, {p, q, t}}, .1], .3], FilledTorus[{x, y, t}, .3], FilledTorus[{p, q, t}, .3]}], {t, 0, 5Pi, .3}]}, Boxed -> False, Background -> GrayLevel[.2]]

Nested filled tori:

Wolfram Language code: Graphics3D[Table[{Opacity[.15, Hue[i / 3]], FilledTorus[{0, 0, 0}, {i, 7 - i}]}, {i, 1, 3}]]
Wolfram Research (2021), FilledTorus, Wolfram Language function, https://reference.wolfram.com/language/ref/FilledTorus.html.

Text

Wolfram Research (2021), FilledTorus, Wolfram Language function, https://reference.wolfram.com/language/ref/FilledTorus.html.

CMS

Wolfram Language. 2021. "FilledTorus." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/FilledTorus.html.

APA

Wolfram Language. (2021). FilledTorus. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/FilledTorus.html

BibTeX

@misc{reference.wolfram_2026_filledtorus, author="Wolfram Research", title="{FilledTorus}", year="2021", howpublished="\url{https://reference.wolfram.com/language/ref/FilledTorus.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_filledtorus, organization={Wolfram Research}, title={FilledTorus}, year={2021}, url={https://reference.wolfram.com/language/ref/FilledTorus.html}, note=[Accessed: 13-June-2026]}