Wolfram Language & System Documentation Center

JacobiZN

JacobiZN[u,m]

gives the Jacobi zeta function .

Details

Mathematical function, suitable for both symbolic and numerical manipulation.
$TemplateBox[{u, m}, JacobiZN]=int_0^u(TemplateBox[{z, m}, JacobiDN]^2-TemplateBox[{m}, EllipticE]/TemplateBox[{m}, EllipticK])dz$ .
Argument conventions for elliptic integrals are discussed in "Elliptic Integrals and Elliptic Functions".
is a singly periodic function in with the period , where is the elliptic integral EllipticK. »
JacobiZN is a meromorphic function in both arguments.
For certain special arguments, JacobiZN automatically evaluates to exact values.
JacobiZN can be evaluated to arbitrary numerical precision.
JacobiZN automatically threads over lists.

Examples

open all close all

Basic Examples (3)

Evaluate numerically:

Wolfram Language code: JacobiZN[1.23, 0.3]

Plot along the real axis:

Wolfram Language code: Plot[JacobiZN[u, 3 / 5], {u, -10, 10}]

Series expansion about the origin:

Wolfram Language code: Series[JacobiZN[u, m], {u, 0, 7}]

Wolfram Language code: Series[JacobiZN[u, m], {m, 0, 2}]

Scope (24)

Numerical Evaluation (5)

Evaluate to high precision:

Wolfram Language code: N[JacobiZN[1, 1 / 2], 50]

The precision of the output tracks the precision of the input:

Wolfram Language code: JacobiZN[1, 1 / 2`55]

Evaluate for complex arguments:

Wolfram Language code: JacobiZN[0.8 - 0.2I, 0.5]

Wolfram Language code: JacobiZN[2.3 + 0.7I, 0.5 + I]

Evaluate JacobiZN efficiently at higher precision:

Wolfram Language code: JacobiZN[2, 0.3`500]//Timing

