Wolfram Language & System Documentation Center

JacobiEpsilon

JacobiEpsilon[u,m]

gives the Jacobi epsilon function .

Details

Mathematical function, suitable for both symbolic and numerical manipulation.
$TemplateBox[{u, m}, JacobiEpsilon]=int_0^uTemplateBox[{z, m}, JacobiDN]^2dz$ .
Argument conventions for elliptic integrals are discussed in "Elliptic Integrals and Elliptic Functions".
JacobiEpsilon is a meromorphic function in both arguments.
For certain special arguments, JacobiEpsilon automatically evaluates to exact values.
JacobiEpsilon can be evaluated to arbitrary numerical precision.
JacobiEpsilon automatically threads over lists.

Examples

open all close all

Basic Examples (3)

Evaluate numerically:

Wolfram Language code: JacobiEpsilon[2.5, 0.5]

Plot along the real axis:

Wolfram Language code: Plot[JacobiEpsilon[u, 3 / 4], {u, -3, 3}]

Series expansion about the origin:

Wolfram Language code: Series[JacobiEpsilon[u, m], {u, 0, 7}]

Wolfram Language code: Series[JacobiEpsilon[u, m], {m, 0, 1}]

Scope (23)

Numerical Evaluation (4)

Evaluate to high precision:

Wolfram Language code: N[JacobiEpsilon[2, 1 / 3], 50]

The precision of the output tracks the precision of the input:

Wolfram Language code: JacobiEpsilon[2, 1 / 3`55]

Evaluate for complex arguments:

Wolfram Language code: JacobiEpsilon[2.3 + 0.7I, 0.5]

Wolfram Language code: JacobiEpsilon[2.3 + 0.7I, 0.5 + I]

Evaluate JacobiEpsilon efficiently at high precision:

Wolfram Language code: JacobiEpsilon[2, 0.3`500]//Timing

