Wolfram Language & System Documentation Center

GegenbauerC

GegenbauerC[n,m,x]

gives the Gegenbauer polynomial .

GegenbauerC[n,x]

gives the renormalized form .

Details

Mathematical function, suitable for both symbolic and numerical manipulation.
Explicit polynomials are given for integer n and for any m.
satisfies the differential equation .
The Gegenbauer polynomials are orthogonal on the interval with weight function , corresponding to integration over a unit hypersphere.
For certain special arguments, GegenbauerC automatically evaluates to exact values.
GegenbauerC can be evaluated to arbitrary numerical precision.
GegenbauerC automatically threads over lists.
GegenbauerC[n,0,x] is always zero.
GegenbauerC[n,m,z] has a branch cut discontinuity in the complex z plane running from to .
GegenbauerC can be used with Interval and CenteredInterval objects. »

Examples

open all close all

Basic Examples (7)

Evaluate numerically:

Wolfram Language code: N[GegenbauerC[3, 1 / 2, 7]]

Compute the 10 Gegenbauer polynomial:

Wolfram Language code: GegenbauerC[10, 1, x]

Compute the 10 renormalized Gegenbauer polynomial:

Wolfram Language code: GegenbauerC[10, x]

Plot over a subset of the reals:

Wolfram Language code: Plot[GegenbauerC[10, x], {x, -1, 1}]

Plot over a subset of the complexes:

