Wolfram Language & System Documentation Center

JacobiP

JacobiP[n,a,b,x]

gives the Jacobi polynomial .

Details

Mathematical function, suitable for both symbolic and numerical manipulation.
Explicit polynomials are given when possible.
satisfies the differential equation .
The Jacobi polynomials are orthogonal with weight function .
For certain special arguments, JacobiP automatically evaluates to exact values.
JacobiP can be evaluated to arbitrary numerical precision.
JacobiP automatically threads over lists.
JacobiP[n,a,b,z] has a branch cut discontinuity in the complex z plane running from to .
JacobiP can be used with Interval and CenteredInterval objects. »

Examples

open all close all

Basic Examples (7)

Evaluate numerically:

Wolfram Language code: N[JacobiP[5, 1 / 2, 1, 3]]

Compute the 2 Jacobi polynomial:

Wolfram Language code: JacobiP[2, a, b, z]

Plot over a subset of the reals:

Wolfram Language code: Plot[JacobiP[10, 2, 2, x], {x, -1, 1}]

Plot over a subset of the complexes:

Wolfram Language code: ComplexPlot3D[JacobiP[10, 2, 2, z], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

Series expansion at the origin:

Wolfram Language code: Series[JacobiP[5, 2, 2, x], {x, 0, 5}]

Asymptotic expansion at Infinity:

Wolfram Language code: Series[JacobiP[5, 2, 2, x], {x, ∞, 3}]//FullSimplify

Asymptotic expansion at a singular point:

Wolfram Language code: Series[JacobiP[5, 2, 2, x], {x, -1, 3}]//FullSimplify

Scope (40)

Numerical Evaluation (6)

Evaluate numerically:

Wolfram Language code: N[JacobiP[3, 1 / 2, 1, 7]]

Wolfram Language code: JacobiP[2.3, 1 / 2, 1 / 8, 12]

Evaluate to high precision:

Wolfram Language code: N[JacobiP[2 / 3, 1 / 2, 9, 7], 50]//Chop

The precision of the output tracks the precision of the input:

Wolfram Language code: JacobiP[2, 2, 9, .33333333333333333333333333333]

Complex number input:

Wolfram Language code: JacobiP[2 + 3 I, 1.2, .8, 7]

Evaluate efficiently at high precision:

Wolfram Language code: JacobiP[2, 1 / 2, 5 / 9, 9`100]//Timing

Wolfram Language code: JacobiP[3, 1 / 7, 5 / 9, 17`100000];//Timing

Compute worst-case guaranteed intervals using Interval and CenteredInterval objects:

Wolfram Language code: JacobiP[1 / 2, 2 / 3, 3 / 4, Interval[{1.1, 1.2}]]

Wolfram Language code: JacobiP[1 / 2, 2 / 3, 3 / 4, CenteredInterval[2, 1 / 100]]

Or compute average-case statistical intervals using Around:

Wolfram Language code: JacobiP[3, 1, 2, Around[2, 0.01]]

Compute the elementwise values of an array:

Wolfram Language code: JacobiP[3, 1, 2, {{1, 2}, {3, 4}}]

Or compute the matrix JacobiP function using MatrixFunction:

Wolfram Language code: MatrixFunction[JacobiP[3, 1, 2, #]&, {{1, 2}, {3, 4}}]//Simplify

Specific Values (6)

Values of JacobiP at fixed points:

Wolfram Language code: Table[JacobiP[3, 1, 2, x ], {x, 1, 5}]

Values at zero:

Wolfram Language code: JacobiP[0, 0, 0, 0]

Find the first positive minimum of JacobiP[10,2,3,x]:

Wolfram Language code: xmin = x /. Solve[D[JacobiP[10, 2, 3, x ], x] == 0 && 0 < x < 5, x][[1]]

Wolfram Language code: Plot[JacobiP[10, 2, 3, x ], {x, -1, 1}, Epilog -> Style[Point[{xmin, JacobiP[10, 2, 3, xmin ]}], PointSize[Large], Red]]

Compute the associated JacobiP polynomial:

Wolfram Language code: JacobiP[3, 2, 1, x]

Compute the associated JacobiP polynomial for half-integer arguments:

Wolfram Language code: JacobiP[1 / 2, 3 / 2, 3 / 2, x]

Different JacobiP types give different symbolic forms:

Wolfram Language code: Table[JacobiP[n, 1, 2, x], {n, 0, 3}]

Visualization (4)

Plot the JacobiP function for various orders:

Wolfram Language code: Plot[{JacobiP[1, 1, 1, x], JacobiP[2, 1, 1, x], JacobiP[3, 1, 1, x], JacobiP[4, 1, 1, x]}, {x, -.7, .7}]

Plot the real part of :

Wolfram Language code: ComplexContourPlot[Re[JacobiP[5, 1, 1, z]], {z, -1 - I, 1 + I}, Contours -> 24]

Plot the imaginary part of :

Wolfram Language code: ComplexContourPlot[Im[JacobiP[5, 1, 1, z]], {z, -1 - I, 1 + I}, Contours -> 24]

Plot as real parts of two parameters vary:

Wolfram Language code: Plot3D[Re[JacobiP[n, 2, 1, z]], {n, 0, 5}, {z, -1, 1}]

Types 2 and 3 of JacobiP function have different branch cut structures:

Wolfram Language code: Plot3D[Im[JacobiP[2, 1, 1, x + I y]], {x, -1.5, 1.5}, {y, -0.5, 0.5}, Exclusions -> {{y == 0, Abs[x] > 1}}]

Wolfram Language code: Plot3D[Im[JacobiP[3, 1, 1, x + I y]], {x, -1.5, 1.5}, {y, -0.5, 0.5}, Exclusions -> {{y == 0, -1 < x < 1}}]

Function Properties (11)

Domain of JacobiP of integer orders:

Wolfram Language code: {FunctionDomain[JacobiP[1, 2, 2, z], z], FunctionDomain[JacobiP[2, 3, 4, z], z]}

Wolfram Language code: {FunctionDomain[JacobiP[1, 2, 2, z], z, Complexes], FunctionDomain[JacobiP[2, 3, 4, z], z, Complexes]}

Domain for noninteger orders:

Wolfram Language code: FunctionDomain[JacobiP[1 / 2, 1 / 2, 1 / 2, z], z]

Wolfram Language code: FunctionDomain[JacobiP[1 / 2, 1 / 2, 1 / 2, z], z, Complexes]

The range for JacobiP of integer orders:

Wolfram Language code: {FunctionRange[JacobiP[1, 2, 2, x], x, y], FunctionRange[JacobiP[2, 3, 4, x], x, y]}

The range for complex values is the whole plane:

Wolfram Language code: {FunctionRange[JacobiP[1, 2, 2, z], z, y, Complexes], FunctionRange[JacobiP[2, 3, 4, z], z, y, Complexes]}

JacobiP has the mirror property for integer , and :

Wolfram Language code:

{JacobiP[1, 2, 2, Conjugate[z]] == Conjugate[JacobiP[1, 2, 2, z]], JacobiP[2, 3, 3, Conjugate[z]] == Conjugate[JacobiP[2, 3, 3, z]]}

Jacobi polynomials are analytic functions:

Wolfram Language code: FunctionAnalytic[JacobiP[10, 2, 2, x], x]

However, is not an analytic function of for noninteger , and :

Wolfram Language code: FunctionAnalytic[JacobiP[1 / 2, 3 / 2, 5 / 2, x], x]

Nor is it meromorphic:

Wolfram Language code: FunctionMeromorphic[JacobiP[1 / 2, 3 / 2, 5 / 2, x], x]

is neither non-decreasing nor non-increasing:

Wolfram Language code: FunctionMonotonicity[JacobiP[10, 2, 2, x], x]

is increasing on its real domain:

Wolfram Language code: FunctionMonotonicity[{JacobiP[1 / 2, 1 / 2, 1 / 2, x], x > -1}, x, StrictInequalities -> True]

is not injective:

Wolfram Language code: FunctionInjective[JacobiP[10, 2, 2, x], x]

is:

Wolfram Language code: FunctionInjective[JacobiP[1 / 2, 1 / 2, 1 / 2, x], x]

Wolfram Language code: Plot[{JacobiP[10, 2, 2, x], JacobiP[1 / 2, 1 / 2, 1 / 2, x], 1}, {x, -1, 1}, PlotRange -> 5]

is not surjective:

Wolfram Language code: FunctionSurjective[JacobiP[10, 2, 2, x], x]

is:

Wolfram Language code: FunctionSurjective[JacobiP[1 / 2, 1 / 2, 1 / 2, x], x]

Wolfram Language code: Plot[{JacobiP[10, 2, 2, x], JacobiP[1 / 2, 1 / 2, 1 / 2, x], -5}, {x, -1, 1}, PlotRange -> 10]

is neither non-negative nor non-positive:

Wolfram Language code: FunctionSign[JacobiP[10, 2, 2, x], x]

has no singularities or discontinuities for integer , and :

Wolfram Language code: FunctionSingularities[JacobiP[10, 2, 2, x], x]

Wolfram Language code: FunctionDiscontinuities[JacobiP[10, 2, 2, x], x]

is neither convex nor concave:

Wolfram Language code: FunctionConvexity[JacobiP[10, 2, 2, x], x]

is concave on its real domain:

Wolfram Language code: FunctionConvexity[{JacobiP[1 / 2, 1 / 2, 1 / 2, x], x > -1}, x]

TraditionalForm formatting:

Wolfram Language code: JacobiP[n, α, β, x]//TraditionalForm

Differentiation (3)

First derivative with respect to x:

Wolfram Language code: D[JacobiP[n, a, b, x], x]

Higher derivatives with respect to x:

Wolfram Language code: Table[D[JacobiP[n, a, b, x], {x, k}], {k, 1, 3}]//FullSimplify

Plot the higher derivatives with respect to x:

Wolfram Language code:

Plot[Evaluate[% /. {n -> 5, a -> 1 / 2, b -> -1 / 3}], {x, -1 / 2, 1 / 2}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative"}]

Formula for the derivative with respect to x:

Wolfram Language code: D[JacobiP[n, a, b, x], {x, k}]// FullSimplify

Integration (3)

Compute the indefinite integral using Integrate:

Wolfram Language code: Integrate[JacobiP[n, a, b, x], x]

Verify the anti-derivative:

Wolfram Language code: FullSimplify[D[%, x]]

Definite integral:

Wolfram Language code: Integrate[JacobiP[n, a, b, x], {x, 0, 4}]

More integrals:

Wolfram Language code: Integrate[x JacobiP[n, a, b, x], x]//FullSimplify

Wolfram Language code: Integrate[x JacobiP[n, a, b, x^2], {x, 0, 3}]//FullSimplify

Series Expansions (4)

Find the Taylor expansion using Series:

Wolfram Language code: Series[JacobiP[n, a, b, x], {x, 0, 3}]

Plots of the first three approximations around :

Wolfram Language code:

terms = Normal@Table[Series[JacobiP[10, 3, 3, x], {x, 0, m}], {m, 1, 5, 2}];
Plot[{JacobiP[10, 3, 3, x], terms}, {x, -1, 1}, PlotRange -> {-20, 20}]

Find the series expansion at Infinity:

Wolfram Language code: Series[JacobiP[n, a, b, x], {x, Infinity, 1}]

Find series expansion for an arbitrary symbolic direction :

Wolfram Language code: Series[JacobiP[n, a, b, x], {x, DirectedInfinity[z], 1}, Assumptions -> x > 0]//Normal// FullSimplify

Taylor expansion at a generic point:

Wolfram Language code: Series[JacobiP[n, a, b, x], {x, x0, 2}]// FullSimplify

Function Identities and Simplifications (3)

JacobiP is defined through the identity:

Wolfram Language code: JacobiP[n, a, b, x] == (Pochhammer[a + 1, n]/n!) Hypergeometric2F1[-n, 1 + a + b + n, a + 1, (1/2)(1 - x)]//FullSimplify

Normalization of JacobiP:

Wolfram Language code: JacobiP[n, a, b, 1] == Binomial[n + a, a]//FullSimplify

Recurrence relations:

Wolfram Language code: JacobiP[n, a, b - 1, x] - JacobiP[n, a - 1, b, x] == JacobiP[n - 1, a, b, x]//FullSimplify

Wolfram Language code: JacobiP[n, a, b, x] - JacobiP[n, a - 1, b, x] == (x + 1/2)JacobiP[n - 1, a, b + 1, x]//FullSimplify

Applications (4)

Expected value of the number of real eigenvalues of a complex matrix:

Wolfram Language code: ListLinePlot[Table[(1 - (-1) ^ n) / 2 + Sqrt[2]JacobiP[n - 2, 1 - n, 3 / 2, 3], {n, 100}]]

Solve a Jacobi differential equation:

Wolfram Language code:

With[{n = 1}, 
	(1 - x^2)Subscript[∂, {x, 2}]JacobiP[n, a, b, x] + (b - a - x(a + b + 2))Subscript[∂, x]JacobiP[n, a, b, x] + n(n + a + b + 1) JacobiP[n, a, b, x]]

Wolfram Language code: Expand[%]

Solution of the Schrödinger equation with a Pöschl–Teller potential:

Wolfram Language code: ψ[n_, a_, b_, x_] := Sin[x]^a + (1/2) Cos[x]^b + (1/2) JacobiP[n, a, b, Cos[2 x]]

Calculate the energy eigenvalue from the differential equation:

Wolfram Language code:

Table[-D[ψ[n, a, b, x], x, x] / ψ[n, a, b, x] + (a^2 - (1/4)/Sin[x]^2) + (b^2 - (1/4)/Cos[x]^2) //FullSimplify, {n, 0, 5}]

In an n-point Gauss–Radau quadrature rule, the value of one of the two extreme nodes is fixed, and the other n-1 nodes are computed from the roots of a certain Jacobi polynomial. Letting the leftmost node be the fixed node, compute the nodes and weights of an n-point Gauss–Radau quadrature rule:

Wolfram Language code:

n = 11;
tmp = Sort[x /. NSolve[JacobiP[n - 1, 0, 1, x], x], LessEqual];
radauNodes = Prepend[tmp, N[-1]]

Wolfram Language code:

w1 = x |-> ((1 - x)(2n - 1)^2/(n(n - 1)JacobiP[n - 2, 0, 1, x])^2);
radauWeights = Prepend[w1[tmp], N[(2/n^2)]]

Use the n-point Gauss–Radau quadrature rule to numerically evaluate an integral:

Wolfram Language code: fun[x_] := (1/1 / 100 + (x - 3 / 10)^2) + (1/1 / 25 + (x - 9 / 10)^2) - 6

Wolfram Language code:

a = 1 / 2;b = 1;
est1 = ((b - a/2)radauWeights).Map[fun, Rescale[radauNodes, {-1, 1}, {a, b}]]

Compare the result of the Gauss–Radau quadrature with the result from NIntegrate:

Wolfram Language code: est1 - NIntegrate[fun[x], {x, a, b}]

Properties & Relations (2)

Use FunctionExpand to expand into other functions:

Wolfram Language code: FunctionExpand[JacobiP[n, a, -n, z]]

The generating function for JacobiP:

Wolfram Language code: GeneratingFunction[JacobiP[n, a, b, c], n, x]

Possible Issues (1)

Cancellations in the polynomial form may lead to inaccurate numerical results:

Wolfram Language code: JacobiP[60, 1, 2, x] /. {x -> N[2 / 3, 16]}

Evaluate the function directly:

Wolfram Language code: JacobiP[60, 1, 2, N[2 / 3, 16] ]

Top

More Learning

Tech Support

Wolfram Solutions

Wolfram Solutions For Education

Get Started

Grow Your Skills

Work with Us

Educational Programs for Adults

Educational Programs for Youth

Read

JacobiP

Details

Examples

Basic Examples (7)

Scope (40)

Numerical Evaluation (6)

Specific Values (6)

Visualization (4)

Function Properties (11)

Differentiation (3)

Integration (3)

Series Expansions (4)

Function Identities and Simplifications (3)

Applications (4)

Properties & Relations (2)

Possible Issues (1)

Text

CMS

APA

BibTeX

BibLaTeX

JacobiP

Details

Examples

Basic Examples (7)

Scope (40)

Numerical Evaluation (6)

Specific Values (6)

Visualization (4)

Function Properties (11)

Differentiation (3)

Integration (3)

Series Expansions (4)

Function Identities and Simplifications (3)

Applications (4)

Properties & Relations (2)

Possible Issues (1)

See Also

Tech Notes

Related Guides

Related Links

History

Text

CMS

APA

BibTeX

BibLaTeX