WOLFRAM

Wolfram Language & System Documentation Center

HeunT[q,α,γ,δ,ϵ,z]

gives the tri-confluent Heun function.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Numerical Evaluation  
Specific Values  
Visualization  
Differentiation  
Integration  
Series Expansions  
Applications  
Properties & Relations  
Possible Issues  
Neat Examples  
See Also
Related Guides
Related Links
History
Cite this Page

HeunT

HeunT[q,α,γ,δ,ϵ,z]

gives the tri-confluent Heun function.

Details

  • HeunT belongs to the Heun class of functions and occurs in quantum mechanics and applications.
  • Mathematical function, suitable for both symbolic and numerical manipulation.
  • HeunT[q,α,γ,δ,ϵ,z] satisfies the tri-confluent Heun differential equation .
  • The HeunT function is the power-series solution of the tri-confluent Heun equation that satisfies the conditions and .
  • For certain special arguments, HeunT automatically evaluates to exact values.
  • HeunT can be evaluated for arbitrary complex parameters.
  • HeunT can be evaluated to arbitrary numerical precision.
  • HeunT automatically threads over lists.

Examples

open all close all

Basic Examples  (3)

Evaluate numerically:

Wolfram Language code: HeunT[-0.2, 1.3, 0.12, -0.14, 4.32, -.3]

Plot the HeunT function:

Wolfram Language code: Plot[HeunT[-0.2, 1.3, 0.12, -0.14, 4.32, x], {x, -1, 2}]

Series expansion of HeunT:

Wolfram Language code: Series[HeunT[q, α, γ, δ, ϵ, z], {z, 0, 2}]

Scope  (24)

Numerical Evaluation  (8)

Evaluate to high precision:

Wolfram Language code: N[HeunT[9 / 10, -14 / 10, 12 / 100, 3 / 100, -2 / 10, 1 / 10], 50]

The precision of the output tracks the precision of the input:

Wolfram Language code: HeunT[9 / 10, -14 / 10, 12 / 100, 3 / 100, -2 / 10, 0.10000000000000000001]

HeunT can take one or more complex number parameters:

Wolfram Language code: HeunT[1.2 + I, -1.4, 0.12, 0.03, -0.2, 0.1]
Wolfram Language code: HeunT[1.2 + I, -1.4 + 0.I, 0.12 - I, 0.03 + 0.123I, -0.2 - 0.2I, 0.1]

HeunT can take complex number arguments:

Wolfram Language code: HeunT[1.2, -1.4, 0.12, 0.03, -0.2, 0.1 + I]

Finally, HeunT can take all complex number input:

Wolfram Language code: HeunT[1.2 + I, -1.4 + 0.I, 0.12 - I, 0.03 + 0.123I, -0.2 - 0.2I, 0.1 + I]

Evaluate HeunT efficiently at high precision:

Wolfram Language code: HeunT[1 / 2, -1 / 3, 1 / 4, 1 / 5, -1 / 6, 1 / 7`100]//Timing
Wolfram Language code: HeunT[1 / 2, -1 / 3, 1 / 4, 1 / 5, -1 / 6, 1 / 7 + I / 2`100]//Timing

Lists and matrices:

Wolfram Language code: HeunT[1.2, -1.4, 0.12, 0.03, -0.2, {0.15, 0.1 + I, I, 4}]
Wolfram Language code: HeunT[-0.2, {1.3, -0.4}, 0.12, -0.14, 4.32, -1.4]
Wolfram Language code: HeunT[1.2, -1.4, 0.12, 0.03, -0.2, (| | | | :- | :---- | | π | u | | v | (π/2) |) ]

Compute the elementwise values of an array:

Wolfram Language code: HeunT[.1, .1 + I, 0.12, 1, -0.32, {{.01, -1}, {.3, .2}}]

Or compute the matrix HeunT function using MatrixFunction:

