WOLFRAM

Wolfram Language & System Documentation Center

Hyperfactorial[n]

gives the hyperfactorial function TemplateBox[{n}, Hyperfactorial].

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Numerical Evaluation  
Specific Values  
Visualization  
Function Properties  
Differentiation  
Series Expansions  
Applications  
Properties & Relations  
Neat Examples  
See Also
Related Guides
Related Links
History
Cite this Page

Hyperfactorial

Hyperfactorial[n]

gives the hyperfactorial function TemplateBox[{n}, Hyperfactorial].

Details

  • Mathematical function, suitable for both symbolic and numeric manipulation.
  • Hyperfactorial is defined as TemplateBox[{n}, Hyperfactorial]=product_(k=1)^nk^k for positive integers and is otherwise defined as TemplateBox[{z}, Hyperfactorial]=(z/(sqrt(2 pi)))^z exp(1/2 z (z-1)+TemplateBox[{{-, 2}, z}, PolyGamma2]).
  • The hyperfactorial function satisfies TemplateBox[{z}, Hyperfactorial]=z^z TemplateBox[{{z, -, 1}}, Hyperfactorial].
  • Hyperfactorial can be evaluated to arbitrary numerical precision.
  • Hyperfactorial automatically threads over lists.

Examples

open all close all

Basic Examples  (5)

Evaluate numerically:

Wolfram Language code: Hyperfactorial[10]

Plot over a subset of the reals:

Wolfram Language code: Plot[Hyperfactorial[z], {z, -1, 2}]

Plot over a subset of the complexes:

Wolfram Language code: ComplexPlot3D[Hyperfactorial[z], {z, -3 - 3I, 3 + 3I}, PlotLegends -> Automatic]

Series expansion at the origin:

Wolfram Language code: Series[Hyperfactorial[x], {x, 0, 2}]//Simplify

Series expansion at Infinity:

Wolfram Language code: Series[Hyperfactorial[x], {x, ∞, 3}]

Scope  (28)

Numerical Evaluation  (6)

Evaluate numerically:

Wolfram Language code: Hyperfactorial[5]
Wolfram Language code: Hyperfactorial[3.4]

Evaluate to high precision:

Wolfram Language code: N[Hyperfactorial[1 / 5], 50]

The precision of the output tracks the precision of the input:

Wolfram Language code: Hyperfactorial[2.0000055555500000000000004440000]

Complex number inputs:

Wolfram Language code: N[Hyperfactorial[1.43 + I]]

Evaluate efficiently at high precision:

Wolfram Language code: Hyperfactorial[1 / 5`500]//Timing
Wolfram Language code: Hyperfactorial[1 / 5`1000];//Timing

Compute average-case statistical intervals using Around:

Wolfram Language code: Hyperfactorial[ Around[2.1, 0.01]]

Compute the elementwise values of an array:

Wolfram Language code: Hyperfactorial[{{1 / 2, 1}, {1, 1 / 2}}]

Or compute the matrix Hyperfactorial function using MatrixFunction:

