![TemplateBox[{n, x}, ChebyshevU]](Files/ChebyshevU.en/36.png "TemplateBox[{n, x}, ChebyshevU]"){kind=small}
ChebyshevU
ChebyshevU[n,x]
gives the Chebyshev polynomial of the second kind ![TemplateBox[{n, x}, ChebyshevU]](Files/ChebyshevU.en/1.png "TemplateBox[{n, x}, ChebyshevU]"){kind=small}
.
Details
- Mathematical function, suitable for both symbolic and numerical manipulation.
- Explicit polynomials are given for integer n.
![TemplateBox[{n, {cos, (, theta, )}}, ChebyshevU]=sin[(n+1)theta]/sin theta](Files/ChebyshevU.en/2.png "TemplateBox[{n, {cos, (, theta, )}}, ChebyshevU]=sin[(n+1)theta]/sin theta")
. - For certain special arguments, ChebyshevU automatically evaluates to exact values.
- ChebyshevU can be evaluated to arbitrary numerical precision.
- ChebyshevU automatically threads over lists.
- ChebyshevU[n,z] has a branch cut discontinuity in the complex z plane running from
to 
for noninteger n. - ChebyshevU can be used with Interval and CenteredInterval objects. »
Examples
open all close allBasic Examples (7)
ChebyshevU[2, 3]Compute the 
ChebyshevU polynomial:
ChebyshevU[10, x]Plot over a subset of the reals:
Plot[ChebyshevU[10, x], {x, -1, 1}]Plot over a subset of the complexes:
ComplexPlot3D[ChebyshevU[5, z], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]Series expansion at the origin:
Series[ChebyshevU[5, x], {x, 0, 5}]Asymptotic expansion at Infinity:
Series[ChebyshevU[1 / 3, x], {x, ∞, 3}]//Normal//FullSimplifyAsymptotic expansion at a singular point:
Series[ChebyshevU[1 / 3, x], {x, -1, 2}]//FullSimplifyScope (44)
Numerical Evaluation (6)
ChebyshevU[2, 5]ChebyshevU[12, 2.5]N[ChebyshevU[1 / 7, 1 / 3], 50]The precision of the output tracks the precision of the input:
ChebyshevU[0.3000000000000000000, 0]N[ChebyshevU[98 + I, I]]Evaluate efficiently at high precision:
ChebyshevU[-1.5, -2.4`100]//TimingChebyshevU[84, 63`10000000];//TimingCompute worst-case guaranteed intervals using Interval and CenteredInterval objects:
ChebyshevU[2, Interval[{1.9, 2.1}]]ChebyshevU[2, CenteredInterval[2, 1 / 100]]Or compute average-case statistical intervals using Around:
ChebyshevU[2, Around[2, 0.01]]Compute the elementwise values of an array:
ChebyshevU[2, {{1, 2}, {3, 4}}]Or compute the matrix ChebyshevU function using MatrixFunction:
MatrixFunction[ChebyshevU[2, #]&, {{1, 2}, {3, 4}}]Specific Values (7)
Values of ChebyshevU at fixed points:
Table[ChebyshevU[n, Pi / 2], {n, 0, 3}]ChebyshevU for symbolic n:
ChebyshevU[n, 0]ChebyshevU[0, 0]ChebyshevU[0, Infinity]ChebyshevU[Infinity, 0][[1, 1]]Find the first positive maximum of ChebyshevU[5,x]:
xmax = x /. Solve[D[ChebyshevU[5, x], x] == 0 && 0 < x < π, x][[1]]Plot[ChebyshevU[5, x], {x, -1, 1}, Epilog -> Style[Point[{xmax, ChebyshevT[5, xmax]}], PointSize[Large], Red]]Compute the associated ChebyshevU[7,x] polynomial:
ChebyshevU[7, x]Compute the associated ChebyshevU[1/2,x] polynomial for half-integer n:
ChebyshevU[1 / 2, x]Visualization (3)
Plot the ChebyshevU function for various orders:
Plot[{ChebyshevU[1, x], ChebyshevU[2, x], ChebyshevU[3, x], ChebyshevU[4, x]}, {x, -1, 1}]![TemplateBox[{3, z}, ChebyshevU]](Files/ChebyshevU.en/6.png "TemplateBox[{3, z}, ChebyshevU]"){kind=small}
ComplexContourPlot[Re[ChebyshevU[3, z]], {z, -3 - 3 I, 3 + 3 I}, IconizedObject[«PlotOptions»]]![TemplateBox[{3, z}, ChebyshevU]](Files/ChebyshevU.en/7.png "TemplateBox[{3, z}, ChebyshevU]"){kind=small}
ComplexContourPlot[Im[ChebyshevU[3, z]], {z, -3 - 3 I, 3 + 3 I}, IconizedObject[«PlotOptions»]]Plot the Chebyshev polynomial as a function of two variables:
Plot3D[ChebyshevU[n, z], {n, 0, 5}, {z, -1, 1}]Function Properties (14)
ChebyshevU is defined for all real values from the interval [-1,∞]:
FunctionDomain[ChebyshevU[n, x], x]ChebyshevU is defined for all complex values besides 
:
FunctionDomain[ChebyshevU[n, z], z, Complexes]![TemplateBox[{1, x}, ChebyshevU]](Files/ChebyshevU.en/9.png "TemplateBox[{1, x}, ChebyshevU]"){kind=small}
achieves all real and complex values:
FunctionRange[ChebyshevU[1, x], x, y]FunctionRange[ChebyshevU[1, z], z, y, Complexes]![TemplateBox[{2, x}, ChebyshevU]](Files/ChebyshevU.en/10.png "TemplateBox[{2, x}, ChebyshevU]"){kind=small}
FunctionRange[ChebyshevU[2, x], x, y]It achieves all complex values:
FunctionRange[ChebyshevU[2, z], z, y, Complexes]Chebyshev polynomial of an odd order is odd:
ChebyshevU[1, -x] == -ChebyshevU[1, x]Chebyshev polynomial of an even order is even:
ChebyshevU[2, -x] == ChebyshevU[2, x]ChebyshevU threads elementwise over lists:
ChebyshevU[{1, 2, 3}, x]Chebyshev polynomials are analytic:
FunctionAnalytic[ChebyshevU[n, x], x, Assumptions -> n∈ℤ]In general, ChebyshevU is neither analytic nor meromorphic:
FunctionAnalytic[ChebyshevU[1 / 3, x], x, ℂ]FunctionMeromorphic[ChebyshevU[1 / 3, x], x]![TemplateBox[{2, x}, ChebyshevU]](Files/ChebyshevU.en/11.png "TemplateBox[{2, x}, ChebyshevU]"){kind=small}
is neither non-decreasing nor non-increasing:
FunctionMonotonicity[ChebyshevU[2, x], x]![TemplateBox[{2, x}, ChebyshevU]](Files/ChebyshevU.en/12.png "TemplateBox[{2, x}, ChebyshevU]"){kind=small}
FunctionInjective[ChebyshevU[2, x], x]![TemplateBox[{1, x}, ChebyshevU]](Files/ChebyshevU.en/13.png "TemplateBox[{1, x}, ChebyshevU]"){kind=small}
FunctionInjective[ChebyshevU[1, x], x]Plot[{ChebyshevU[1, x], ChebyshevU[2, x], 2}, {x, -1, 1}]![TemplateBox[{2, x}, ChebyshevU]](Files/ChebyshevU.en/14.png "TemplateBox[{2, x}, ChebyshevU]"){kind=small}
FunctionSurjective[ChebyshevU[2, x], x]![TemplateBox[{1, x}, ChebyshevU]](Files/ChebyshevU.en/15.png "TemplateBox[{1, x}, ChebyshevU]"){kind=small}
FunctionSurjective[ChebyshevU[1, x], x]Plot[{ChebyshevU[1, x], ChebyshevU[2, x], -2}, {x, -1, 1}]![TemplateBox[{2, x}, ChebyshevU]](Files/ChebyshevU.en/16.png "TemplateBox[{2, x}, ChebyshevU]"){kind=small}
is neither non-negative nor non-positive:
FunctionSign[ChebyshevU[2, x], x]![TemplateBox[{n, x}, ChebyshevU]](Files/ChebyshevU.en/17.png "TemplateBox[{n, x}, ChebyshevU]"){kind=small}
has singularities and discontinuities for 
when 
is not an integer:
FunctionSingularities[ChebyshevU[n, x], x]FunctionDiscontinuities[ChebyshevU[n, x], x]![TemplateBox[{2, x}, ChebyshevU]](Files/ChebyshevU.en/20.png "TemplateBox[{2, x}, ChebyshevU]"){kind=small}
FunctionConvexity[ChebyshevU[2, x], x]TraditionalForm formatting:
ChebyshevU[n, x]//TraditionalFormDifferentiation (3)
First derivative with respect to x:
D[ChebyshevU[n, x] , x]Higher derivatives with respect to x:
Table[D[ChebyshevU[n, x], {x, k}], {k, 1, 3}]//SimplifyPlot the higher derivatives with respect to x when n=5:
Plot[Evaluate[% /. n -> 5], {x, -10, 10}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative"}]Formula for the 
derivative with respect to x:
D[ChebyshevU[n, x], {x, k}]// FullSimplifyIntegration (4)
Compute the indefinite integral using Integrate:
Integrate[ChebyshevU[n, x], x]FullSimplify[D[%, x]]Integrate[ChebyshevU[n, x], {x, 0, 4}]Definite integral of ChebyshevU over a period for odd integers is 0:
Integrate[ChebyshevU[2n - 1, x], {x, -5, 5}]Table[%, {n, 3, 11, 2}]//FullSimplifyIntegrate[ChebyshevU[3, x]ChebyshevT[5, x], x]//FullSimplifyIntegrate[Exp[x] ChebyshevU[5, x], {x, 0, 5}]//FullSimplifySeries Expansions (3)
Find the Taylor expansion using Series:
Series[ChebyshevU[n, x], {x, 0, 3}]Plots of the first three approximations around 
:
terms = Normal@Table[Series[ChebyshevU[10, x], {x, 0, m}], {m, 1, 5, 2}];
Plot[{ChebyshevU[10, x], terms}, {x, -1, 1}, PlotRange -> {-3, 3}]General term in the series expansion using SeriesCoefficient:
SeriesCoefficient[ChebyshevU[n, x], {x, 0, n}]Taylor expansion at a generic point:
Series[ChebyshevU[n, x], {x, x0, 2}]Function Identities and Simplifications (4)
ChebyshevU is defined through the following trigonometric identity:
ChebyshevU[n, Cos[θ]] == Sin[(n + 1) θ] / Sin[θ]//FullSimplifyThe ordinary generating function of ChebyshevU:
Sum[ChebyshevU[n, x]t^n, {n, 0, Infinity}]The exponential generating function of ChebyshevU:
Sum[ChebyshevU[n, x]t^n / n!, {n, 0, Infinity}]ChebyshevU[n, z] == 2 z ChebyshevU[n + 1, z] - ChebyshevU[n + 2, z]//FullSimplifyChebyshevU[n - 1, z] + ChebyshevU[n + 1, z] == 2 z ChebyshevU[n, z]//FullSimplifyGeneralizations & Extensions (2)
ChebyshevU can be applied to power series:
ChebyshevU[10, Log[1 + x] + O[x] ^ 6]ChebyshevU can be applied to Interval:
ChebyshevU[10, Interval[{-1, 1}]]Applications (7)
Approximate a function on the interval 
:
coeffs = Table[((2/π)Subsuperscript[∫, -1, 1]Sqrt[1 - x^2] ChebyshevU[n, x] Sinc[2x π]ⅆx), {n, 0, 4}];Plot[{Sinc[2π x], Evaluate[coeffs.Table[ChebyshevU[n, x], {n, 0, 4}]]}, {x, -1, 1}]Build a curve that passes through given points:
curve[pts_List] := Function[x, Evaluate[Block[{n = Length[pts]}, pts.Table[ChebyshevU[n - 1, Sin[(k π/n)] Sqrt[1 - x^2] + x Cos[(π k/n)]], {k, 0, n - 1}] / n]]]points[pts_List] := MapIndexed[{-1. Cos[(First[#2]) * Pi / Length[pts]], #1}&, Reverse[pts]]Plot[Evaluate[curve[Range[15]][x]], {x, -1, 1}, Prolog -> {Red, PointSize[0.02], Point[points[Range[15]]]}]Light amplitude transmission through 
layers of glass:
Plot[ Evaluate[Table[1 / (1 + k^2 ChebyshevU[n, Cos[k] + Sinc[k]]^2), {n, 0, 5}]], {k, 0, 10}, PlotRange -> All]Define a Toeplitz tridiagonal matrix:
toeplitzTridiagonal[a_, b_, c_, n_] := SparseArray[{Band[{2, 1}] -> a, Band[{1, 1}] -> b, Band[{1, 2}] -> c}, {n, n}]toeplitzTridiagonal[a, b, c, 4]//MatrixFormThe characteristic polynomial of a Toeplitz tridiagonal matrix can be expressed in terms of ChebyshevU:
cPoly[a_, b_, c_, n_, x_] := (-Sqrt[a c])^n ChebyshevU[n, (x - b/2Sqrt[a c])]Verify for the first few cases:
Table[CharacteristicPolynomial[toeplitzTridiagonal[a, b, c, n], x] == cPoly[a, b, c, n, x]//Simplify, {n, 2, 9}]Define the Kac–Murdock–Szegő (KMS) matrix, a symmetric Toeplitz matrix:
kms[ρ_, n_] := ToeplitzMatrix[ρ^Range[0, n - 1]]The KMS matrix is the correlation matrix of an autoregressive process of order one (i.e. an AR(1) process):
n = 6;
kms[ρ, n] == Correlation[ARProcess[{ρ}, σ ^ 2][Range[n]]]//SimplifyThe characteristic polynomial of the KMS matrix can be expressed in terms of ChebyshevU:
CharacteristicPolynomial[kms[ρ, n], λ] == With[{τ = (ρ^2(λ + 1) + λ - 1/2ρ λ)}, ((ρ λ)^n/1 - ρ^2)(ChebyshevU[n, τ] - 2ρ ChebyshevU[n - 1, τ] + ρ^2ChebyshevU[n - 2, τ])]//SimplifySolve a differential equation with the ChebyshevU function as the inhomogeneous part:
DSolve[y''[x] + ChebyshevU[n, x] == 0, y[x], x]Find a Chebyshev polynomial from its generating function:
Series[1 / (1 - 2 t x + t ^ 2), {t, 0, 4}]SeriesCoefficient[%, 4]ChebyshevU[4, x]Properties & Relations (7)
Get the list of coefficients in a ChebyshevU polynomial:
CoefficientList[ ChebyshevU[10, x], x]Use FunctionExpand to expand through trigonometric functions:
FunctionExpand[ChebyshevU[n, x]]Derivative of ChebyshevU with respect to 
:
D[ChebyshevU[n, x], x]ChebyshevU can be represented as a DifferenceRoot:
DifferenceRootReduce[ChebyshevU[k, z], k]General term in the series expansion of ChebyshevU:
SeriesCoefficient[ChebyshevU[a, x], {x, 0, n}]The generating function for ChebyshevU:
GeneratingFunction[ChebyshevU[n, k], n, x]The exponential generating function for ChebyshevU:
ExponentialGeneratingFunction[ChebyshevU[n, k], n, x]Related Links
MathWorld
The Wolfram Functions SiteText
Wolfram Research (1988), ChebyshevU, Wolfram Language function, https://reference.wolfram.com/language/ref/ChebyshevU.html (updated 2022).
CMS
Wolfram Language. 1988. "ChebyshevU." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2022. https://reference.wolfram.com/language/ref/ChebyshevU.html.
APA
Wolfram Language. (1988). ChebyshevU. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ChebyshevU.html