Wolfram Language code: JacobiZN[2, 0.3`10000];//Timing

Compute average-case statistical intervals using Around:

Wolfram Language code: JacobiZN[2, Around[1 / 2, 0.01]]

Compute the elementwise values of an array:

Wolfram Language code: JacobiZN[-(π/3)I, {{1, 0}, {0, 1}}]

Or compute the matrix JacobiZN function using MatrixFunction:

Wolfram Language code: MatrixFunction[JacobiZN[-(π/3)I, #]&, {{1, 0}, {0, 1}}]

Specific Values (3)

Simple exact values are generated automatically:

Wolfram Language code: {JacobiZN[u, 0], JacobiZN[u, 1]}

Wolfram Language code: {JacobiZN[0, m], JacobiZN[EllipticK[m] / 2, m], JacobiZN[EllipticK[m], m]}

JacobiZN has poles coinciding with poles of JacobiDN:

Wolfram Language code: Table[JacobiZN[(2r + 1)I EllipticK[1 - m] + 2 EllipticK[m], m], {r, -1, 1}, {s, -1, 1}]

Find a root of JacobiZN[u,2/3]=1/7:

Wolfram Language code: xroot = x /. FindRoot[JacobiZN[x, 2 / 3] == 1 / 7, {x, 0, 1 / 2}]

Wolfram Language code: Plot[JacobiZN[x, 2 / 3], {x, -π, 2π}, Epilog -> Style[Point[{xroot, JacobiZN[xroot, 2 / 3]}], PointSize[Large], Red]]

Visualization (3)

Plot JacobiZN functions for various values of parameter m:

Wolfram Language code: Plot[{JacobiZN[u, -1], JacobiZN[u, 1 / 3], JacobiZN[u, 1]}, {u, -Pi, Pi}]

Plot JacobiZN as a function of its parameter m:

Wolfram Language code: Plot[{JacobiZN[1 / 4, m], JacobiZN[1, m], JacobiZN[2, m]}, {m, -4, 1}]

Plot the real part of JacobiZN[x+y,1/2]:

Wolfram Language code: ContourPlot[Re[JacobiZN[x + I y, 1 / 2]], {x, -4, 4}, {y, -4, 4}, IconizedObject[«PlotOptions»]]

Plot the imaginary part of JacobiZN[x+y,1/2]:

Wolfram Language code: ContourPlot[Im[JacobiZN[x + I y, 1 / 2]], {x, -4, 4}, {y, -4, 4}, IconizedObject[«PlotOptions»]]

Function Properties (2)

JacobiZN is periodic with period :

Wolfram Language code: JacobiZN[u + 2EllipticK[m], m]

JacobiZN is additive quasiperiodic with a quasiperiod of :

Wolfram Language code: JacobiZN[u + 2I EllipticK[1 - m], m]

JacobiZN is an odd function:

Wolfram Language code: JacobiZN[-u, m]

Differentiation (3)

First derivative:

Wolfram Language code: D[JacobiZN[u, m], u]

Higher-order derivatives:

Wolfram Language code: derivs = Table[D[JacobiZN[u, m], {u, n}], {n, 1, 4}]//FullSimplify

Plot derivatives for parameter :

Wolfram Language code:

Plot[Evaluate[derivs /. m -> 1 / 3], {u, -6, 6}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]

Derivative with respect to parameter m:

Wolfram Language code: D[JacobiZN[u, m], m]

Integration (1)

Indefinite integral of JacobiZN:

Wolfram Language code: Integrate[JacobiZN[u, m], u]

Series Expansions (3)

Series expansion for JacobiZN[u,1/3] around :

Wolfram Language code: Series[JacobiZN[u, 1 / 3], {u, 0, 7}]

Plot three approximations for JacobiZN[u,1/3]:

Wolfram Language code:

terms = Normal@Table[Series[JacobiZN[u, 1 / 3], {u, 0, n}], {n, {3, 5, 7}}];
Plot[{JacobiZN[u, 1 / 3], terms}, {u, -2, 2}]

Taylor series for JacobiZN[2,m] around :

Wolfram Language code: Series[JacobiZN[2, m], {m, 0, 3}]

Plot series approximations for JacobiZN[2,m]:

Wolfram Language code:

terms = Normal@Table[Series[JacobiZN[2, m], {m, 0, n}], {n, 1, 3}];
Plot[{JacobiZN[2, m], terms}, {m, -2, 2}]

JacobiZN can be applied to power series:

Wolfram Language code: JacobiZN[JacobiAmplitude[ϕ, m] + O[ϕ] ^ 4, m]

Function Identities and Simplifications (2)

Parity transformation and quasiperiodicity relations are automatically applied:

Wolfram Language code: JacobiZN[-u, m]

Wolfram Language code: JacobiZN[u + 2EllipticK[m], m]

Wolfram Language code: JacobiZN[u + 2I EllipticK[1 - m], m]

Automatic argument simplification:

Wolfram Language code: JacobiZN[u + EllipticK[m], m]

Wolfram Language code: JacobiZN[u + I EllipticK[1 - m], m]

Function Representations (2)

JacobiZN is related to JacobiZeta function:

Wolfram Language code: JacobiZN[EllipticF[ϕ, m], m]

TraditionalForm formatting:

Wolfram Language code: JacobiZN[u, m]//TraditionalForm

Applications (4)

Express derivatives of Neville theta functions:

Wolfram Language code: D[NevilleThetaN[u, m], u]

Wolfram Language code: D[NevilleThetaN[u, m], m]

Supersymmetric zero‐energy solution of the Schrödinger equation in a periodic potential:

Wolfram Language code: w[x_] := m^2JacobiSN[x, m]^2JacobiCD[x, m]^2 - (2 - m - (2 EllipticE[m]/EllipticK[m]));

Wolfram Language code: v[x_] = w[x]^2 + w'[x];

Define a solution using JacobiZN:

Wolfram Language code: ψ0[x_] := Exp[m JacobiCD[x, m]JacobiSN[x, m] - 2JacobiZN[x, m]] / 10

Check that the function defined previously solves the Schrödinger equation:

Wolfram Language code: -D[ψ0[x], x, x] + v[x] ψ0[x]//FullSimplify

Plot the superpotential, the potential and the wavefunction:

Wolfram Language code:

Plot[Evaluate[{w[x], v[x], ψ0[x]} /. m -> 0.85], {x, 0, 6}, PlotLegends -> {"Superpotential", "Potential", "Wavefunction"}]

Define a conformal map using JacobiZN:

Wolfram Language code: z[w_, m_] := JacobiZN[w, m] + w Pi / (EllipticK[m] EllipticK[1 - m])

Wolfram Language code: With[{m = 0.29}, ParametricPlot[ReIm[z[u + I v, m]], {u, 0, EllipticK[m]}, {v, 0, EllipticK[1 - m]}, Mesh -> 50]]

Parameterization of genus‐1 constant mean-curvature Wente torus:

Wolfram Language code:

WenteEmbedding[params : {H_, 𝓂_, m_, γ_, ℽ_, Γ_, α_, 𝒶_, b_, p_}, {u_, v_}] := Module[{𝓏, ω, 𝒿}, 
	𝓏 = Sqrt[(2/H)](1/𝒶^2)((((𝒶^2 - b)(γ Cos[u])^2 + p)ℽ JacobiCN[v, 𝓂] - (p(γ Cos[u])^2 + 𝒶^2 + b)γ Cos[u]) / ((1 - Γ Cos[u]JacobiCN[v, 𝓂])Sqrt[p - 2b(γ Cos[u])^2 - p(γ Cos[u])^4]));
	ω = (2Sqrt[H]/α)((2/1 - Γ^2)EllipticPi[(Γ^2/Γ^2 - 1), u, m] - EllipticF[u, m]);
	𝒿 = u - ArcTan[((2Sqrt[H] - αSqrt[1 - m Sin[u]^2])Sin[2u]/2(2Sqrt[H]Cos[u]^2 + α Sin[u]^2Sqrt[1 - m Sin[u]^2]))];
	{𝓏 Cos[ω - 𝒿] + (Cos[ω]/2H), 𝓏 Sin[ω - 𝒿] + (Sin[ω]/2H), ((1/𝒶Sqrt[H])) ((2Γ Cos[u]JacobiSN[v, 𝓂]JacobiDN[v, 𝓂]/1 - Γ Cos[u]JacobiCN[v, 𝓂]) + (2/ℽ)JacobiZN[v, 𝓂])}]

Wolfram Language code:

WenteSineSquaredValues[r_Rational /; 1 < r < 2, m_Real /; 0 < m < 1] := N[ /. FindRoot[With[{g = Sqrt[(/1 - )]Sqrt[(m/1 - m)]}, (2/1 - g)EllipticPi[(g/g - 1), ] - EllipticK[]] == r(Pi/2)(1/Sqrt[1 - 2 - (2m - 1)Sqrt[(1 - ) / (m(1 - m))]]), {, 1 / 10, 0, 4 / 23}, WorkingPrecision -> Precision[m] - 2], Precision[m] - 5]

Wolfram Language code:

WenteTorusFunction[lobes_Integer /; lobes ≥ 2, u_, v_] := Module[{𝓂, m, g = lobes, H = 1 / 2, b, f, p, α, 𝒶, γ, ℽ, Γ}, 
	(* elliptic parameter related to Halphen's constant *)
	𝓂 =  /. FindRoot[EllipticK[] == 2EllipticE[], {, 4 / 5}, WorkingPrecision -> 50];
	m = WenteSineSquaredValues[1 + 1 / g, 𝓂];
	γ = (m/1 - m)^(1/(4));ℽ = (𝓂/1 - 𝓂)^(1/(4));Γ = γ ℽ;
	f = H / ((1 - 2m)Sqrt[𝓂(1 - 𝓂)] + (1 - 2𝓂)Sqrt[m(1 - m)]);
	α = 2Sqrt[fSqrt[𝓂(1 - 𝓂)]];𝒶 = 2Sqrt[fSqrt[m(1 - m)]];
	b = 4fSqrt[m(1 - m)](2𝓂 - 1);p = 8fSqrt[m(1 - m)]Sqrt[𝓂(1 - 𝓂)];
	
	Sequence@@{WenteEmbedding[{H, 𝓂, m, γ, ℽ, Γ, α, 𝒶, b, p}, {u, v}], {u, -π / 2, (2g - 1)π / 2}, {v, 0, 4EllipticK[𝓂]}}
	]

Visualize 3‐lobe, 5‐lobe, 7‐lobe and 11‐lobe tori:

Wolfram Language code:

Table[ParametricPlot3D@@{WenteTorusFunction[l, u, v], Lighting -> "Neutral", Mesh -> False, PlotPoints -> 55, PlotStyle -> Opacity[1 / 2, Gray], Ticks -> None}, {l, {3, 5, 7, 11}}]//Multicolumn

Properties & Relations (2)

JacobiZN is defined in terms of JacobiEpsilon:

Wolfram Language code: JacobiZN[u, m]//FunctionExpand

JacobiZN[u,m] is a meromorphic extension of :

Wolfram Language code:

With[{m = 2 / 3}, Plot[{Im[JacobiZN[1 + I t, m]], Im[JacobiZeta[JacobiAmplitude[1 + I t, m], m]]}, {t, -7, 7}, Sequence[...]]]

Top

More Learning

Tech Support

Wolfram Solutions

Wolfram Solutions For Education

Get Started

Grow Your Skills

Work with Us

Educational Programs for Adults

Educational Programs for Youth

Read

JacobiZN

Details

Examples

Basic Examples (3)

Scope (24)

Numerical Evaluation (5)

Specific Values (3)

Visualization (3)

Function Properties (2)

Differentiation (3)

Integration (1)

Series Expansions (3)

Function Identities and Simplifications (2)

Function Representations (2)

Applications (4)

Properties & Relations (2)

Text

CMS

APA

BibTeX

BibLaTeX

JacobiZN

Details

Examples

Basic Examples (3)

Scope (24)

Numerical Evaluation (5)

Specific Values (3)

Visualization (3)

Function Properties (2)

Differentiation (3)

Integration (1)

Series Expansions (3)

Function Identities and Simplifications (2)

Function Representations (2)

Applications (4)

Properties & Relations (2)

See Also

Related Guides

History

Text

CMS

APA

BibTeX

BibLaTeX