WOLFRAM

Wolfram Language & System Documentation Center

LameC[ν,j,z,m]

gives the ^(th) Lamé function TemplateBox[{nu, j, z, m}, LameC] of order with elliptic parameter .

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Numerical Evaluation  
Specific Values  
Visualization  
Show More Show More
Function Properties  
Differentiation  
Integration  
Series Expansions  
Function Representations  
Applications  
Properties & Relations  
Possible Issues  
See Also
Related Guides
History
Cite this Page

LameC

LameC[ν,j,z,m]

gives the ^(th) Lamé function TemplateBox[{nu, j, z, m}, LameC] of order with elliptic parameter .

Details

  • LameC belongs to the Lamé class of functions and solves boundary-value problems for Laplace's equation in ellipsoidal and spheroconal coordinates, as well as occurring in other problems of mathematical physics and quantum mechanics.
  • Mathematical function, suitable for both symbolic and numerical manipulation.
  • LameC[ν,j,z,m] satisfies the Lamé differential equation , with the Lamé eigenvalue given by LameEigenvalueA[ν,j,m], and where TemplateBox[{z, m}, JacobiSN] is the Jacobi elliptic function JacobiSN[z,m].
  • For certain special arguments, LameC automatically evaluates to exact values.
  • LameC can be evaluated to arbitrary numerical precision for an arbitrary complex argument.
  • LameC automatically threads over lists.
  • LameC[ν,0,z,0]= and LameC[ν,j,z,0]=Cos[j(-z)].
  • LameC[ν,j,z,m] is proportional to HeunG[a,q,α,β,γ,δ,ξ], where , if the parameters of HeunG are specialized as follows: .

Examples

open all close all

Basic Examples  (3)

Evaluate numerically:

Wolfram Language code: LameC[0.9, 2, 0.7, 0.3]

Plot the LameC function for and :

Wolfram Language code: With[{ν = 1.5, m = 0.5}, Plot[{LameC[ν, 1, z, m], LameC[ν, 2, z, m]}, {z, -2EllipticK[m], 2EllipticK[m]}, PlotLabels -> {"j = 1", "j = 2"}]]

Series expansion of LameC at the origin:

Wolfram Language code: Series[LameC[ν, j, z, m], {z, 0, 2}]

Scope  (27)

Numerical Evaluation  (5)

Evaluate to high precision:

Wolfram Language code: N[LameC[9 / 10, 2, 7 / 10, 3 / 10], 50]

The precision of the output tracks the precision of the input:

Wolfram Language code: LameC[9 / 10, 2, 7 / 10, 0.33333333333333333333331]

LameC can take complex number parameters and argument:

Wolfram Language code: LameC[1.2 + I, 2, 0.7, 0.3]
Wolfram Language code: LameC[1.2 + I, 2, 0.7 - 0.1I, 0.3 + I]

Evaluate LameC efficiently at high precision:

Wolfram Language code: LameC[0.9, 2, 0.7, 3 / 10`500]//Timing
Wolfram Language code: LameC[0.9, 2, 0.7, 3 / 10`500 + I]//Timing

Lists and matrices:

Wolfram Language code: LameC[0.9, 2, 0.7, {0.1, 0.1 + I, I, 4}]
Wolfram Language code: LameC[0.9, 2, {0.1, 0.7, 0.1I, 4 - 1 / 2I}, 0.1]
Wolfram Language code: LameC[0.9, 2, 0.7, (| | | | :- | :---- | | π | u | | v | (π/2) |)]

Specific Values  (3)

Value of LameC when and :

Wolfram Language code: LameC[ν, 0, z, 0]

Value of LameC when and :

Wolfram Language code: LameC[ν, 3, z, 0]

Some poles of LameC:

Wolfram Language code: {LameC[ν, 1, 3I EllipticK[1 - m], m], LameC[ν, 1, 2EllipticK[m] + 3I EllipticK[1 - m], m]}

For integer values of and , LameC can be expressed entirely in terms of Jacobi elliptic functions:

Wolfram Language code: LameC[3, 0, z, (1/2)]//FunctionExpand
Wolfram Language code: LameC[4, 2, z, (1/2)]//FunctionExpand

Visualization  (6)

Plot the first three even LameC functions:

Wolfram Language code: With[{ν = 3 / 2, m = 1 / 2}, Plot[{LameC[ν, 0, z, m], LameC[ν, 2, z, m], LameC[ν, 4, z, m]}, {z, -2EllipticK[m], 2EllipticK[m]}]]

Plot the first three odd LameC functions:

Wolfram Language code: With[{ν = 3 / 2, m = 1 / 2}, Plot[{LameC[ν, 1, z, m], LameC[ν, 3, z, m], LameC[ν, 5, z, m]}, {z, -2EllipticK[m], 2EllipticK[m]}]]

Plot the absolute value of the LameC function for complex parameters:

Wolfram Language code: Plot[Abs[LameC[3 / 2 + I, 3, z, 0.1 + 0.1I]], {z, -8EllipticK[1 / 3], 8EllipticK[1 / 3]}]

Plot LameC as a function of its first parameter :

Wolfram Language code: Plot[{LameC[-1 / 2, 1, z, 9 / 10], LameC[1, 1, z, 9 / 10], LameC[3, 1, z, 9 / 10]}, {z, -4EllipticK[1 / 3], 4EllipticK[1 / 3]}]

Plot LameC as a function of and elliptic parameter :