Wolfram Language code: JacobiEpsilon[2, 0.3`10000];//Timing

JacobiEpsilon threads elementwise over lists:

Wolfram Language code: JacobiEpsilon[{u1, u2}, m]

Specific Values (3)

Simple exact values are generated automatically:

Wolfram Language code: {JacobiEpsilon[u, 0], JacobiEpsilon[u, 1]}

Wolfram Language code: {JacobiEpsilon[0, m], JacobiEpsilon[EllipticK[m] / 2, m], JacobiEpsilon[EllipticK[m], m]}

Wolfram Language code: {JacobiEpsilon[I EllipticK[1 - m], m], JacobiEpsilon[EllipticK[m] + I EllipticK[1 - m], m]}

JacobiEpsilon has poles coinciding with the poles of JacobiDN:

Wolfram Language code: Asymptotic[Table[JacobiEpsilon[u + (2r + 1)I EllipticK[1 - m] + 2s EllipticK[m], m], {r, -1, 1}, {s, -1, 1}], u -> 0]

Wolfram Language code: Asymptotic[Table[JacobiDN[u + (2r + 1)I EllipticK[1 - m] + 2s EllipticK[m], m], {r, -1, 1}, {s, -1, 1}], u -> 0]

Find a root of JacobiEpsilon[u,]=2:

Wolfram Language code: {xroot} = x /. NSolve[JacobiEpsilon[x, 2 / 3] == 2 && 1 < x < 5, x]

Wolfram Language code:

Plot[JacobiEpsilon[x, 2 / 3], {x, -π, 2π}, Epilog -> Style[Point[{xroot, JacobiEpsilon[xroot, 2 / 3]}], PointSize[Large], Red]]

Visualization (3)

Plot the JacobiEpsilon functions for various values of parameter m:

Wolfram Language code: Plot[{JacobiEpsilon[u, -1], JacobiEpsilon[u, 0], JacobiEpsilon[u, 2 / 3], JacobiEpsilon[u, 4]}, {u, -Pi, Pi}]

Plot JacobiEpsilon as a function of its parameter m:

Wolfram Language code: Plot[{JacobiEpsilon[1, m], JacobiEpsilon[2, m], JacobiEpsilon[3, m]}, {m, -7, 10}]

Plot the real part of JacobiEpsilon[x+y,]:

Wolfram Language code: ContourPlot[Re[JacobiEpsilon[x + I y, 1 / 2]], {x, -4, 4}, {y, -4, 4}, IconizedObject[«PlotOptions»]]

Plot the imaginary part of JacobiEpsilon[x+y,]:

Wolfram Language code: ContourPlot[Im[JacobiEpsilon[x + I y, 1 / 2]], {x, -4, 4}, {y, -4, 4}, IconizedObject[«PlotOptions»]]

Function Properties (2)

JacobiEpsilon is additive quasiperiodic with quasiperiod :

Wolfram Language code: JacobiEpsilon[u + 2 llipticK[m], m]

JacobiEpsilon is additive quasiperiodic with quasiperiod :

Wolfram Language code: JacobiEpsilon[u + 2I EllipticK[1 - m], m]

JacobiEpsilon is an odd function:

Wolfram Language code: JacobiEpsilon[-u, m]

Differentiation (3)

First derivative:

Wolfram Language code: D[JacobiEpsilon[u, m], u]

Higher-order derivatives:

Wolfram Language code: derivs = Table[D[JacobiEpsilon[u, m], {u, n}], {n, 1, 4}]//FullSimplify

Plot derivatives for parameter :

Wolfram Language code:

Plot[Evaluate[derivs /. m -> 1 / 3], {u, -6, 6}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]

Derivative with respect to parameter m:

Wolfram Language code: D[JacobiEpsilon[u, m], m]

Integration (1)

Indefinite integral of JacobiEpsilon:

Wolfram Language code: Integrate[JacobiEpsilon[u, m], u]

Series Expansions (3)

Series expansion for JacobiEpsilon[u,]:

Wolfram Language code: Series[JacobiEpsilon[u, 1 / 3], {u, 0, 7}]

Plot the first three approximations for JacobiEpsilon[u,] around :

Wolfram Language code:

terms = Normal@Table[Series[JacobiEpsilon[u, 1 / 3], {u, 0, n}], {n, 2, 7, 2}];
Plot[{JacobiEpsilon[u, 1 / 3], terms}, {u, -2, 2}]

Taylor expansion for JacobiEpsilon[2,m]:

Wolfram Language code: Series[JacobiEpsilon[2, m], {m, 0, 3}]

Plot the first three series approximations for JacobiEpsilon[2,m] around :

Wolfram Language code:

terms = Normal@Table[Series[JacobiEpsilon[2, m], {m, 0, n}], {n, 1, 3}];
Plot[{JacobiEpsilon[2, m], terms}, {m, -2, 2}]

JacobiEpsilon can be applied to power series:

Wolfram Language code: JacobiEpsilon[JacobiAmplitude[ϕ, m] + O[ϕ] ^ 4, m]

Function Identities and Simplifications (2)

Parity transformation and quasiperiodicity relations are automatically applied:

Wolfram Language code: JacobiEpsilon[-u, m]

Wolfram Language code: JacobiEpsilon[u + 2EllipticK[m] + 2I EllipticK[1 - m], m]

Automatic argument simplifications:

Wolfram Language code: JacobiEpsilon[u + EllipticK[m], m]

Wolfram Language code: JacobiEpsilon[u + I EllipticK[1 - m], m]

Function Representations (2)

JacobiEpsilon is related to the elliptic integral of the second kind:

Wolfram Language code: JacobiEpsilon[EllipticF[ϕ, m], m]

TraditionalForm formatting:

Wolfram Language code: JacobiEpsilon[u, m]//TraditionalForm

Applications (7)

JacobiEpsilon arises in derivatives of Jacobi elliptic functions with respect to parameter :

Wolfram Language code: D[JacobiSN[u, m], m]

Plot JacobiEpsilon over the complex plane:

Wolfram Language code:

Plot3D[Im[JacobiEpsilon[x + I y, 1 / 3]], {x, -4EllipticK[1 / 3], 4EllipticK[1 / 3]}, {y, -4EllipticK[2 / 3], 4EllipticK[2 / 3]}]

Motion of a charged particle in a magnetic field:

Wolfram Language code:

With[{ω = Sqrt[v0 γ / 2]}, 
	x[t_] = 2ω / γ JacobiSN[ω t, -1];
	y[t_] = 2ω / γ(ω t - JacobiEpsilon[ω t, -1])
	];

Verify that it solves Newton's equation of motion with Lorentz force:

Wolfram Language code: {x''[t], y''[t], 0} - γ Cross[{x'[t], y'[t], 0}, {0, 0, x[t]}]//FullSimplify

Plot particle trajectories for several different initial velocities:

Wolfram Language code:

ParametricPlot[Evaluate[Table[{x[t], y[t]} /. γ -> 1, {v0, 1 / 4, 1, 1 / 4}]], {t, 0, 12}, IconizedObject[«PlotOptions»]]

Parameterization of a rotating elastic rod (fixed at the origin):

Wolfram Language code:

y[F_, β_, m_][ℓ_] = -Integrate[2Sqrt[m]JacobiSN[F + β σ, m]JacobiDN[F + β σ, m], {σ, 0, ℓ}, GenerateConditions -> False]

Wolfram Language code: z[F_, β_, m_][ℓ_] = Integrate[1 - 2JacobiDN[F + β σ, m]^2, {σ, 0, ℓ}, GenerateConditions -> False]

Plot the shape of the deformed rod:

Wolfram Language code: ParametricPlot[Evaluate[{z[1.1, 1, 0.96][ℓ], y[1.1, 1, 0.96][ℓ]}], {ℓ, 0, 3}]

The parameterization parameter is the length of the rod:

Wolfram Language code: With[{F = 1.1, β = 1, m = 0.96, ℓ = 2.5}, ArcLength[{z[F, β, m][t], y[F, β, m][t]}, {t, 0, ℓ}]]

Parameterization of Costa's minimal surface [MathWorld]:

Wolfram Language code:

x[w_, m_] := With[{c = 2EllipticK[m]}, Re[((π/2) + (c^2/4))w - (c/2)(JacobiEpsilon[c w, m] + JacobiCN[c w, m]JacobiDS[c w, m]) - (π/4c)JacobiSD[c w, m](JacobiNC[c w, m] + JacobiCN[c w, m])]];

Wolfram Language code:

y[w_, m_] := With[{c = 2EllipticK[m]}, Im[((π/2) - (c^2/4))w + (c/2)(JacobiEpsilon[c w, m] + JacobiCN[c w, m]JacobiDS[c w, m]) - (π/4c)JacobiSD[c w, m](JacobiNC[c w, m] + JacobiCN[c w, m])]];

Wolfram Language code: z[w_, m_] := With[{c = 2EllipticK[m]}, Sqrt[(π/8)]Log[Abs[JacobiCN[c w, m]^2]]];

Wolfram Language code: ParametricPlot3D[With[{w = u + I v}, {x[w, 1 / 2], y[w, 1 / 2], z[w, 1 / 2]}], {u, 0, 1}, {v, 0, 1}, Mesh -> False]

Parameterization of the Chen–Gackstatter minimal surface:

Wolfram Language code:

x[w_] := With[{c = 2EllipticK[(1/2)]}, Re[(π + (c^2/2))w - c JacobiEpsilon[c w, (1/2)] + JacobiCS[c w, (1/2)]JacobiDS[c w, (1/2)]((2 π/c)JacobiNS[c w, (1/2)] - c JacobiSN[c w, (1/2)])]];

Wolfram Language code:

y[w_] := With[{c = 2EllipticK[(1/2)]}, Im[(π - (c^2/2))w + c JacobiEpsilon[c w, (1/2)] + JacobiCS[c w, (1/2)] JacobiDS[c w, (1/2)]((2 π/c)JacobiNS[c w, (1/2)] + c JacobiSN[c w, (1/2)])]];

Wolfram Language code: z[w_] := With[{c = 2EllipticK[(1/2)]}, Sqrt[6 π] Re[JacobiNS[c w, (1/2)]^2] - Sqrt[(3π/2)]];

Wolfram Language code: ParametricPlot3D[With[{w = r E^I θ}, {x[w], y[w], z[w]}], {r, 1 / 5, 4 / 5}, {θ, -π, π}, Mesh -> False]

Construct nonperiodic solutions of the Lamé differential equation from periodic solutions:

Wolfram Language code:

ν = 1;j = 1;m = 1 / 2;
fsol = FunctionExpand[LameC[ν, j, x, m]]Integrate[FunctionExpand[LameC[ν, j, x, m] ^ -2], x]

Wolfram Language code: gsol = FunctionExpand[LameS[ν, j, x, m]]Integrate[FunctionExpand[LameS[ν, j, x, m] ^ -2], x]

Verify that they satisfy the Lamé equation:

Wolfram Language code: D[fsol, {x, 2}] + (LameEigenvalueA[ν, j, m] - ν(ν + 1)m JacobiSN[x, m]^2)fsol == 0//FullSimplify

Wolfram Language code: D[gsol, {x, 2}] + (LameEigenvalueB[ν, j, m] - ν(ν + 1)m JacobiSN[x, m]^2)gsol == 0//FullSimplify

Plot all the solutions together:

Wolfram Language code: Plot[{LameC[ν, j, x, m], fsol, LameS[ν, j, x, m], gsol}//Evaluate, {x, -4EllipticK[m], 4EllipticK[m]}]

Properties & Relations (3)

JacobiEpsilon is defined as a definite integral of $TemplateBox[{u, m}, JacobiDN]^2$ :

Wolfram Language code: Integrate[JacobiDN[𝓊, m] ^ 2, {𝓊, 0, u}]

JacobiEpsilon[u,m] is a meromorphic extension of :

Wolfram Language code:

With[{m = 2 / 3}, Plot[{Im[JacobiEpsilon[1 + I t, m]], Im[EllipticE[JacobiAmplitude[1 + I t, m], m]]}, {t, -7, 7}, IconizedObject[«PlotOptions»]]]

JacobiEpsilon is related to JacobiZN:

Wolfram Language code: JacobiZN[u, m]//FunctionExpand

Top

More Learning

Tech Support

Wolfram Solutions

Wolfram Solutions For Education

Get Started

Grow Your Skills

Work with Us

Educational Programs for Adults

Educational Programs for Youth

Read

JacobiEpsilon

Details

Examples

Basic Examples (3)

Scope (23)

Numerical Evaluation (4)

Specific Values (3)

Visualization (3)

Function Properties (2)

Differentiation (3)

Integration (1)

Series Expansions (3)

Function Identities and Simplifications (2)

Function Representations (2)

Applications (7)

Properties & Relations (3)

Text

CMS

APA

BibTeX

BibLaTeX

JacobiEpsilon

Details

Examples

Basic Examples (3)

Scope (23)

Numerical Evaluation (4)

Specific Values (3)

Visualization (3)

Function Properties (2)

Differentiation (3)

Integration (1)

Series Expansions (3)

Function Identities and Simplifications (2)

Function Representations (2)

Applications (7)

Properties & Relations (3)

See Also

Related Guides

History

Text

CMS

APA

BibTeX

BibLaTeX