Wolfram Language code: ComplexPlot3D[GegenbauerC[5, z], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

Series expansion at the origin:

Wolfram Language code: Series[GegenbauerC[5, x], {x, 0, 5}]

Asymptotic expansion at Infinity:

Wolfram Language code: Series[GegenbauerC[5, x], {x, ∞, 3}]//FullSimplify

Asymptotic expansion at a singular point:

Wolfram Language code: Series[GegenbauerC[5, x], {x, -1, 3}]//FullSimplify

Scope (44)

Numerical Evaluation (6)

Evaluate numerically:

Wolfram Language code: GegenbauerC[5, 1 / 8, 7.]

Wolfram Language code: GegenbauerC[2, 0.5]

Evaluate to high precision:

Wolfram Language code: N[GegenbauerC[1 / 6, 1 / 8, 7], 50]

The precision of the output tracks the precision of the input:

Wolfram Language code: GegenbauerC[0.333333333333333333, 7, 1]

Complex number input:

Wolfram Language code: N[GegenbauerC[2 / 7, 5 - I, 2]]

Evaluate efficiently at high precision:

Wolfram Language code: GegenbauerC[2 / 49, 5, 1`100]//Timing

Wolfram Language code: GegenbauerC[89 / 49, 3, 5`1000];//Timing

Compute worst-case guaranteed intervals using Interval and CenteredInterval objects:

Wolfram Language code: GegenbauerC[3 / 4, 4 / 5, Interval[{1.9, 2.1}]]

Wolfram Language code: GegenbauerC[3 / 4, 4 / 5, CenteredInterval[5, 1 / 100]]

Or compute average-case statistical intervals using Around:

Wolfram Language code: GegenbauerC[1 / 2, Around[.9, 0.1]]

Compute the elementwise values of an array:

Wolfram Language code: GegenbauerC[3, {{2, 0}, {1 / 2, -2}}]

Or compute the matrix GegenbauerC function using MatrixFunction:

Wolfram Language code: MatrixFunction[GegenbauerC[3, #]&, {{2, 0}, {1 / 2, -2}}]

Specific Values (8)

Values of GegenbauerC at fixed points:

Wolfram Language code: Table[GegenbauerC[10, x ], {x, 1, 5}]

Simple cases give exact symbolic results:

Wolfram Language code: GegenbauerC[{1 / 3, 1 / 2}, 1 / 6, 0]

GegenbauerC for symbolic n:

Wolfram Language code: GegenbauerC[n, 0]

Wolfram Language code: GegenbauerC[n, 1 / 2, x]

Wolfram Language code: GegenbauerC[n, 1, x]

Wolfram Language code: GegenbauerC[n, x]

Wolfram Language code: Table[GegenbauerC[n, m, x], {x, 0, 1}, {m, 0, 1}]

Values at zero:

Wolfram Language code: GegenbauerC[1, 0]

Wolfram Language code: GegenbauerC[0, 1, 1]

Find the first positive maximum of GegenbauerC[10,x ]:

Wolfram Language code: xmax = x /. Solve[D[GegenbauerC[10, x ], x] == 0 && 0 < x < 5, x][[1]]

Wolfram Language code: Plot[GegenbauerC[10, x ], {x, -1, 1}, Epilog -> Style[Point[{xmax, GegenbauerC[10, xmax ]}], PointSize[Large], Red]]

Compute the associated GegenbauerC[7,x] polynomial:

Wolfram Language code: GegenbauerC[7, x]

Compute the associated GegenbauerC[1/2,x] polynomial for half-integer n:

Wolfram Language code: GegenbauerC[1 / 2, x]

Different GegenbauerC types give different symbolic forms:

Wolfram Language code: Table[GegenbauerC[n, m, x], {n, 0, 3}, {m, 0, 1}]

Visualization (4)

Plot the GegenbauerC function for various orders:

Wolfram Language code: Plot[{GegenbauerC[1, x], GegenbauerC[2, x], GegenbauerC[3, x], GegenbauerC[4, x]}, {x, -.7, .7}]

Plot the real part of :

Wolfram Language code: ComplexContourPlot[Re[GegenbauerC[3, 1, z]], {z, -3 - 3 I, 3 + 3 I}, IconizedObject[«PlotOptions»]]

Plot the imaginary part of :

Wolfram Language code: ComplexContourPlot[Im[GegenbauerC[3, 1, z]], {z, -3 - 3 I, 3 + 3 I}, IconizedObject[«PlotOptions»]]

Plot as real parts of two parameters vary:

Wolfram Language code: Plot3D[Re[GegenbauerC[n, 1, z]], {n, 0, 5}, {z, -1, 1}]

Types 2 and 3 of GegenbauerC function have different branch cut structures:

Wolfram Language code: Plot3D[Im[GegenbauerC[2, x + I y]], {x, -1.5, 1.5}, {y, -0.5, 0.5}, Exclusions -> {{y == 0, Abs[x] > 1}}]

Wolfram Language code:

Plot3D[Im[GegenbauerC[3, x + I y]], {x, -1.5, 1.5}, {y, -0.5, 0.5}, Exclusions -> {{y == 0, -1 < x < 1}}, PlotRange -> All]

Function Properties (14)

Domain of GegenbauerC of integer orders:

Wolfram Language code: {FunctionDomain[GegenbauerC[1, z], z], FunctionDomain[GegenbauerC[2, z], z]}

Wolfram Language code: {FunctionDomain[GegenbauerC[1, z], z, Complexes], FunctionDomain[GegenbauerC[2, z], z, Complexes]}

The range for GegenbauerC of integer orders:

Wolfram Language code: {FunctionRange[GegenbauerC[1, x], x, y], FunctionRange[GegenbauerC[2, x], x, y]}

The range for complex values is the whole plane:

Wolfram Language code: {FunctionRange[GegenbauerC[1, z], z, y, Complexes], FunctionRange[GegenbauerC[2, z], z, y, Complexes]}

Gegenbauer polynomial of an odd order is odd:

Wolfram Language code: GegenbauerC[1, -x] == -GegenbauerC[1, x]

Gegenbauer polynomial of an even order is even:

Wolfram Language code: GegenbauerC[2, -x] == GegenbauerC[2, x]

GegenbauerC threads elementwise over lists:

Wolfram Language code: GegenbauerC[{1, 2, 3}, m, x]

GegenbauerC has the mirror property :

Wolfram Language code:

{GegenbauerC[1, Conjugate[z]] == Conjugate[GegenbauerC[1, z]], GegenbauerC[2, Conjugate[z]] == Conjugate[GegenbauerC[2, z]]}

Gegenbauer polynomials are analytic:

Wolfram Language code: FunctionAnalytic[GegenbauerC[n, x], x, Assumptions -> n∈ℤ && n ≠ 0]

However, the GegenbauerC function is generally not analytic for noninteger parameters:

Wolfram Language code: FunctionAnalytic[GegenbauerC[1 / 2, x], x]

Wolfram Language code: FunctionAnalytic[GegenbauerC[1 / 2, 1, x], x]

Nor is it meromorphic:

Wolfram Language code: FunctionMeromorphic[GegenbauerC[1 / 2, x], x]

Wolfram Language code: FunctionMeromorphic[GegenbauerC[1 / 2, 1, x], x]

is neither non-decreasing nor non-increasing:

Wolfram Language code: FunctionMonotonicity[GegenbauerC[2, x], x]

is not injective:

Wolfram Language code: FunctionInjective[GegenbauerC[2, x], x]

Wolfram Language code: Plot[{GegenbauerC[2, x], 2}, {x, -2, 2}]

is not surjective:

Wolfram Language code: FunctionSurjective[GegenbauerC[2, x], x]

Wolfram Language code: Plot[{GegenbauerC[2, x], -2}, {x, -2, 2}]

is neither non-negative nor non-positive:

Wolfram Language code: FunctionSign[GegenbauerC[2, x], x]

has singularities or discontinuities when is not an integer and :

Wolfram Language code: FunctionSingularities[GegenbauerC[n, x], x]

Wolfram Language code: FunctionDiscontinuities[GegenbauerC[n, x], x]

has additional singularities when is noninteger:

Wolfram Language code: FunctionSingularities[GegenbauerC[n, m, x], x]

Wolfram Language code: FunctionDiscontinuities[GegenbauerC[n, m, x], x]

is convex:

Wolfram Language code: FunctionConvexity[GegenbauerC[2, x], x]

TraditionalForm formatting:

Wolfram Language code: GegenbauerC[n, λ, x]//TraditionalForm

Wolfram Language code: GegenbauerC[n, m]//HoldForm//TraditionalForm

Differentiation (3)

First derivatives with respect to x:

Wolfram Language code: D[GegenbauerC[n, m, x], x]

Wolfram Language code: D[GegenbauerC[n, x], x]

Higher derivatives with respect to x:

Wolfram Language code: Table[D[GegenbauerC[n, m, x], {x, k}], {k, 1, 3}]//FullSimplify

Plot the higher derivatives with respect to x when n=10 and m=1/3:

Wolfram Language code:

Plot[Evaluate[% /. { n -> 10, m -> 1 / 3}], {x, -3, 3}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative"}]

Formula for the derivative with respect to x:

Wolfram Language code: D[GegenbauerC[n, m, x], {x, k}]// FullSimplify

Integration (3)

Compute the indefinite integral using Integrate:

Wolfram Language code: Integrate[GegenbauerC[n, m, x], x]

Verify the anti-derivative:

Wolfram Language code: FullSimplify[D[%, x]]

Definite integral:

Wolfram Language code: Integrate[GegenbauerC[n, m, x], {x, 0, 4}]

More integrals:

Wolfram Language code: Integrate[Exp[x] GegenbauerC[2, x], x]//FullSimplify

Wolfram Language code: Integrate[ x GegenbauerC[1, x^2], {x, 0, 3}]//FullSimplify

Series Expansions (2)

Find the Taylor expansion using Series:

Wolfram Language code: Series[GegenbauerC[n, x], {x, 0, 3}]

Plots of the first three approximations around :

Wolfram Language code:

terms = Normal@Table[Series[GegenbauerC[10, x], {x, 0, m}], {m, 1, 5, 2}];
Plot[{GegenbauerC[10, x], terms}, {x, -1, 1}]

Taylor expansion at a generic point:

Wolfram Language code: Series[GegenbauerC[n, x], {x, x0, 2}]// Normal//FullSimplify

Function Identities and Simplifications (4)

GegenbauerC is a special case of JacobiP:

Wolfram Language code: GegenbauerC[n, m, x] == (Pochhammer[2m, n]/Pochhammer[m + 1 / 2, n]) JacobiP[n, m - 1 / 2, m - 1 / 2, x]//FullSimplify

Derivative identity of GegenbauerC:

Wolfram Language code: D[GegenbauerC[n, m, x], x] == 2 m GegenbauerC[n - 1, m + 1, x]

Generating function of Gegenbauer polynomials:

Wolfram Language code: GeneratingFunction[GegenbauerC[n, m, x], n, t]

Recurrence relations:

Wolfram Language code:

GegenbauerC[n, m, x] == (2 (m + n + 1)x/2 m  + n) GegenbauerC[n + 1, m, x] - ( n + 2/2 m  + n) GegenbauerC[n + 2, m, x] //FullSimplify

Wolfram Language code:

GegenbauerC[n, m, x] == (2 (m + n - 1)x/n) GegenbauerC[n - 1, m, x] - (2 m + n - 2/n) GegenbauerC[n - 2, m, x] //FullSimplify

Generalizations & Extensions (2)

Apply GegenbauerC to a power series:

Wolfram Language code: GegenbauerC[5, Sin[x] + O[x] ^ 4]

GegenbauerC can deal with real-valued intervals:

Wolfram Language code: GegenbauerC[4, Interval[{-1, 1}]]

Applications (3)

Eigenfunctions of the angular part of the four-dimensional Laplace operator:

Wolfram Language code:

Δ = ((1/Sin[θ]^2)D[ Sin[θ]^2D[#, θ], θ] + (1/Sin[θ]^2Sin[χ])D[Sin[χ]D[#, χ], χ] + (1/Sin[θ]^2Sin[χ]^2)D[#, ϕ, ϕ])&;

Wolfram Language code: With[{f = GegenbauerC[ n, 1, Cos[θ]]}, FullSimplify[Δ[ f ] / f]]

Radial part of the hydrogen atom eigenfunction in momentum representation:

Wolfram Language code:

ψ[{n_, l_, m_}, p_] := (2^ll!/n^2)Sqrt[((n - l - 1)!/(n + l)!)]((p / n)^l/(p^2 + n^-2)^2 + l)GegenbauerC[n - l - 1, l + 1, (1 - n^2p^2/1 + n^2p^2)]

Wolfram Language code: Table[Plot[ψ[{4, l, 0}, p] ^ 2, {p, 0, 0.4}], {l, 0, 3}]

In an n-point Gauss–Lobatto quadrature rule, the values of the two extreme nodes are fixed, and the other n-2 nodes are computed from the roots of a certain Gegenbauer polynomial. Compute the nodes and weights of an n-point Gauss–Lobatto quadrature rule:

Wolfram Language code:

n = 10;
tmp = x /. NSolve[GegenbauerC[n - 2, 3 / 2, x], x];
lobattoNodes = Join[{N[-1]}, tmp, {N[1]}]

Wolfram Language code:

w1 = x |-> (2/n(n - 1)GegenbauerC[n - 1, 1 / 2, x]^2);
lobattoWeights = ArrayPad[w1[tmp], 1, N[(2/n(n - 1))]]

Use the n-point Gauss–Lobatto quadrature rule to numerically evaluate an integral:

Wolfram Language code: fun[x_] := (1/1 / 100 + (x - 3 / 10)^2) + (1/1 / 25 + (x - 9 / 10)^2) - 6

Wolfram Language code:

a = 1 / 2;b = 1;
est1 = ((b - a/2)lobattoWeights).Map[fun, Rescale[lobattoNodes, {-1, 1}, {a, b}]]

Compare the result of the Gauss–Lobatto quadrature with the result from NIntegrate:

Wolfram Language code: est1 - NIntegrate[fun[x], {x, a, b}]

Properties & Relations (5)

Use FunctionExpand to expand GegenbauerC into other functions:

Wolfram Language code: FunctionExpand[GegenbauerC[1 / 2, -1 / 2, x]]

Wolfram Language code: FunctionExpand[GegenbauerC[n, m, 1]]

GegenbauerC can be represented as a DifferenceRoot:

Wolfram Language code: DifferenceRootReduce[GegenbauerC[k, z, y], k]

Wolfram Language code: DifferenceRootReduce[GegenbauerC[1, 2, k], k]

General term in the series expansion of GegenbauerC:

Wolfram Language code: SeriesCoefficient[GegenbauerC[a, x], {x, 0, n}]

The generating function for GegenbauerC:

Wolfram Language code: GeneratingFunction[GegenbauerC[n, a, b], n, x]

Define an inner product on functions using Integrate:

Wolfram Language code: dot[f_, g_] := 2 / π Subsuperscript[∫, -1, 1]Conjugate[f]gSqrt[1 - x^2]ⅆx

Construct an orthonormal basis using Orthogonalize:

Wolfram Language code: Orthogonalize[{1, x, x ^ 2, x ^ 3, x ^ 4}, dot] // Expand

This inner product produces the GegenbauerC polynomials:

Wolfram Language code: Table[GegenbauerC[n, 1, x], {n, 0, 4}]

Possible Issues (1)

Cancellations in the polynomial form may lead to inaccurate numerical results:

Wolfram Language code: GegenbauerC[60, x] /. {x -> N[2 / 3, 17]}

Evaluate the function directly:

Wolfram Language code: GegenbauerC[60, N[2 / 3, 17] ]

Top

More Learning

Tech Support

Wolfram Solutions

Wolfram Solutions For Education

Get Started

Grow Your Skills

Work with Us

Educational Programs for Adults

Educational Programs for Youth

Read

GegenbauerC

Details

Examples

Basic Examples (7)

Scope (44)

Numerical Evaluation (6)

Specific Values (8)

Visualization (4)

Function Properties (14)

Differentiation (3)

Integration (3)

Series Expansions (2)

Function Identities and Simplifications (4)

Generalizations & Extensions (2)

Applications (3)

Properties & Relations (5)

Possible Issues (1)

Text

CMS

APA

BibTeX

BibLaTeX

GegenbauerC

Details

Examples

Basic Examples (7)

Scope (44)

Numerical Evaluation (6)

Specific Values (8)

Visualization (4)

Function Properties (14)

Differentiation (3)

Integration (3)

Series Expansions (2)

Function Identities and Simplifications (4)

Generalizations & Extensions (2)

Applications (3)

Properties & Relations (5)

Possible Issues (1)

See Also

Tech Notes

Related Guides

Related Links

History

Text

CMS

APA

BibTeX

BibLaTeX