Wolfram Language code: Plot3D[LameC[3 / 2, 1, z, m], {z, -5, 5}, {m, 0, 1}, ViewPoint -> {-1.3, 2.4, 2.}]

Plot the family of LameC functions for different values of the elliptic parameter :

Wolfram Language code: Plot[Evaluate[Table[LameC[3, 1, z, m], {m, 0, 9 / 10, 1 / 15}]], {z, -4EllipticK[1 / 3], 4EllipticK[1 / 3]}, ...]

Function Properties  (2)

When is even, LameC is a periodic function of real argument with a period 2EllipticK[m]:

Wolfram Language code: With[{ν = 7 / 2, m = 9 / 10, j = 2}, LameC[ν, j, z + 2EllipticK[m], m]]
Wolfram Language code: With[{ν = 7 / 2, m = 9 / 10, j = 2}, Plot[LameC[ν, j, z, m], {z, -2EllipticK[m], 2EllipticK[m]}]]

When is odd, LameC is a periodic function of real argument with a period 4EllipticK[m] and has an initial value LameC[ν,j,0,m]=0:

Wolfram Language code: With[{ν = 7 / 2, m = 9 / 10, j = 3}, LameC[ν, j, z + 4EllipticK[m], m]]
Wolfram Language code: With[{ν = 7 / 2, m = 9 / 10, j = 3}, Plot[LameC[ν, j, z, m], {z, -4EllipticK[m], 4EllipticK[m]}, Epilog -> Point[{0, 0}]]]

Differentiation  (3)

The -derivative of LameC is LameCPrime:

Wolfram Language code: D[LameC[ν, j, z, m], z]

Higher derivatives of LameC are calculated using LameCPrime:

Wolfram Language code: D[LameC[ν, j, z, m], {z, 2}]

Derivatives of LameC for specific cases of parameters:

Wolfram Language code: D[LameC[ν, 2, z, 0], z]
Wolfram Language code: D[LameC[ν, 2, z, 0], {z, n}]

Integration  (3)

Indefinite integrals of LameC cannot be expressed in elementary or other special functions:

Wolfram Language code: Integrate[LameC[ν, j, z, m], z]

Definite numerical integrals of LameC:

Wolfram Language code: NIntegrate[LameC[12 / 10, 2, z, 9 / 10], {z, 0, 1 / 3}]

More integrals with LameC:

Wolfram Language code: NIntegrate[z^2LameC[12 / 10, 2, z, 9 / 10], {z, -1, 1 / 3}]
Wolfram Language code: NIntegrate[Sin[z / 2]LameC[12 / 10, 2, z, 9 / 10], {z, -1, 1 / 2}]

Series Expansions  (3)

Series expansion of LameC at the origin:

Wolfram Language code: Series[LameC[ν, j, z, m], {z, 0, 2}]

Coefficient of the second-order term of this expansion:

Wolfram Language code: SeriesCoefficient[LameC[ν, j, z, m], {z, 0, 2}]

Plot the first- and third-order approximations for LameC around :

Wolfram Language code: {ν, j, m} = {1 / 9, 1, 9 / 10};
Wolfram Language code: terms = Normal@Table[Series[LameC[ν, j, z, m], {z, 0, l}], {l, 1, 3, 2}];
Wolfram Language code: Plot[{LameC[ν, j, z, m], terms}//Flatten//Evaluate, {z, -2EllipticK[m], 2EllipticK[m]}, PlotLegends -> {LameC[ν, j, z, m], "1st approximation", "3rd approximation"}]

Series expansion for LameC at any ordinary complex point:

Wolfram Language code: Series[LameC[ν, j, z, m], {z, 1 / 2, 2}]

Function Representations  (2)

LameC cannot be represented in terms of MeijerG:

Wolfram Language code: MeijerGReduce[LameC[ν, j, z, m], z]

TraditionalForm formatting:

Wolfram Language code: LameC[ν, j, z, m]//TraditionalForm

Applications  (1)

LameC solves the Lamé differential equation when h=LameEigenvalueA[ν,j,m]:

Wolfram Language code: y[x_] := LameC[ν, j, x, m];
Wolfram Language code: y''[x] + (LameEigenvalueA[ν, j, m] - ν(ν + 1)m JacobiSN[x, m]^2)y[x] == 0//Simplify

Properties & Relations  (2)

LameC is an even function when is a non-negative even integer:

Wolfram Language code: LameC[ν, 2, -z, m]

LameC is an odd function when is a positive odd integer:

Wolfram Language code: LameC[ν, 1, -z, m]

Use FunctionExpand to expand LameC for integer values of and :

Wolfram Language code: LameC[7, 5, z, (3/4)]//FunctionExpand

Possible Issues  (1)

LameC is not defined if is a negative integer:

Wolfram Language code: LameC[ν, -3, z, m]

LameC is not defined if is not an integer:

Wolfram Language code: LameC[ν, 3 / 2, z, m]
Wolfram Research (2020), LameC, Wolfram Language function, https://reference.wolfram.com/language/ref/LameC.html.

Text

Wolfram Research (2020), LameC, Wolfram Language function, https://reference.wolfram.com/language/ref/LameC.html.

CMS

Wolfram Language. 2020. "LameC." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/LameC.html.

APA

Wolfram Language. (2020). LameC. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/LameC.html

BibTeX

@misc{reference.wolfram_2026_lamec, author="Wolfram Research", title="{LameC}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/LameC.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_lamec, organization={Wolfram Research}, title={LameC}, year={2020}, url={https://reference.wolfram.com/language/ref/LameC.html}, note=[Accessed: 13-June-2026]}