Wolfram Language code: MatrixFunction[Hyperfactorial[#]&, {{1 / 2, 1}, {1, 1 / 2}}]//FullSimplify

Specific Values  (4)

Values at fixed points:

Wolfram Language code: Table[Hyperfactorial[z], {z, {-2, 2, 3}}]

Value at zero:

Wolfram Language code: Hyperfactorial[0]

Hyperfactorial gives exact values for integer multiples of 1/2 and 1/4:

Wolfram Language code: Hyperfactorial[1 / 2]
Wolfram Language code: Hyperfactorial[-3 / 4]

Find the positive minimum:

Wolfram Language code: xmin = x /. N@Solve[D[Hyperfactorial[x], x] == 0 && 0 < x < 2, x, Reals][[1]]//Quiet
Wolfram Language code: Plot[Hyperfactorial[x], {x, -1, 2}, Epilog -> Style[Point[{xmin, Hyperfactorial[xmin]}], PointSize[Large], Red]]

Visualization  (2)

Plot the Hyperfactorial function:

Wolfram Language code: Plot[Hyperfactorial[x], {x, -1, 2}]

Plot the real part of TemplateBox[{z}, Hyperfactorial]:

Wolfram Language code: ComplexContourPlot[Re[Hyperfactorial[z]], {z, -3 - 4I, 3 + 4I}, Contours -> 24]

Plot the imaginary part of TemplateBox[{z}, Hyperfactorial]:

Wolfram Language code: ComplexContourPlot[Im[Hyperfactorial[z]], {z, -3 - 4I, 3 + 4I}, Contours -> 24]

Function Properties  (11)

Real domain of Hyperfactorial:

Wolfram Language code: FunctionDomain[Hyperfactorial[x], x]

Complex domain:

Wolfram Language code: FunctionDomain[Hyperfactorial[z], z, Complexes]

Function range of Hyperfactorial on the contiguous portion of its domain:

Wolfram Language code: FunctionRange[{Hyperfactorial[x], x ≥ -1}, x, y]//N

Hyperfactorial threads elementwise over lists:

Wolfram Language code: Hyperfactorial[{1, 2, 3, 4, 5}]

Hyperfactorial is not an analytic function:

Wolfram Language code: FunctionAnalytic[Hyperfactorial[x], x]

Nor is it meromorphic:

Wolfram Language code: FunctionMeromorphic[Hyperfactorial[x], x]

Hyperfactorial is neither non-increasing nor non-decreasing:

Wolfram Language code: FunctionMonotonicity[{Hyperfactorial[x], x > -1}, x]

Hyperfactorial is not injective:

Wolfram Language code: FunctionInjective[Hyperfactorial[x], x]
Wolfram Language code: Plot[{Hyperfactorial[x], 1}, {x, -1, 2}]

Hyperfactorial is not surjective:

Wolfram Language code: FunctionSurjective[Hyperfactorial[x], x]
Wolfram Language code: Plot[{Hyperfactorial[x], -2}, {x, -1, 2}]

Hyperfactorial is neither non-negative nor non-positive:

Wolfram Language code: FunctionSign[Hyperfactorial[x], x]

Hyperfactorial has both singularities and discontinuities for x≤-1:

Wolfram Language code: FunctionSingularities[Hyperfactorial[x], x]
Wolfram Language code: FunctionDiscontinuities[Hyperfactorial[x], x]

Hyperfactorial is neither convex nor concave:

Wolfram Language code: FunctionConvexity[{Hyperfactorial[x], x > -1}, x]

TraditionalForm formatting:

Wolfram Language code: Hyperfactorial[z]//TraditionalForm

Differentiation  (2)

First derivative with respect to n:

Wolfram Language code: D[Hyperfactorial[n], n]

Higher derivatives with respect to n:

Wolfram Language code: Table[D[Hyperfactorial[n], {n, k}], {k, 1, 3}]//FullSimplify

Plot the higher derivatives with respect to n:

Wolfram Language code: Plot[%, {n, -1, 1}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative"}]

Series Expansions  (3)

Find the Taylor expansion using Series:

Wolfram Language code: Series[Hyperfactorial[x], {x, 0, 3}]//Normal//FullSimplify

Plots of the first three approximations around :

Wolfram Language code: terms = Normal@Table[Series[Hyperfactorial[x], {x, 0, m}], {m, 1, 3}]; Plot[{Hyperfactorial[x], terms}, {x, -5, 5}, PlotRange -> {-20, 20}]

Taylor expansion at a generic point:

Wolfram Language code: Series[Hyperfactorial[x], {x, x0, 2}]//Normal// FullSimplify

Find the series expansion at Infinity:

Wolfram Language code: Series[Hyperfactorial[x], {x, Infinity, 3}]

Applications  (3)

Obtain Glaisher from a limit with Hyperfactorial and Exp functions:

Wolfram Language code: Limit[ (Hyperfactorial[n]/n^Binomial[n + 1, 2]Exp[-(n^2/4)]n^(1/12)), n -> ∞]

The discriminant of the Hermite polynomial can be expressed in terms of the hyperfactorial:

Wolfram Language code: Table[Discriminant[HermiteH[n, x], x], {n, 5}]
Wolfram Language code: Table[8 ^ Binomial[n, 2] Hyperfactorial[n], {n, 5}]

The product of all nonzero elements of the Farey sequence for a few small orders:

Wolfram Language code: Table[Apply[Times, Rest[FareySequence[n]]], {n, 2, 12}]

Compare with a closed-form formula:

Wolfram Language code: Table[Underoverscript[∏, k = 1, n]((BarnesG[Quotient[n, k] + 2]/Hyperfactorial[Quotient[n, k]]))^MoebiusMu[k], {n, 2, 12}]

Properties & Relations  (3)

Use FullSimplify and FunctionExpand to simplify expressions involving Hyperfactorial:

Wolfram Language code: FunctionExpand[Hyperfactorial[n]]
Wolfram Language code: FullSimplify[BarnesG[n + 1]Hyperfactorial[n] == Gamma[n + 1] ^ n, n > 0]

Hyperfactorial is produced in Product:

Wolfram Language code: Product[k ^ k, k]
Wolfram Language code: Product[k ^ (2k), {k, 1, n}]

FindSequenceFunction can recognize the Hyperfactorial sequence:

Wolfram Language code: Table[Hyperfactorial[n], {n, 7}]
Wolfram Language code: FindSequenceFunction[%, n]

Neat Examples  (2)

Determinants of matrices built out of binomial coefficients:

Wolfram Language code: Table[Det[Table[Binomial[i j, i], {i, n}, {j, n}]], {n, 9}]
Wolfram Language code: Table[Hyperfactorial[n], {n, 9}]

Determinants of matrices built out of Bernstein polynomials:

Wolfram Language code: Table[Det[Table[Binomial[n, i]If[n != i, (1 - j)^n - i, 1]j^i, {i, n}, {j, n}]], {n, 9}]
Wolfram Language code: Table[Hyperfactorial[n], {n, 9}]
Wolfram Research (2008), Hyperfactorial, Wolfram Language function, https://reference.wolfram.com/language/ref/Hyperfactorial.html.

Text

Wolfram Research (2008), Hyperfactorial, Wolfram Language function, https://reference.wolfram.com/language/ref/Hyperfactorial.html.

CMS

Wolfram Language. 2008. "Hyperfactorial." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/Hyperfactorial.html.

APA

Wolfram Language. (2008). Hyperfactorial. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Hyperfactorial.html

BibTeX

@misc{reference.wolfram_2026_hyperfactorial, author="Wolfram Research", title="{Hyperfactorial}", year="2008", howpublished="\url{https://reference.wolfram.com/language/ref/Hyperfactorial.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_hyperfactorial, organization={Wolfram Research}, title={Hyperfactorial}, year={2008}, url={https://reference.wolfram.com/language/ref/Hyperfactorial.html}, note=[Accessed: 13-June-2026]}