WOLFRAM

Wolfram Language & System Documentation Center

ChebyshevT[n,x]

gives the Chebyshev polynomial of the first kind TemplateBox[{n, x}, ChebyshevT].

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Numerical Evaluation  
Specific Values  
Visualization  
Show More Show More
Function Properties  
Differentiation  
Integration  
Series Expansions  
Function Identities and Simplifications  
Generalizations & Extensions  
Applications  
Properties & Relations  
Possible Issues  
Neat Examples  
See Also
Tech Notes
Related Guides
Related Links
History
Cite this Page

ChebyshevT

ChebyshevT[n,x]

gives the Chebyshev polynomial of the first kind TemplateBox[{n, x}, ChebyshevT].

Details

  • Mathematical function, suitable for both symbolic and numerical manipulation.
  • Explicit polynomials are given for integer n.
  • TemplateBox[{n, {cos, , theta}}, ChebyshevT]=cos(ntheta).
  • For certain special arguments, ChebyshevT automatically evaluates to exact values.
  • ChebyshevT can be evaluated to arbitrary numerical precision.
  • ChebyshevT automatically threads over lists.
  • ChebyshevT[n,z] has a branch cut discontinuity in the complex z plane running from to if n is not an integer.
  • ChebyshevT can be used with Interval and CenteredInterval objects. »

Examples

open all close all

Basic Examples  (7)

Evaluate numerically:

Wolfram Language code: ChebyshevT[2, 3]

Compute the 10^(th) Chebyshev polynomial:

Wolfram Language code: ChebyshevT[10, x]

Plot over a subset of the reals:

Wolfram Language code: Plot[ChebyshevT[10, x], {x, -1, 1}]

Plot over a subset of the complexes:

Wolfram Language code: ComplexPlot3D[ChebyshevT[5, z], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

Series expansion at the origin:

Wolfram Language code: Series[ChebyshevT[5, x], {x, 0, 5}]

Asymptotic expansion at Infinity:

Wolfram Language code: Series[ChebyshevT[1 / 3, x], {x, ∞, 3}]//Normal//FullSimplify

Asymptotic expansion at a singular point:

Wolfram Language code: Series[ChebyshevT[1 / 3, x], {x, -1, 2}]//FullSimplify

Scope  (44)

Numerical Evaluation  (6)

Evaluate numerically:

Wolfram Language code: ChebyshevT[2, 5]
Wolfram Language code: ChebyshevT[12, 2.5]

Evaluate to high precision:

Wolfram Language code: N[ChebyshevT[1 / 7, 1 / 3], 50]

The precision of the output tracks the precision of the input:

Wolfram Language code: ChebyshevT[0.3000000000000000000, 0]

Complex number input:

Wolfram Language code: N[ChebyshevT[98 + I, I]]

Evaluate efficiently at high precision:

Wolfram Language code: ChebyshevT[-1.5, -2.4`100]//Timing
Wolfram Language code: ChebyshevT[84, 63`10000000];//Timing

Compute worst-case guaranteed intervals using Interval and CenteredInterval objects:

Wolfram Language code: ChebyshevT[2, Interval[{1.9, 2.1}]]
Wolfram Language code: ChebyshevT[2, CenteredInterval[2, 1 / 100]]

Or compute average-case statistical intervals using Around:

Wolfram Language code: ChebyshevT[2, Around[2, 0.01]]

Compute the elementwise values of an array:

Wolfram Language code: ChebyshevT[2, {{1, 2}, {3, 4}}]

Or compute the matrix ChebyshevT function using MatrixFunction:

Wolfram Language code: MatrixFunction[ChebyshevT[2, #]&, {{1, 2}, {3, 4}}]

Specific Values  (7)

Values of ChebyshevT at fixed points:

Wolfram Language code: Table[ChebyshevT[n, Pi / 2], {n, 0, 3}]

ChebyshevT for symbolic n:

Wolfram Language code: ChebyshevT[n, 0]

Values at zero:

Wolfram Language code: ChebyshevT[0, 0]

Values at infinity:

Wolfram Language code: ChebyshevT[0, Infinity]
Wolfram Language code: ChebyshevT[Infinity, 0][[1, 1]]

Find the first positive maximum of ChebyshevT[5,x]:

Wolfram Language code: xmax = x /. Solve[D[ChebyshevT[5, x], x] == 0 && 0 < x < π, x][[1]]
Wolfram Language code: Plot[ChebyshevT[5, x], {x, -1, 1}, Epilog -> Style[Point[{xmax, ChebyshevT[5, xmax]}], PointSize[Large], Red]]

Compute the associated ChebyshevT[7,x] polynomial:

Wolfram Language code: ChebyshevT[7, x]

Compute the associated ChebyshevT[1/2,x] polynomial for half-integer n:

Wolfram Language code: ChebyshevT[1 / 2, x]

Visualization  (3)

Plot the ChebyshevT function for various orders:

Wolfram Language code: Plot[{ChebyshevT[1, x], ChebyshevT[2, x], ChebyshevT[3, x], ChebyshevT[4, x]}, {x, -1, 1}]

Plot the real part of TemplateBox[{3, z}, ChebyshevT]:

Wolfram Language code: ComplexContourPlot[Re[ChebyshevT[3, z]], {z, -3 - 3 I, 3 + 3 I}, IconizedObject[«PlotOptions»]]

Plot the imaginary part of TemplateBox[{3, z}, ChebyshevT]:

Wolfram Language code: ComplexContourPlot[Im[ChebyshevT[3, z]], {z, -3 - 3 I, 3 + 3 I}, IconizedObject[«PlotOptions»]]

Plot the Chebyshev polynomial as a function of two variables:

Wolfram Language code: Plot3D[ChebyshevT[n, z], {n, 0, 5}, {z, -1, 1}]

Function Properties  (14)

ChebyshevT is defined for all real values from the interval [-1,∞]:

Wolfram Language code: FunctionDomain[ChebyshevT[n, x], x]

ChebyshevT is defined for all complex values:

Wolfram Language code: FunctionDomain[ChebyshevT[n, z], z, Complexes]

TemplateBox[{1, x}, ChebyshevT] achieves all real and complex values:

Wolfram Language code: FunctionRange[ChebyshevT[1, x], x, y]
Wolfram Language code: FunctionRange[ChebyshevT[1, z], z, y, Complexes]

Real range of TemplateBox[{2, x}, ChebyshevT]:

Wolfram Language code: FunctionRange[ChebyshevT[2, x], x, y]

It achieves all complex values:

Wolfram Language code: FunctionRange[ChebyshevT[2, z], z, y, Complexes]

Chebyshev polynomial of an odd order is odd:

Wolfram Language code: ChebyshevT[1, -x] == -ChebyshevT[1, x]

Chebyshev polynomial of an even order is even:

Wolfram Language code: ChebyshevT[2, -x] == ChebyshevT[2, x]

ChebyshevT threads elementwise over lists:

Wolfram Language code: ChebyshevT[{1, 2, 3}, x]

Chebyshev polynomials are analytic:

Wolfram Language code: FunctionAnalytic[ChebyshevT[n, x], x, Assumptions -> n∈ℤ]

In general, ChebyshevT is neither analytic nor meromorphic:

Wolfram Language code: FunctionAnalytic[ChebyshevT[1 / 3, x], x, ℂ]
Wolfram Language code: FunctionMeromorphic[ChebyshevT[1 / 3, x], x]

TemplateBox[{2, x}, ChebyshevT] is neither non-decreasing nor non-increasing:

Wolfram Language code: FunctionMonotonicity[ChebyshevT[2, x], x]

TemplateBox[{2, x}, ChebyshevT] is not injective:

Wolfram Language code: FunctionInjective[ChebyshevT[2, x], x]

TemplateBox[{1, x}, ChebyshevT] is:

Wolfram Language code: FunctionInjective[ChebyshevT[1, x], x]
Wolfram Language code: Plot[{ChebyshevT[1, x], ChebyshevT[2, x], 2}, {x, -2, 2}]

TemplateBox[{2, x}, ChebyshevT] is not surjective:

Wolfram Language code: FunctionSurjective[ChebyshevT[2, x], x]

TemplateBox[{1, x}, ChebyshevT] is:

Wolfram Language code: FunctionSurjective[ChebyshevT[1, x], x]
Wolfram Language code: Plot[{ChebyshevT[1, x], ChebyshevT[2, x], 2}, {x, -2, 2}]

TemplateBox[{2, x}, ChebyshevT] is neither non-negative nor non-positive:

Wolfram Language code: FunctionSign[ChebyshevT[2, x], x]

TemplateBox[{n, x}, ChebyshevT] has singularities and discontinuities for when is not an integer:

Wolfram Language code: FunctionSingularities[ChebyshevT[n, x], x]
Wolfram Language code: FunctionDiscontinuities[ChebyshevT[n, x], x]

TemplateBox[{2, x}, ChebyshevT] is convex:

Wolfram Language code: FunctionConvexity[ChebyshevT[2, x], x]

TraditionalForm formatting:

Wolfram Language code: ChebyshevT[n, x]//TraditionalForm

Differentiation  (3)

First derivative with respect to x:

Wolfram Language code: D[ChebyshevT[n, x] , x]

Higher derivatives with respect to x:

Wolfram Language code: Table[D[ChebyshevT[n, x], {x, k}], {k, 1, 3}]//Simplify

Plot the higher derivatives with respect to x when n=5:

Wolfram Language code: Plot[Evaluate[% /. n -> 5], {x, -1, 1}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative"}]

Formula for the ^(th) derivative with respect to x:

Wolfram Language code: D[ChebyshevT[n, x], {x, k}]// FullSimplify

Integration  (4)

Compute the indefinite integral using Integrate:

Wolfram Language code: Integrate[ChebyshevT[n, x], x]

Verify the anti-derivative:

Wolfram Language code: FullSimplify[D[%, x]]

Definite integral:

Wolfram Language code: Integrate[ChebyshevT[n, x], {x, 0, 4}]

Definite integral of ChebyshevT over a period for odd integers is 0:

Wolfram Language code: Integrate[ChebyshevT[2n - 1, x], {x, -5, 5}]
Wolfram Language code: Table[%, {n, 3, 11, 2}]//FullSimplify

More integrals:

Wolfram Language code: Integrate[ChebyshevT[3, x]ChebyshevT[5, x], x]//FullSimplify
Wolfram Language code: Integrate[Exp[x] ChebyshevT[5, x], {x, 0, 5}]//FullSimplify

Series Expansions  (3)

Find the Taylor expansion using Series:

Wolfram Language code: Series[ChebyshevT[n, x], {x, 0, 3}]

Plots of the first three approximations around :

Wolfram Language code: terms = Normal@Table[Series[ChebyshevT[10, x], {x, 0, m}], {m, 1, 5, 2}]; Plot[{ChebyshevT[10, x], terms}, {x, -1, 1}, PlotRange -> {-3, 3}]

General term in the series expansion using SeriesCoefficient:

Wolfram Language code: SeriesCoefficient[ChebyshevT[n, x], {x, 0, n}]

Taylor expansion at a generic point:

Wolfram Language code: Series[ChebyshevT[n, x], {x, x0, 2}]

Function Identities and Simplifications  (4)

ChebyshevT is defined through the identity:

Wolfram Language code: ChebyshevT[n, Cos[θ]] == Cos[n θ]//FullSimplify

The ordinary generating function of ChebyshevT:

Wolfram Language code: Sum[ChebyshevT[n, x]t^n, {n, 0, Infinity}]

The exponential generating function of ChebyshevT:

Wolfram Language code: Sum[ChebyshevT[n, x]t^n / n!, {n, 0, Infinity}]

Recurrence relations:

Wolfram Language code: ChebyshevT[n, z] == 2 z ChebyshevT[n + 1, z] - ChebyshevT[n + 2, z]//FullSimplify
Wolfram Language code: ChebyshevT[n - 1, z] + ChebyshevT[n + 1, z] == 2 z ChebyshevT[n, z]//FullSimplify

Generalizations & Extensions  (2)

ChebyshevT can be applied to power series:

Wolfram Language code: ChebyshevT[1 / 3, Sin[x] + O[x] ^ 3]

ChebyshevT can be applied to Interval:

Wolfram Language code: ChebyshevT[10, Interval[{-1, 1}]]

Applications  (4)

Plot the first 10 Chebyshev polynomials:

Wolfram Language code: Plot[Evaluate[Table[ChebyshevT[n, x], {n, 0, 5}]], {x, -1, 1}]

Find a minimax approximation to the function Clip[4 x]:

Wolfram Language code: c = Table[(2/π)Subsuperscript[∫, -1, 1]Clip[4 x](ChebyshevT[n, x]/Sqrt[1 - x^2])ⅆx, {n, 0, 5}]
Wolfram Language code: Plot[ {Clip[4 x], -First[c] / 2 + Evaluate[c . Table[ChebyshevT[n - 1, x], {n, Length[c]}]]}, {x, -1, 1}]

Get an expansion for a function in the Chebyshev polynomials:

Wolfram Language code: f[x_] := 1 / (1 + (5x) ^ 2);

The values of the function at the Chebyshev nodes:

Wolfram Language code: n = 47; cnodes = N[Cos[Pi Range[0, n] / n]]; fc = Map[f, cnodes]; pf = ListPlot[Transpose[{cnodes, fc}], PlotRange -> All]

Find the Chebyshev coefficients:

Wolfram Language code: cc = FourierDCT[fc, 1] * Sqrt[2 / n]; cc[[{1, -1}]] /= 2;

Show the error:

Wolfram Language code: Plot[f[x] - Sum[ChebyshevT[i - 1, x] * cc[[i]], {i, Length[cc]}], {x, -1, 1}, PlotRange -> All]

Solve a differential equation with the ChebyshevT function as the inhomogeneous part:

Wolfram Language code: DSolve[y''[x] + ChebyshevT[n, x] == 0, y[x], x]

Properties & Relations  (7)

Use FullSimplify with ChebyshevT:

Wolfram Language code: FullSimplify[ChebyshevT[10, Cos[x]]]

Compare an expanded trigonometric expression with ChebyshevT:

Wolfram Language code: FunctionExpand[Cos[10ArcCos[x]]]//Expand
Wolfram Language code: ChebyshevT[10, x]

Derivative of ChebyshevT is expressed in terms of ChebyshevU:

Wolfram Language code: D[ChebyshevT[n, x], x]

ChebyshevT can be represented as a DifferenceRoot:

Wolfram Language code: DifferenceRootReduce[ChebyshevT[k, z], k]

General term in the series expansion of ChebyshevT:

Wolfram Language code: SeriesCoefficient[ChebyshevT[a, x], {x, 0, n}]

The generating function for ChebyshevT:

Wolfram Language code: GeneratingFunction[ChebyshevT[n, k], n, x]

The exponential generating function for ChebyshevT:

Wolfram Language code: ExponentialGeneratingFunction[ChebyshevT[n, k], n, x]

Possible Issues  (1)

Cancellations in the polynomial form may lead to inaccurate numerical results:

Wolfram Language code: ChebyshevT[60, x] /. x -> N[2 / 3, 16]

Evaluate the function directly:

Wolfram Language code: ChebyshevT[60, N[2 / 3, 16] ]

Neat Examples  (1)

Plot the first few Banchoff–Chmutov surfaces:

Wolfram Language code: Table[ContourPlot3D[ChebyshevT[2k, x] + ChebyshevT[2k, y] + ChebyshevT[2k, z] == 0, {x, -5 / 4, 5 / 4}, {y, -5 / 4, 5 / 4}, {z, -5 / 4, 5 / 4}, Axes -> None, Boxed -> False], {k, 4}]//GraphicsRow
Wolfram Research (1988), ChebyshevT, Wolfram Language function, https://reference.wolfram.com/language/ref/ChebyshevT.html (updated 2022).

Text

Wolfram Research (1988), ChebyshevT, Wolfram Language function, https://reference.wolfram.com/language/ref/ChebyshevT.html (updated 2022).

CMS

Wolfram Language. 1988. "ChebyshevT." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2022. https://reference.wolfram.com/language/ref/ChebyshevT.html.

APA

Wolfram Language. (1988). ChebyshevT. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ChebyshevT.html

BibTeX

@misc{reference.wolfram_2026_chebyshevt, author="Wolfram Research", title="{ChebyshevT}", year="2022", howpublished="\url{https://reference.wolfram.com/language/ref/ChebyshevT.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_chebyshevt, organization={Wolfram Research}, title={ChebyshevT}, year={2022}, url={https://reference.wolfram.com/language/ref/ChebyshevT.html}, note=[Accessed: 13-June-2026]}