WOLFRAM

Wolfram Language & System Documentation Center

HeunTPrime[q,α,γ,δ,ϵ,z]

gives the -derivative of the HeunT function.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Numerical Evaluation  
Specific Values  
Visualization  
Differentiation  
Integration  
Series Expansions  
Applications  
Properties & Relations  
Possible Issues  
Neat Examples  
See Also
Related Guides
Related Links
History
Cite this Page

HeunTPrime

HeunTPrime[q,α,γ,δ,ϵ,z]

gives the -derivative of the HeunT function.

Details

  • Mathematical function, suitable for both symbolic and numerical manipulation.
  • HeunTPrime belongs to the Heun class of functions.
  • For certain special arguments, HeunTPrime automatically evaluates to exact values.
  • HeunTPrime can be evaluated for arbitrary complex parameters.
  • HeunTPrime can be evaluated to arbitrary numerical precision.
  • HeunTPrime automatically threads over lists.

Examples

open all close all

Basic Examples  (3)

Evaluate numerically:

Wolfram Language code: HeunTPrime[4, -0.6, -0.7 , -0.18, 0.3 , 0.12]

Plot HeunTPrime:

Wolfram Language code: Plot[HeunTPrime[4, -0.6, -0.7 , -0.18, 0.3 , x], {x, -3 / 10, 9 / 10}]

Series expansion of HeunTPrime:

Wolfram Language code: Series[HeunTPrime[q, α, γ, δ, ϵ, z], {z, 0, 2}]

Scope  (22)

Numerical Evaluation  (8)

Evaluate to high precision:

Wolfram Language code: N[HeunTPrime[9 / 10, -14 / 10, 12 / 100, 3 / 100, -2 / 10, 1 / 10], 50]

The precision of the output tracks the precision of the input:

Wolfram Language code: HeunTPrime[9 / 10, -14 / 10, 12 / 100, 3 / 100, -2 / 10, 0.10000000000000000001]

HeunTPrime can take one or more complex number parameters:

Wolfram Language code: HeunTPrime[1.2 + I, -1.4, 0.12, 0.03, -0.2, 0.1]
Wolfram Language code: HeunTPrime[1.2 + I, -1.4 + 0.I, 0.12 - I, 0.03 + 0.123I, -0.2 - 0.2I, 0.1]

HeunTPrime can take complex number arguments:

Wolfram Language code: HeunTPrime[1.2, -1.4, 0.12, 0.03, -0.2, 0.1 + I]

Finally, HeunTPrime can take all complex number input:

Wolfram Language code: HeunTPrime[1.2 + I, -1.4 + 0.I, 0.12 - I, 0.03 + 0.123I, -0.2 - 0.2I, 0.1 + I]

Evaluate HeunTPrime efficiently at high precision:

Wolfram Language code: HeunTPrime[1 / 2, -1 / 3, 1 / 4, 1 / 5, -1 / 6, 1 / 7`100]//Timing
Wolfram Language code: HeunTPrime[1 / 2, -1 / 3, 1 / 4, 1 / 5, -1 / 6, 1 / 7 + I / 2`100]//Timing

Lists and matrices:

Wolfram Language code: HeunTPrime[1.2, -1.4, 0.12, 0.03, -0.2, {0.15, 0.1 + I, I, 4}]
Wolfram Language code: HeunTPrime[-0.002, {1.3, -0.4}, 0.12, -0.14, 4.32, -1.4]
Wolfram Language code: HeunTPrime[1.2, -1.4, 0.12, 0.03, -0.2, (| | | | :- | :---- | | π | u | | v | (π/2) |) ]

Compute the elementwise values of an array:

Wolfram Language code: HeunTPrime[.1 + I, I, 0.12, 0, -0.32, {{2, -1}, {1, 2}}]

Or compute the matrix HeunTPrime function using MatrixFunction:

Wolfram Language code: MatrixFunction[HeunTPrime[.1 + I, I, 0.12, 0, -0.32, #]&, {{2, -1}, {0, 2}}]

Specific Values  (1)

Value of HeunTPrime at origin:

Wolfram Language code: HeunTPrime[q, α, γ, δ, ϵ, 0]

Visualization  (5)

Plot the HeunTPrime function:

Wolfram Language code: Plot[HeunTPrime[4, -0.6, -0.7 , -0.18, 0.3 , z], {z, -3 / 10, 9 / 10}]

Plot the absolute value of the HeunTPrime function for complex parameters:

Wolfram Language code: Plot[Abs[HeunTPrime[4 + I, -0.6 + 0.9 I, -0.7 I, -0.18 - 0.03 I, 0.3  + 0.6 I, z]], {z, -3 / 10, 9 / 10}]

Plot HeunTPrime as a function of its second parameter :

Wolfram Language code: Plot[HeunTPrime[4, α, -0.7, -0.18, 0.3 , z] /. α -> {-2, Sqrt[20], 1 / 10}//Evaluate, {z, -3 / 10, 9 / 10}]

Plot HeunTPrime as a function of and :

Wolfram Language code: {α, γ, ϵ, δ} = {0.2 + I, -0.6 + 0.9 I, -0.7 I, 0.3  + 0.6 I};
Wolfram Language code: Plot3D[Abs[HeunTPrime[q, α, γ, δ, ϵ, z]], {q, -20, 2}, {z, 1 / 10, 9 / 10}, ColorFunction -> Function[{q, z, HTPrime}, Hue[HTPrime]], PlotRange -> All]

Plot the family of HeunTPrime functions for different values of the accessory parameter :

Wolfram Language code: {α, γ, δ, ϵ} = {0.8 + 0.7 I, 0.92  + 0.33I, 0.21  + 0.72 I, -0.76 - 0.81I};
Wolfram Language code: Plot[Evaluate[Table[Abs[HeunTPrime[q, α, γ, δ, ϵ, z]], {q, -18, 3, 3}]], {z, -4, 7 / 2}, PlotStyle -> Table[{Hue[i / 10], Thickness[0.002]}, {i, 20}], PlotRange -> {0, 7}, Frame -> True, Axes -> False]

Differentiation  (1)

The derivatives of HeunTPrime are calculated using the HeunT function:

Wolfram Language code: D[HeunTPrime[q, α, γ, δ, ϵ, z], z]

Integration  (3)

Integral of HeunTPrime gives back HeunT:

Wolfram Language code: Integrate[HeunTPrime[q, α, γ, δ, ϵ, z], z]

Definite numerical integral of HeunTPrime:

Wolfram Language code: NIntegrate[HeunTPrime[12 / 10, -14 / 10, 12 / 100, 3 / 100, -2 / 10, z], {z, 0, 1 / 3}]

More integrals with HeunTPrime:

Wolfram Language code: NIntegrate[z ^ 2 HeunTPrime[12 / 10, -14 / 10, 12 / 100, 3 / 100, -2 / 10, z], {z, -1, 1 / 3}]
Wolfram Language code: NIntegrate[Sin[Sqrt[z]] ^ 2 HeunTPrime[12 / 10, -14 / 10, 12 / 100, 3 / 100, -2 / 10, z], {z, -1, 1 / 3}]

Series Expansions  (4)

Taylor expansion for HeunTPrime at origin:

Wolfram Language code: Series[HeunTPrime[q, α, γ, δ, ϵ, z], {z, 0, 2}]

Coefficient of the second term in the series expansion of HeunTPrime at :

Wolfram Language code: SeriesCoefficient[HeunTPrime[q, α, γ, δ, ϵ, z], {z, 0, 2}]

Plots of the first three approximations for HeunTPrime around :

Wolfram Language code: {q, α, γ, δ, ϵ} = {1 / 31, 9 / 10, 1 / 10, 14 / 10, 1 / 2};
Wolfram Language code: terms = Normal@Table[Series[HeunTPrime[q, α, γ, δ, ϵ, z], {z, 0, m}], {m, 1, 3}];
Wolfram Language code: Plot[{HeunTPrime[q, α, γ, δ, ϵ, z], terms}, {z, -1, 2}, PlotRange -> All, PlotLegends -> {"HeunTPrime[q, α, γ, δ, ϵ, z]", "1st approximation", "2nd approximation", "3rd approximation"}]

Series expansion for HeunTPrime at any ordinary complex point:

Wolfram Language code: Series[HeunTPrime[q, α, γ, δ, ϵ, z], {z, 1 / 2, 1}]//FullSimplify

Applications  (1)

Use the HeunTPrime function to calculate the derivatives of HeunT:

Wolfram Language code: D[HeunT[q, α, γ, δ, ϵ, z], {z, 2}]

Properties & Relations  (4)

HeunTPrime is analytic at the origin:

Wolfram Language code: Series[HeunTPrime[q, α, γ, δ, ϵ, z], {z, 0, 2}]

HeunTPrime can be calculated at any finite complex :

Wolfram Language code: HeunTPrime[4 + I, -1 / 2, 1 / 4, -7 / 5, 2, z] /. z -> RandomComplex[{-2 - I, 2 + I}, 5]

HeunTPrime is the derivative of HeunT:

Wolfram Language code: D[HeunT[q, α, γ, δ, ϵ, z], z]

Use FunctionExpand to expand HeunTPrime into simpler functions:

Wolfram Language code: FunctionExpand[HeunTPrime[q, 0, 1, 1, 0, z]]
Wolfram Language code: FunctionExpand[HeunTPrime[0, -1, 0, 0, 0, z]]

Possible Issues  (1)

HeunTPrime calculations might take time for big arguments:

Wolfram Language code: AbsoluteTiming[HeunTPrime[0.03 + I, 1.3, 1, 0.12, 4.32, 20]]

Neat Examples  (1)

The Schrödinger equation for the following infinite potential well can be solved in terms of HeunTPrime:

Wolfram Language code: V[x_] := (V0/Sqrt[x])

Plot the potential:

Wolfram Language code: Plot[V[x] /. {V0 -> -1}, {x, 0, 1}]

Construct the general solution of the Schrödinger equation:

Wolfram Language code: Subscript[ψ, 1][x_] := E^(Sqrt[-2 EE m] x/ℏ) HeunTPrime[0, -(2 Sqrt[2] m V0/ℏ^2), 0, (2 Sqrt[-2 EE m] /ℏ), 0, Sqrt[2x]] Subscript[ψ, 2][x_] := E^-(Sqrt[-2 EE m]x/ℏ) HeunTPrime[0, -(2 Sqrt[2] m V0/ℏ^2), 0, -(2 Sqrt[-2 EE m] /ℏ), 0, Sqrt[2x]]
Wolfram Language code: ψ[x_] = C[1]Subscript[ψ, 1][x] + C[2]Subscript[ψ, 2][x];

Verify this solution by direct substitution:

Wolfram Language code: ψ''[x] + (2m/ℏ^2)(EE - (V0/Sqrt[x]))ψ[x] == 0//Simplify
Wolfram Research (2020), HeunTPrime, Wolfram Language function, https://reference.wolfram.com/language/ref/HeunTPrime.html.

Text

Wolfram Research (2020), HeunTPrime, Wolfram Language function, https://reference.wolfram.com/language/ref/HeunTPrime.html.

CMS

Wolfram Language. 2020. "HeunTPrime." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/HeunTPrime.html.

APA

Wolfram Language. (2020). HeunTPrime. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/HeunTPrime.html

BibTeX

@misc{reference.wolfram_2026_heuntprime, author="Wolfram Research", title="{HeunTPrime}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/HeunTPrime.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_heuntprime, organization={Wolfram Research}, title={HeunTPrime}, year={2020}, url={https://reference.wolfram.com/language/ref/HeunTPrime.html}, note=[Accessed: 12-June-2026]}