Wolfram Language & System Documentation Center

JacobiDN

JacobiDN[u,m]

gives the Jacobi elliptic function .

Details

Mathematical function, suitable for both symbolic and numerical manipulation.
, where .
a is doubly periodic function in u with periods and , where is the elliptic integral EllipticK.
JacobiDN is a meromorphic function in both arguments.
For certain special arguments, JacobiDN automatically evaluates to exact values.
JacobiDN can be evaluated to arbitrary numerical precision.
JacobiDN automatically threads over lists.

Examples

open all close all

Basic Examples (4)

Evaluate numerically:

Wolfram Language code: JacobiDN[4., 2 / 3]

Plot the function for several values of the modulus m over a subset of the reals:

Wolfram Language code: Plot[{JacobiDN[x, 1 / 3], JacobiDN[x, 2 / 3], JacobiDN[x, 1]}, {x, -4, 4}]

Plot over a subset of the complexes:

Wolfram Language code: ComplexPlot3D[JacobiDN[z, 1 / 3], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

Series expansions about the origin:

Wolfram Language code: Series[JacobiDN[z, m], {z, 0, 6}]

Wolfram Language code: Series[JacobiDN[z, m], {m, 0, 2}]

Scope (34)

Numerical Evaluation (5)

Evaluate to high precision:

Wolfram Language code: N[JacobiDN[3, 1 / 3], 50]

The precision of the output tracks the precision of the input:

Wolfram Language code: JacobiDN[3, 0.33333333333333333333333333333333333333]

Evaluate for complex arguments:

Wolfram Language code: JacobiDN[2.5 - I, 1 - I]

Evaluate JacobiDN efficiently at high precision:

Wolfram Language code: JacobiDN[3, 0.3`500]//Timing

Wolfram Language code: JacobiDN[3, 0.3`10000];//Timing

Compute average-case statistical intervals using Around:

Wolfram Language code: JacobiDN[2, Around[1 / 2, 0.01]]

Compute the elementwise values of an array:

Wolfram Language code: JacobiDN[-(I π/3), {{1, 0}, {0, 1}}]

Or compute the matrix JacobiDN function using MatrixFunction:

Wolfram Language code: MatrixFunction[JacobiDN[-(I π/3), #]&, {{1, 0}, {0, 1}}]

Specific Values (3)

Simple exact values are generated automatically:

Wolfram Language code: {JacobiDN[z, 0], JacobiDN[z, 1]}

Wolfram Language code: {JacobiDN[0, m], JacobiDN[EllipticK[m] / 2, m], JacobiDN[EllipticK[m], m]}

Some poles of JacobiDN:

Wolfram Language code: {JacobiDN[-I EllipticK[1 - m], m], JacobiDN[I EllipticK[1 - m], m], JacobiDN[ 2EllipticK[m] + I EllipticK[1 - m], m]}

Find a local maximum of JacobiDN as a root of :

Wolfram Language code: xmax = Solve[D[JacobiDN[x, 1 / 3], x] == 0 && 2.5 < x < 4, x][[1, 1, 2]]//Quiet

Wolfram Language code:

Plot[JacobiDN[x, 1 / 3], {x, -2, 6}, PlotRange -> {0, 1.2}, Epilog -> Style[Point[{xmax, JacobiDN[xmax, 1 / 3]}], PointSize[Large], Red]]

Visualization (3)

Plot the JacobiDN functions for various parameter values:

Wolfram Language code: Plot[{JacobiDN[x, -1], JacobiDN[x, 0.5], JacobiDN[x, 1], JacobiDN[x, 1.5], JacobiDN[x, 2]}, {x, -2π, 2π}]

Plot JacobiDN as a function of its parameter :

Wolfram Language code: Plot[{JacobiDN[1, m], JacobiDN[2, m], JacobiDN[3, m]}, {m, -8, 8}]

Plot the real part of :

Wolfram Language code: ComplexContourPlot[Re[JacobiDN[z, 1 / 2]], {z, -8 - 8 I, 8 + 8 I}, IconizedObject[«PlotOptions»]]

Plot the imaginary part of :

Wolfram Language code: ComplexContourPlot[Im[JacobiDN[z, 1 / 2]], {z, -8 - 8 I, 8 + 8 I}, IconizedObject[«PlotOptions»]]

Function Properties (8)

JacobiDN is -periodic along the real axis:

Wolfram Language code: JacobiDN[x, m] == JacobiDN[x + 2EllipticK[m], m]

JacobiDN is -periodic along the imaginary axis:

Wolfram Language code: JacobiDN[x, m] == JacobiDN[x + 4I EllipticK[1 - m], m]

JacobiDN is an even function in its first argument:

Wolfram Language code: JacobiDN[-x, m] == JacobiDN[x, m]

JacobiDN is an analytic function:

Wolfram Language code: FunctionAnalytic[JacobiDN[x, m], {x, m}]

It has no singularities or discontinuities:

Wolfram Language code: FunctionSingularities[JacobiDN[x, m], {x, m}]

Wolfram Language code: FunctionDiscontinuities[JacobiDN[x, m], {x, m}]

is neither nondecreasing nor nonincreasing:

Wolfram Language code: FunctionMonotonicity[JacobiDN[x, 3], x]

is not injective for any fixed :

Wolfram Language code: FunctionInjective[JacobiDN[x, m], x, Assumptions -> m > 1]

Wolfram Language code: Plot[{JacobiDN[x, 3], .5}, {x, -5, 5}]

is not surjective for any fixed :

Wolfram Language code: FunctionSurjective[JacobiDN[x, m], x, Assumptions -> m∈Reals]

Wolfram Language code: Plot[{JacobiDN[x, 3], 1.5}, {x, -5, 5}]

is non-negative for :

Wolfram Language code: FunctionSign[JacobiDN[x, m], x, Assumptions -> m <= 1]

In general, it is neither non-negative nor non-positive:

Wolfram Language code: FunctionSign[JacobiDN[x, m], {x, m}]

JacobiDN is neither convex nor concave:

Wolfram Language code: FunctionConvexity[JacobiDN[x, m], {x, m}]

Differentiation (3)

First derivative:

Wolfram Language code: D[JacobiDN[x, m], x]

Higher derivatives:

Wolfram Language code: derivs = Table[D[JacobiDN[x, m], {x, n}], {n, 1, 4}]

Plot higher derivatives for :

Wolfram Language code:

Plot[Evaluate[derivs /. m -> 1 / 3], {x, -5, 5}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]

Derivative with respect to :

Wolfram Language code: D[JacobiDN[x, m], m]

Integration (3)

Indefinite integral of JacobiDN:

Wolfram Language code: Integrate[JacobiDN[z, m], z]

Definite integral of JacobiDN over the interval centered at the origin:

Wolfram Language code: Integrate[JacobiDN[z, 1 / 3], {z, -1, 1}]

This is twice the integral over half the interval:

Wolfram Language code: 2Integrate[JacobiDN[z, 1 / 3], {z, 0, 1}]

More integrals:

Wolfram Language code: Integrate[JacobiDN[z, m]JacobiCN[z, m], z]

Wolfram Language code: Integrate[(JacobiDN[t, m]/1 + JacobiCN[t, m]), t]

Wolfram Language code: Integrate[JacobiDN[z, m] ^ 3, z]

Series Expansions (3)

Taylor expansion for :

Wolfram Language code: Series[JacobiDN[x, 1 / 3], {x, 0, 7}]

Plot the first three approximations for around :

Wolfram Language code:

terms = Normal@Table[Series[JacobiDN[x, 1 / 3], {x, 0, n}], {n, 2, 7, 2}];
Plot[{JacobiDN[x, 1 / 3], terms}, {x, -1.5, 1.5}]

Taylor expansion for :

Wolfram Language code: Series[JacobiDN[1, m], {m, 0, 3}]

Plot the first three approximations for around :

Wolfram Language code:

terms = Normal@Table[Series[JacobiDN[1, m], {m, 0, n}], {n, 1, 3}];
Plot[{JacobiDN[1, m], terms}, {m, -8, 8}]

JacobiDN can be applied to a power series:

Wolfram Language code: JacobiDN[ArcSin[x] + O[x] ^ 8, m]//Simplify

Function Identities and Simplifications (3)

Parity transformations and periodicity relations are automatically applied:

Wolfram Language code: JacobiDN[-u, m]

Wolfram Language code: JacobiDN[u + 2 EllipticK[m] + 4I EllipticK[1 - m], m]

Identity involving JacobiSN:

Wolfram Language code: JacobiDN[z, m]^2 + m JacobiSN[z, m]^2//FullSimplify

Argument simplifications:

Wolfram Language code: JacobiDN[z + EllipticK[m], m]

Wolfram Language code: JacobiDN[z + I EllipticK[1 - m], m]

Function Representations (3)

Differential representation:

Wolfram Language code: D[JacobiAmplitude[z, m], z]

Relation to other Jacobi elliptic functions:

Wolfram Language code: JacobiDN[z, m] == (1/JacobiND[z, m])//FullSimplify

Wolfram Language code: JacobiDS[z, m] JacobiSN[z, m]//FullSimplify

TraditionalForm formatting:

Wolfram Language code: JacobiDN[z, m]//TraditionalForm

Applications (9)

Cartesian coordinates of a pendulum:

Wolfram Language code:

x[t_] = 2ℓ Sin[(φ0/2)]JacobiSN[tSqrt[(g/ℓ)] , Sin[(φ0/2)]^2]JacobiDN[t Sqrt[(g/ℓ)] , Sin[(φ0/2)]^2];y[t_] = -ℓ(2 JacobiDN[tSqrt[(g/ℓ)], Sin[(φ0/2)]^2] ^ 2 - 1);

Plot the time dependence of the coordinates:

Wolfram Language code: Plot[Evaluate[{x[t], y[t]} /. {ℓ -> 1, g -> 9.81, φ0 -> Pi / 4}], {t, 0, 10}]

Plot the trajectory:

Wolfram Language code: ParametricPlot[Evaluate[{x[t], y[t]} /. {ℓ -> 1, g -> 9.81, φ0 -> Pi / 2}], {t, 0, 10}]

Uniformization of a Fermat cubic :

Wolfram Language code:

a[u_] := With[{m = Sin[(Pi/12)] ^ 2}, (2 3^1 / 4JacobiDN[u, m]JacobiSN[u, m] - (1 - JacobiCN[u, m])^2) / (2 3^1 / 4JacobiDN[u, m]JacobiSN[u, m] + (1 - JacobiCN[u, m])^2)];

Wolfram Language code:

b[u_] := With[{m = Sin[(Pi/12)] ^ 2}, (2^11 / 6Sqrt[1 - m](1 - JacobiCN[u, m])(1 + Sqrt[(m/1 - m)]JacobiCN[u, m])) / (2 3^1 / 4JacobiDN[u, m]JacobiSN[u, m] + (1 - JacobiCN[u, m])^2)]

Check:

Wolfram Language code: a[u] ^ 3 + b[u] ^ 3 /. u -> RandomComplex[WorkingPrecision -> 20]

Conformal map from a unit triangle to the unit disk:

Wolfram Language code:

w[z_] := With[{ζ = z(Gamma[1 / 3]^3/2^1 / 3 3^1 / 4 π), m = Sin[(π/12)] ^ 2}, 2^11 / 6Sqrt[1 - m](1 - JacobiCN[ζ, m])(1 + Sqrt[(m/1 - m)]JacobiCN[ζ, m]) / 
	(2 3^1 / 4JacobiDN[ζ, m]JacobiSN[ζ, m] + (1 - JacobiCN[ζ, m]) ^ 2)]

Show points before and after the map:

Wolfram Language code:

trianglePoints = With[{t = E ^ (2 Pi I / 3)}, Flatten[Table[α / 8. Table[N[#1 + j / 16(#2 - #1)], {j, 0, 16}]&@@@({{1, t}, {t, 1 / t}, {1 / t, 1}} / Sqrt[3]), {α, 1, 8}]]];

Wolfram Language code:

Row[{Graphics[Point[{Re[#], Im[#]}]& /@ trianglePoints, Frame  -> True, ImageSize -> Small], 
	Graphics[Point[{Re[#], Im[#]}]& /@ w[trianglePoints], Frame  -> True, ImageSize -> Small]}, Spacer[20]]

Solution of Nahm equations:

Wolfram Language code:

Subscript[T, 1][z_] = -Sqrt[m ]JacobiSN[z, m] {{0, 1, 0}, {1, 0, 1}, {0, 1, 0}} / Sqrt[2];
Subscript[T, 2] [z_] = I Sqrt[m] JacobiCN[z, m] {{0, I, 0}, {-I, 0, I}, {0, -I, 0}} / Sqrt[2];
Subscript[T, 3][z_]   = I  JacobiDN[z, m] {{1, 0, 0}, {0, 0, 0}, {0, 0, -1}};

Check that the solutions fulfill the Nahm equations:

Wolfram Language code: Subsuperscript[T, 1, ′][z] - I (Subscript[T, 2][z]. Subscript[T, 3][z] - Subscript[T, 3][z].Subscript[T, 2][z])

Wolfram Language code: Subsuperscript[T, 2, ′][z] - I (Subscript[T, 3][z].Subscript[T, 1][z] - Subscript[T, 1][z]. Subscript[T, 3][z])

Wolfram Language code: Subsuperscript[T, 3, ′][z] - I (Subscript[T, 1][z]. Subscript[T, 2][z] - Subscript[T, 2][z].Subscript[T, 1][z])

Periodic solution of the nonlinear Schrödinger equation :

Wolfram Language code: ψ[x_, t_] := r Exp[I(p x - (p ^ 2 - (2 - k ^ 2)r ^ 2)t)]JacobiDN[r x - 2 p r t, k ^ 2]

Plot the solution:

Wolfram Language code: Plot3D[Evaluate[Abs[ψ[x, t]] ^ 2 /. {r -> 2, p -> 1 / 3, k -> 1 / 2}], {x, -4, 4}, {t, 0, 2}]

Parametrize a lemniscate by arc length [more info]:

Wolfram Language code:

lemniscate[s_] := {JacobiCN[Sqrt[2]s, 1 / 2]JacobiDN[Sqrt[2]s, 1 / 2], JacobiCN[Sqrt[2]s, 1 / 2]JacobiSN[Sqrt[2]s, 1 / 2] / Sqrt[2]}

Show arc length parametrization and classical parametrization:

Wolfram Language code: r[θ_] := If[Cos[2θ] > 0, Sqrt[Cos[2θ]], 0];

Wolfram Language code:

Row[{ParametricPlot[{r[θ]Cos[θ], r[θ]Sin[θ]}, {θ, -Pi, Pi}, ImageSize -> Small], 
	ParametricPlot[Evaluate[lemniscate[s]], {s, 0, Gamma[1 / 4] ^ 2 / Sqrt[2Pi]}, ImageSize -> Small]}, Spacer[20]]

Zero modes of the periodic supersymmetric partner potentials:

Wolfram Language code:

Subscript[V,  + ][z_] := 2 - m + 2(m - 1) / JacobiDN[z, m]^2
Subscript[ψ,  + ][z_] := 1 / JacobiDN[z, m]

Wolfram Language code:

Subscript[V,  - ][z_] := 2 - m - 2JacobiDN[z, m]^2
Subscript[ψ,  - ][z_] := JacobiDN[z, m]

Plot the zero modes:

Wolfram Language code:

Row[{Plot[Evaluate[{Subscript[V,  + ][z], Subscript[ψ,  + ][z]} /. m -> 1 / 2], {z, -4, 4}, ImageSize -> Small], 
	Plot[Evaluate[{Subscript[V,  - ][z], Subscript[ψ,  - ][z]} /. m -> 1 / 2], {z, -4, 4}, ImageSize -> Small]}, Spacer[20]]

Complex parametrization of a "sphere":

Wolfram Language code:

ellipticSphere[{α_, β_}, m_] := { m^1 / 2JacobiSN[α, m]JacobiSN[β, m], I (m^1 / 2/(1 - m)^1 / 2) JacobiCN[α, m]JacobiCN[β, m], (1/(1 - m)^1 / 2) JacobiDN[α, m]JacobiDN[β, m]}

Plot real and imaginary parts:

Wolfram Language code:

Row[{Plot3D[Evaluate[Re[ellipticSphere[{α, β}, 0.3]]], {α, 0, 1}, {β, 1, 2}, ImageSize -> Small], 
	Plot3D[Evaluate[Im[ellipticSphere[{α, β}, 0.3]]], {α, 0, 1}, {β, 1, 2}, ImageSize -> Small]}]

Parametrization of a Mylar balloon (two flat sheets of plastic sewn together at their circumference and then inflated):

Wolfram Language code:

With[{kk = N[π CarlsonRK[2, 4]]}, 
	ParametricPlot3D[{JacobiCN[u, (1/2)]Cos[v], JacobiCN[u, (1/2)]Sin[v], 
	(1/Sqrt[2])(u - (1/3)JacobiSN[u, (1/2)]^3CarlsonRD[JacobiCN[u, (1/2)]^2, JacobiDN[u, (1/2)]^2, 1])}, 
	{u, -kk, kk}, {v, -π, π}, Exclusions -> None, PlotRange -> All]]

Properties & Relations (3)

Compose with inverse functions:

Wolfram Language code: {JacobiDN[InverseJacobiDN[z, m], m], InverseJacobiDN[JacobiDN[z, m], m]}

Use PowerExpand to disregard multivaluedness of the inverse function:

Wolfram Language code: PowerExpand[%]

Evaluate as a result of applying D to JacobiAmplitude:

Wolfram Language code: D[JacobiAmplitude[z, m], z]

Solve a transcendental equation:

Wolfram Language code: Solve[JacobiDN[x, m]^2 + 3JacobiDN[x, m] == a, x]//Quiet

Possible Issues (2)

Machine-precision input is insufficient to give the correct answer:

Wolfram Language code: JacobiDN[10. ^ 15, 4 / 7]

Wolfram Language code: N[JacobiDN[10 ^ 15, 4 / 7], 20]

Currently only simple simplification rules are built in for Jacobi functions:

Wolfram Language code: JacobiDN[u, m] ^ 2 + m JacobiSN[u, m] ^ 2 - 1//FullSimplify

Wolfram Language code: JacobiDN[u, m]JacobiNS[u, m]JacobiSD[u, m]//FullSimplify

Top

More Learning

Tech Support

Wolfram Solutions

Wolfram Solutions For Education

Get Started

Grow Your Skills

Work with Us

Educational Programs for Adults

Educational Programs for Youth

Read

JacobiDN

Details

Examples

Basic Examples (4)

Scope (34)

Numerical Evaluation (5)

Specific Values (3)

Visualization (3)

Function Properties (8)

Differentiation (3)

Integration (3)

Series Expansions (3)

Function Identities and Simplifications (3)

Function Representations (3)

Applications (9)

Properties & Relations (3)

Possible Issues (2)

Text

CMS

APA

BibTeX

BibLaTeX

JacobiDN

Details

Examples

Basic Examples (4)

Scope (34)

Numerical Evaluation (5)

Specific Values (3)

Visualization (3)

Function Properties (8)

Differentiation (3)

Integration (3)

Series Expansions (3)

Function Identities and Simplifications (3)

Function Representations (3)

Applications (9)

Properties & Relations (3)

Possible Issues (2)

See Also

Tech Notes

Related Guides

Related Links

History

Text

CMS

APA

BibTeX

BibLaTeX