Wolfram Language code: MatrixFunction[HeunT[.1, .1 + I, 0.12, 1, -0.32, #]&, {{.01, -1}, {.3, .2}}]

Specific Values  (2)

Value of HeunT at origin:

Wolfram Language code: HeunT[q, α, γ, δ, ϵ, 0]

Calculate HeunT for arbitrary arguments:

Wolfram Language code: HeunT[12 / 10, -14 / 10, 12 / 100, 3 / 100, -2 / 10, 0.7 - 3.1I]

Visualization  (5)

Plot the HeunT function:

Wolfram Language code: Plot[HeunT[4, -0.6, 0.7 , 1.18, -1.3 , z], {z, -1, 1}]

Plot the absolute value of the HeunT function for complex parameters:

Wolfram Language code: Plot[Abs[HeunT[4 + I, -0.6 - 0.3I, -0.7 , -0.18, 0.3 , z]], {z, -2, 1}]

Plot HeunT as a function of its second parameter :

Wolfram Language code: Plot[HeunT[4, α, -0.7, -0.18, 0.3 , z] /. α -> {-2, Sqrt[20], 1 / 10}//Evaluate, {z, -1, 1}]

Plot HeunT as a function of and :

Wolfram Language code: {α, γ, ϵ, δ} = {0.2 + I, -0.6 + 0.9 I, -0.7 I, 0.3  + 0.6 I};
Wolfram Language code: Plot3D[Abs[HeunT[q, α, γ, δ, ϵ, z]], {q, -20, 2}, {z, 1 / 10, 9 / 10}, ColorFunction -> Function[{q, z, HT}, Hue[HT]], PlotRange -> All]

Plot the family of HeunT functions for different accessory parameter :

Wolfram Language code: {α, γ, δ, ϵ} = {0.8 + 0.7 I, 0.92  + 0.33I, 0.21  + 0.72 I, -0.76 - 0.81I};
Wolfram Language code: Plot[Evaluate[Table[Abs[HeunT[q, α, γ, δ, ϵ, z]], {q, -18, 3, 3}]], {z, -4, 7 / 2}, PlotStyle -> Table[{Hue[i / 10], Thickness[0.002]}, {i, 20}], PlotRange -> {0, 4}, Frame -> True, Axes -> False]

Differentiation  (2)

First -derivative of HeunT is HeunTPrime:

Wolfram Language code: D[HeunT[q, α, γ, δ, ϵ, z], z]

Higher derivatives of HeunT are calculated using HeunTPrime:

Wolfram Language code: D[HeunT[q, α, γ, δ, ϵ, z], {z, 2}]//Simplify

Integration  (3)

Indefinite integrals of HeunT are not expressed in elementary or other special functions:

Wolfram Language code: Integrate[HeunT[q, α, γ, δ, ϵ, z], z]

Definite numerical integral of HeunT:

Wolfram Language code: NIntegrate[HeunT[12 / 10, -14 / 10, 12 / 100, 3 / 100, -2 / 10, z], {z, 0, 1 / 3}]

More integrals with HeunT:

Wolfram Language code: NIntegrate[z ^ 2 HeunT[12 / 10, -14 / 10, 12 / 100, 3 / 100, -2 / 10, z], {z, -1, 1 / 3}]
Wolfram Language code: NIntegrate[Sin[Sqrt[z]] ^ 2 HeunT[12 / 10, -14 / 10, 12 / 100, 3 / 100, -2 / 10, z], {z, -1, 1 / 3}]

Series Expansions  (4)

Taylor expansion for HeunT at origin:

Wolfram Language code: Series[HeunT[q, α, γ, δ, ϵ, z], {z, 0, 3}]

Coefficient of the third term in the series expansion of HeunT at :

Wolfram Language code: SeriesCoefficient[HeunT[q, α, γ, δ, ϵ, z], {z, 0, 3}]

Plot the first three approximations for HeunT around :

Wolfram Language code: {q, α, γ, δ, ϵ} = {-8, -9 / 10, 1 / 10, 4 / 7, 3 / 2};
Wolfram Language code: terms = Normal@Table[Series[HeunT[q, α, γ, δ, ϵ, z], {z, 0, m}], {m, 1, 4}];
Wolfram Language code: Plot[{HeunT[q, α, γ, δ, ϵ, z], terms}, {z, -3, 3}, PlotRange -> {-5, 5}, PlotLegends -> {"HeunT[q, α, γ, δ, ϵ, z]", "1st approximation", "2nd approximation", "3rd approximation", "4th approximation"}]

Series expansion for HeunT at any ordinary complex point:

Wolfram Language code: Series[HeunT[q, α, γ, δ, ϵ, z], {z, 1 / 2, 1}]//FullSimplify

Applications  (5)

Solve the tri-confluent Heun differential equation using DSolve:

Wolfram Language code: sol = DSolve[ y''[z] + (γ + δ z + ϵ z^2)y'[z] + (α z - q)y[z] == 0, y[z], z]

Plot the solution:

Wolfram Language code: {q, α, γ, δ, ϵ} = {4, -10, 1 / 3, 0, -1 / 3};
Wolfram Language code: Plot[y[z] /. sol /. {{C[1] -> 1, C[2] -> 0}, {C[1] -> 0, C[2] -> 1}, {C[1] -> 1 / 3, C[2] -> 1 / 3}}//Evaluate, {z, -4, 1}]

Solve the initial value problem for the tri-confluent Heun differential equation:

Wolfram Language code: sol = DSolveValue[{y''[z] + (γ + δ z + ϵ z^2)y'[z] + (α z - q)y[z] == 0, y[0] == 1, y'[0] == 0}, y[z], z]

Plot the solution for different values of the accessory parameter q:

Wolfram Language code: {α, γ, δ, ϵ} = {-10, 1 / 3, 4 / 3, -1 / 3};
Wolfram Language code: Plot[Abs[sol] /. q -> {1, 2, 3, 4}//Evaluate, {z, -5 / 2, 1}]

Directly solve the tri-confluent Heun differential equation:

Wolfram Language code: y[z_] := HeunT[q, α, γ, δ, ϵ, z]
Wolfram Language code: y''[z] + (γ + δ z + ϵ z^2)y'[z] + (α z - q)y[z] == 0//Simplify

The quartic potential for the 1D Schrödinger equation:

Wolfram Language code: V[z_] := λ^2(Underoverscript[∏, i = 1, 4](z - Subscript[z, i]))

Solve this general potential in terms of HeunT functions:

Wolfram Language code: {Subscript[z, 1], Subscript[z, 2], Subscript[z, 3], Subscript[z, 4]} = {1, 2, 3, 4};
Wolfram Language code: DSolve[u''[z] - V[z]u[z] == 0, u[z], z]

When , HeunT can be expressed in terms of Airy functions:

Wolfram Language code: y[z_] = FunctionExpand[HeunT[0, -1, 0, 0, 0, z]]

Verify that the result is a solution of the Airy equation:

Wolfram Language code: y''[z] - z y[z] == 0//Simplify

Properties & Relations  (4)

HeunT is analytic at the origin:

Wolfram Language code: Series[HeunT[q, α, γ, δ, ϵ, z], {z, 0, 2}]

HeunT can be calculated at any finite complex :

Wolfram Language code: HeunT[4 + I, -1 / 2, 1 / 4, -7 / 5, 2, z] /. z -> RandomComplex[{-2 - I, 2 + I}, 5]

The derivative of HeunT is HeunTPrime:

Wolfram Language code: D[HeunT[q, α, γ, δ, ϵ, z], z]

Use FunctionExpand to expand HeunT into simpler functions:

Wolfram Language code: FunctionExpand[HeunT[q, 0, 1, 1, 0, z]]

Possible Issues  (1)

HeunT calculations might take time for big arguments:

Wolfram Language code: AbsoluteTiming[HeunT[0.03 + I, 1.3, 1, 0.12, 4.32, 20]]

Neat Examples  (1)

The classical anharmonic oscillator equation is solved in terms of HeunT:

Wolfram Language code: sol = DSolve[u''[z] + (Subscript[λ, 1] + Subscript[λ, 2]z^2 + Subscript[λ, 4] z^4)u[z] == 0, u[z], z]

Simulate the anharmonic oscillator dynamics:

Wolfram Language code: {Subscript[λ, 1], Subscript[λ, 2], Subscript[λ, 4]} = {1, 1 / 2, 1 / 4};
Wolfram Language code: Plot[{u[z] /. sol /. {C[1] -> 1, C[2] -> 1}}, {z, 0, 9 / 2}]
Wolfram Research (2020), HeunT, Wolfram Language function, https://reference.wolfram.com/language/ref/HeunT.html.

Text

Wolfram Research (2020), HeunT, Wolfram Language function, https://reference.wolfram.com/language/ref/HeunT.html.

CMS

Wolfram Language. 2020. "HeunT." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/HeunT.html.

APA

Wolfram Language. (2020). HeunT. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/HeunT.html

BibTeX

@misc{reference.wolfram_2026_heunt, author="Wolfram Research", title="{HeunT}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/HeunT.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_heunt, organization={Wolfram Research}, title={HeunT}, year={2020}, url={https://reference.wolfram.com/language/ref/HeunT.html}, note=[Accessed: 12-June-2026]}