WOLFRAM

Wolfram Language & System Documentation Center

HeunB[q,α,γ,δ,ϵ,z]

gives the bi-confluent Heun function.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Numerical Evaluation  
Specific Values  
Visualization  
Show More Show More
Function Properties  
Differentiation  
Integration  
Series Expansions  
Applications  
Properties & Relations  
Possible Issues  
Neat Examples  
See Also
Related Guides
Related Links
History
Cite this Page

HeunB

HeunB[q,α,γ,δ,ϵ,z]

gives the bi-confluent Heun function.

Details

  • HeunB belongs to the Heun class of functions and occurs in quantum mechanics, mathematical physics and applications.
  • Mathematical function, suitable for both symbolic and numerical manipulation.
  • HeunB[q,α,γ,δ,ϵ,z] satisfies the bi-confluent Heun differential equation .
  • The HeunB function is the regular solution of the bi-confluent Heun equation that satisfies the condition HeunB[q,α,γ,δ,ϵ,0]1.
  • For certain special arguments, HeunB automatically evaluates to exact values.
  • HeunB can be evaluated for arbitrary complex parameters.
  • HeunB can be evaluated to arbitrary numerical precision.
  • HeunB automatically threads over lists.

Examples

open all close all

Basic Examples  (3)

Evaluate numerically:

Wolfram Language code: HeunB[-0.2, 1.3, 0.12, -0.14, 4.32, -.3]

Plot the HeunB function:

Wolfram Language code: Plot[HeunB[-0.2, 1.3, 0.12, -0.14, 4.32, x], {x, -3, 3}]

Series expansion of HeunB:

Wolfram Language code: Series[HeunB[q, α, γ, δ, ϵ, z], {z, 0, 2}]

Scope  (24)

Numerical Evaluation  (8)

Evaluate to high precision:

Wolfram Language code: N[HeunB[9 / 10, -14 / 10, 12 / 100, 3 / 100, -2 / 10, 1 / 10], 50]

The precision of the output tracks the precision of the input:

Wolfram Language code: HeunB[9 / 10, -14 / 10, 12 / 100, 3 / 100, -2 / 10, 0.10000000000000000001]

HeunB can take one or more complex number parameters:

Wolfram Language code: HeunB[1.2 + I, -1.4, 0.12, 0.03, -0.2, 0.1]
Wolfram Language code: HeunB[1.2 + I, -1.4 + 0.I, 0.12 - I, 0.03 + 0.123I, -0.2 - 0.2I, 0.1]

HeunB can take complex number arguments:

Wolfram Language code: HeunB[1.2, -1.4, 0.12, 0.03, -0.2, 0.1 + I]

Finally, HeunB can take all complex number input:

Wolfram Language code: HeunB[1.2 + I, -1.4 + 0.I, 0.12 - I, 0.03 + 0.123I, -0.2 - 0.2I, 0.1 + I]

Evaluate HeunB efficiently at high precision:

Wolfram Language code: HeunB[1 / 2, -1 / 3, 1 / 4, 1 / 5, -1 / 6, 1 / 7`100]//Timing
Wolfram Language code: HeunB[1 / 2, -1 / 3, 1 / 4, 1 / 5, -1 / 6, 1 / 7 + I / 2`100]//Timing

Lists and matrices:

Wolfram Language code: HeunB[1.2, -1.4, 0.12, 0.03, -0.2, {0.15, 0.1 + I, I, 4}]
Wolfram Language code: HeunB[-0.2, {1.3, -0.4}, 0.12, -0.14, 4.32, -1.4]
Wolfram Language code: HeunB[1.2, -1.4, 0.12, 0.03, -0.2, (| | | | :- | :---- | | π | u | | v | (π/2) |) ]

Compute the elementwise values of an array:

Wolfram Language code: HeunB[.1 + I, I, 0.12, 0, -0.32, {{π, -1}, {1, π / 2}}]

Or compute the matrix HeunB function using MatrixFunction:

Wolfram Language code: MatrixFunction[HeunB[.1 + I, I, 0.12, 0, -0.32, #]&, {{π, -1}, {0, π / 2}}]

Specific Values  (1)

Value of HeunB at origin:

Wolfram Language code: HeunB[q, α, γ, δ, ϵ, 0]

Visualization  (5)

Plot the HeunB function:

Wolfram Language code: Plot[HeunB[4, 0.6, -0.7 , -0.18, 0.3 , z], {z, -5, 1}]

Plot the absolute value of the HeunB function for complex parameters:

Wolfram Language code: Plot[Abs[HeunB[4 + I, -0.6 - 0.3I, -0.7 , -0.18, 0.3 , z]], {z, -5, 1}]

Plot HeunB as a function of its second parameter :

Wolfram Language code: Plot[HeunB[4, α, -0.7, -0.18, 0.3 , z] /. α -> {-2, Sqrt[20], 1 / 10}//Evaluate, {z, -5, 1}]

Plot HeunB as a function of and :

Wolfram Language code: {α, γ, ϵ, δ} = {0.2 + I, -0.6 + 0.9 I, -0.7 I, 0.3  + 0.6 I};
Wolfram Language code: Plot3D[Abs[HeunB[q, α, γ, δ, ϵ, z]], {q, -20, 2}, {z, 1 / 10, 9 / 10}, ColorFunction -> Function[{q, z, HB}, Hue[HB]], PlotRange -> All]

Plot the family of HeunB functions for different accessory parameter :

Wolfram Language code: {α, γ, δ, ϵ} = {0.8 + 0.7 I, 0.9  - 0.6I, 0.2 - 0.7 I, -0.7 + 0.8I};
Wolfram Language code: Plot[Evaluate[Table[Abs[HeunB[q, α, γ, δ, ϵ, z]], {q, -10, 10, 2}]], {z, -3, 3}, PlotStyle -> Table[{Hue[i / 10], Thickness[0.002]}, {i, 20}], PlotRange -> {0, 3}, Frame -> True, Axes -> False]

Function Properties  (1)

HeunB can be simplified to Hypergeometric1F1 function in the following case:

Wolfram Language code: HeunB[q, 0, γ, -1, 0, z]

Differentiation  (2)

The -derivative of HeunB is HeunBPrime:

Wolfram Language code: D[HeunB[q, α, γ, δ, ϵ, z], z]

Higher derivatives of HeunB are calculated using HeunBPrime:

Wolfram Language code: D[HeunB[q, α, γ, δ, ϵ, z], {z, 2}]//Simplify

Integration  (3)

Indefinite integrals of HeunB are not expressed in elementary or other special functions:

Wolfram Language code: Integrate[HeunB[q, α, γ, δ, ϵ, z], z]

Definite numerical integral of HeunB:

Wolfram Language code: NIntegrate[HeunB[12 / 10, -14 / 10, 12 / 100, 3 / 100, -2 / 10, z], {z, 0, 1 / 3}]

More integrals with HeunB:

Wolfram Language code: NIntegrate[z ^ 2 HeunB[12 / 10, -14 / 10, 12 / 100, 3 / 100, -2 / 10, z], {z, -1, 1 / 3}]
Wolfram Language code: NIntegrate[Sin[Sqrt[z]] ^ 2 HeunB[12 / 10, -14 / 10, 12 / 100, 3 / 100, -2 / 10, z], {z, -1, 1 / 3}]

Series Expansions  (4)

Taylor expansion for HeunB at regular singular origin:

Wolfram Language code: Series[HeunB[q, α, γ, δ, ϵ, z], {z, 0, 2}]

Coefficient of the second term in the series expansion of HeunB at :

Wolfram Language code: SeriesCoefficient[HeunB[q, α, γ, δ, ϵ, z], {z, 0, 2}]

Plot the first three approximations for HeunB around :

Wolfram Language code: {q, α, γ, δ, ϵ} = {1 / 31, 9 / 10, 1 / 10, 1 / 10, 3 / 2};
Wolfram Language code: terms = Normal@Table[Series[HeunB[q, α, γ, δ, ϵ, z], {z, 0, m}], {m, 1, 5, 2}];
Wolfram Language code: Plot[{HeunB[q, α, γ, δ, ϵ, z], terms}, {z, -6, 3}, PlotRange -> {-4, 8}, PlotLegends -> {"HeunB[q, α, γ, δ, ϵ, z]", "1st approximation", "2nd approximation", "3rd approximation"}]

Series expansion for HeunB at any ordinary complex point:

Wolfram Language code: Series[HeunB[q, α, γ, δ, ϵ, z], {z, 1 / 2, 1}]//FullSimplify

Applications  (4)

Solve the bi-confluent Heun differential equation using DSolve:

Wolfram Language code: sol = DSolve[ y''[z] + ((γ/z) + δ + ϵ z)y'[z] + (α z - q/z)y[z] == 0, y[z], z]

Plot the solution:

Wolfram Language code: {q, α, γ, δ, ϵ} = {4 + I, -0.6 - 0.3I, -0.7 , -0.18, 0.3 };
Wolfram Language code: Plot[Abs[y[z]] /. sol /. {{C[1] -> 1, C[2] -> 0}, {C[1] -> 0, C[2] -> 10}, {C[1] -> 1 / 3, C[2] -> 1}}//Evaluate, {z, -5, 1}, PlotRange -> {0, 8}]

Solve the initial value problem for the bi-confluent Heun differential equation:

Wolfram Language code: sol = DSolveValue[ {y''[z] + ((γ/z) + δ + ϵ z)y'[z] + (α z - q/z)y[z] == 0, y[0] == 1, y'[0] == (q/γ)}, y[z], z]

Plot the solution for different values of the accessory parameter q:

Wolfram Language code: {α, γ, δ, ϵ} = {-3 / 5, -7 / 10, -1 / 5, 1 / 3 };
Wolfram Language code: Plot[sol /. q -> {0, 1, 2, 3, 4}//Evaluate, {z, -8, 1}]

Directly solve the bi-confluent Heun differential equation:

Wolfram Language code: y[z_] := HeunB[q, α, γ, δ, ϵ, z]
Wolfram Language code: y''[z] + ((γ/z) + δ + ϵ z)y'[z] + (α z - q/z)y[z] == 0//FullSimplify

Solve the class of confinement potentials for the radial Schrödinger equation in terms of HeunB functions:

Wolfram Language code: V[r_] := (a/r) + b r + c r^2 + (l(l + 1)/r^2)

Plot the potential for arbitrary parameters:

Wolfram Language code: Plot[V[r] /. {a -> -30, b -> -25, c -> 3, l -> 1}, {r, -5, 5}]

This general potential is solved in terms of HeunB functions:

Wolfram Language code: {a, b, c} = {1, 4, 4};
Wolfram Language code: DSolve[R''[r] + ((2m/ℏ^2)Ee - V[r])R[r] == 0, R[r], r, Assumptions -> l > 0]

Properties & Relations  (3)

HeunB is analytic at the origin:

Wolfram Language code: Series[HeunB[q, α, γ, δ, ϵ, z], {z, 0, 2}]

HeunB can be calculated at any finite complex :

Wolfram Language code: HeunB[4 + I, -1 / 2, 1 / 4, -7 / 5, 2, z] /. z -> RandomComplex[{-5 - I, 5 + I}, 5]

The derivative of HeunB is HeunBPrime:

Wolfram Language code: D[HeunB[q, α, γ, δ, ϵ, z], z]

Possible Issues  (1)

HeunB diverges for big arguments:

Wolfram Language code: HeunB[0.03 + I, 1.3, 1, 0.12, 4.32, 100]

Neat Examples  (2)

Create a table of some special cases for HeunB :

Wolfram Language code: flist = Inactivate[{HeunB[q, 0, γ, -1, 0, z], HeunB[1, 0, γ, 0, 0, z], HeunB[1 / 2, 0, 1, -1, 0, z], HeunB[2, 0, 1, -1, 0, z]}, HeunB];
Wolfram Language code: Grid[Join[{{Text["Special case of HeunB"], Text["Simpler Special function"]}}, Transpose[{flist, Activate[flist]}]], IconizedObject[«Grid options»]]//TraditionalForm

The quantum-mechanical doubly anharmonic oscillator potential is:

Wolfram Language code: V[x_] := μ x^2 + λ x^4 + η x^6

Plot the potential:

Wolfram Language code: Plot[V[x] /. {μ -> -7, λ -> -5, η -> 1}, {x, -3, 3}]

The general solution of the Schrödinger equation is written in terms of HeunB functions:

Wolfram Language code: Subscript[ψ, 1][x_] := E^(x^2 (x^2 η + λ)/4 Sqrt[η]) HeunB[-(EE/4) - (λ/8 Sqrt[η]), (12 η^3 / 2 + λ^2 - 4 η μ/16 η), (1/2), (λ/2 Sqrt[η]), Sqrt[η], x^2] Subscript[ψ, 2][x_] := E^(x^2 (x^2 η + λ)/4 Sqrt[η]) x HeunB[-(EE/4) - (3 λ/8 Sqrt[η]), (20 η^3 / 2 + λ^2 - 4 η μ/16 η), (3/2), (λ/2 Sqrt[η]), Sqrt[η], x^2]
Wolfram Language code: ψ[x_] = C[1]Subscript[ψ, 1][x] + C[2]Subscript[ψ, 2][x];

Verify this solution by direct substitution:

Wolfram Language code: ψ''[x] + (EE - μ x^2 - λ x^4 - η x^6)ψ[x]//Simplify
Wolfram Research (2020), HeunB, Wolfram Language function, https://reference.wolfram.com/language/ref/HeunB.html.

Text

Wolfram Research (2020), HeunB, Wolfram Language function, https://reference.wolfram.com/language/ref/HeunB.html.

CMS

Wolfram Language. 2020. "HeunB." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/HeunB.html.

APA

Wolfram Language. (2020). HeunB. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/HeunB.html

BibTeX

@misc{reference.wolfram_2026_heunb, author="Wolfram Research", title="{HeunB}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/HeunB.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_heunb, organization={Wolfram Research}, title={HeunB}, year={2020}, url={https://reference.wolfram.com/language/ref/HeunB.html}, note=[Accessed: 12-June-2026]}