WOLFRAM

Wolfram Language & System Documentation Center

LameS[ν,j,z,m]

gives the ^(th) Lamé function TemplateBox[{nu, j, z, m}, LameS] of order with elliptic parameter .

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Numerical Evaluation  
Specific Values  
Visualization  
Show More Show More
Function Properties  
Differentiation  
Integration  
Series Expansions  
Function Representations  
Applications  
Properties & Relations  
Possible Issues  
See Also
Related Guides
History
Cite this Page

LameS

LameS[ν,j,z,m]

gives the ^(th) Lamé function TemplateBox[{nu, j, z, m}, LameS] of order with elliptic parameter .

Details

  • LameS belongs to the Lamé class of functions and solves boundary-value problems for Laplace's equation in ellipsoidal and spheroconal coordinates, as well as occurring in other problems of mathematical physics and quantum mechanics.
  • Mathematical function, suitable for both symbolic and numerical manipulation.
  • LameS[ν,j,z,m] satisfies the Lamé differential equation , with the Lamé eigenvalue given by LameEigenvalueB[ν,j,m], and where TemplateBox[{z, m}, JacobiSN] is the Jacobi elliptic function JacobiSN[z,m].
  • For certain special arguments, LameS automatically evaluates to exact values.
  • LameS can be evaluated to arbitrary numerical precision for arbitrary complex argument.
  • LameS automatically threads over lists.
  • LameS[ν,j,z,0]=Sin[j(-z)].
  • LameS[ν,j,z,m] is proportional to HeunG[a,q,α,β,γ,δ,ξ], where , if the parameters of HeunG are specialized as follows: .

Examples

open all close all

Basic Examples  (3)

Evaluate numerically:

Wolfram Language code: LameS[0.9, 2, 0.7, 0.3]

Plot the LameS function for and :

Wolfram Language code: With[{ν = 1.5, m = 0.5}, Plot[{LameS[ν, 1, z, m], LameS[ν, 2, z, m]}, {z, -2EllipticK[m], 2EllipticK[m]}, PlotLabels -> {"j = 1", "j = 2"}]]

Series expansion of LameS at the origin:

Wolfram Language code: Series[LameS[ν, j, z, m], {z, 0, 2}]

Scope  (27)

Numerical Evaluation  (5)

Evaluate to high precision:

Wolfram Language code: N[LameS[9 / 10, 2, 7 / 10, 3 / 10], 50]

The precision of the output tracks the precision of the input:

Wolfram Language code: LameS[9 / 10, 2, 7 / 10, 0.33333333333333333333331]

LameS can take complex number parameters and argument:

Wolfram Language code: LameS[1.2 + I, 2, 0.7, 0.3]
Wolfram Language code: LameS[1.2 + I, 2, 0.7 - 0.1I, 0.3 + I]

Evaluate LameS efficiently at high precision:

Wolfram Language code: LameS[0.9, 2, 0.7, 3 / 10`500]//Timing
Wolfram Language code: LameS[0.9, 2, 0.7, 3 / 10`500 + I]//Timing

Lists and matrices:

Wolfram Language code: LameS[0.9, 2, 0.7, {0.1, 0.1 + I, I, 4}]
Wolfram Language code: LameS[0.9, 2, {0.1, 0.7, 0.1I, 4 - 1 / 2I}, 0.1]
Wolfram Language code: LameS[0.9, 2, 0.7, (| | | | :- | :---- | | π | u | | v | (π/2) |)]

Specific Values  (3)

Value of LameS when and :

Wolfram Language code: LameS[ν, 1, z, 0]

Value of LameS when and :

Wolfram Language code: LameS[ν, 4, z, 0]

Some poles of LameS:

Wolfram Language code: {LameS[ν, 1, 3I EllipticK[1 - m], m], LameS[ν, 1, 2EllipticK[m] + 3I EllipticK[1 - m], m]}

For integer values of and , LameS can be expressed entirely in terms of Jacobi elliptic functions:

Wolfram Language code: LameS[3, 1, z, (1/2)]//FunctionExpand
Wolfram Language code: LameS[5, 2, z, (1/2)]//FunctionExpand

Visualization  (6)

Plot the first three even LameS functions:

Wolfram Language code: With[{ν = 3 / 2, m = 1 / 2}, Plot[{LameS[ν, 2, z, m], LameS[ν, 4, z, m], LameS[ν, 6, z, m]}, {z, -2EllipticK[m], 2EllipticK[m]}, Evaluated -> True]]

Plot the first three odd LameS functions:

Wolfram Language code: With[{ν = 3 / 2, m = 1 / 2}, Plot[{LameS[ν, 1, z, m], LameS[ν, 3, z, m], LameS[ν, 5, z, m]}, {z, -2EllipticK[m], 2EllipticK[m]}, Evaluated -> True]]

Plot the absolute value of the LameS function for complex parameters:

Wolfram Language code: Plot[Abs[LameS[3 / 2 + I, 3, z, 0.1 + 0.1I]], {z, -8EllipticK[1 / 3], 8EllipticK[1 / 3]}]

Plot LameS as a function of its first parameter :

Wolfram Language code: Plot[{LameS[-1 / 2, 1, z, 9 / 10], LameS[1, 1, z, 9 / 10], LameS[3, 1, z, 9 / 10]}, {z, -4EllipticK[1 / 3], 4EllipticK[1 / 3]}]

Plot LameS as a function of and elliptic parameter :

Wolfram Language code: Plot3D[LameS[5 / 2, 2, z, m], {z, -5, 5}, {m, 0, 1}, ViewPoint -> {-1.3, 2.4, 2.}]

Plot the family of LameS functions for different values of the elliptic parameter :

Wolfram Language code: Plot[Evaluate[Table[LameS[3, 1, z, m], {m, 0, 9 / 10, 1 / 15}]], {z, -4EllipticK[1 / 3], 4EllipticK[1 / 3]}, ...]

Function Properties  (2)

When is even, LameS is a periodic function of real argument with a period 2 EllipticK[m] and has an initial value LameS[ν,j,0,m]=0:

Wolfram Language code: With[{ν = 7 / 2, m = 9 / 10, j = 2}, LameS[ν, j, z + 2EllipticK[m], m]]
Wolfram Language code: With[{ν = 7 / 2, m = 9 / 10, j = 2}, Plot[LameS[ν, j, z, m], {z, -2EllipticK[m], 2EllipticK[m]}, Epilog -> Point[{0, 0}]]]

When is odd, LameS is a periodic function of real argument with a period 4 EllipticK[m]:

Wolfram Language code: With[{ν = 7 / 2, m = 9 / 10, j = 3}, LameS[ν, j, z + 4EllipticK[m], m]]
Wolfram Language code: With[{ν = 7 / 2, m = 9 / 10, j = 3}, Plot[LameS[ν, j, z, m], {z, -4EllipticK[m], 4EllipticK[m]}]]

Differentiation  (3)

The -derivative of LameS is LameSPrime:

Wolfram Language code: D[LameS[ν, j, z, m], z]

Higher derivatives of LameS are calculated using LameSPrime:

Wolfram Language code: D[LameS[ν, j, z, m], {z, 2}]//Simplify

Derivatives of LameS for specific cases of parameters:

Wolfram Language code: D[LameS[ν, 2, z, 0], z]
Wolfram Language code: D[LameS[ν, 2, z, 0], {z, n}]

Integration  (3)

Indefinite integrals of LameS cannot be expressed in elementary or other special functions:

Wolfram Language code: Integrate[LameS[ν, j, z, m], z]

Definite numerical integrals of LameS:

Wolfram Language code: NIntegrate[LameS[12 / 10, 2, z, 9 / 10], {z, 0, 1 / 3}]

More integrals with LameS:

Wolfram Language code: NIntegrate[z^2LameS[12 / 10, 2, z, 9 / 10], {z, -1, 1 / 3}]
Wolfram Language code: NIntegrate[Sin[z / 2]LameS[12 / 10, 2, z, 9 / 10], {z, -1, 1 / 2}]

Series Expansions  (3)

Series expansion of LameS at the origin:

Wolfram Language code: Series[LameS[ν, j, z, m], {z, 0, 2}]

Coefficient of the second term of this expansion:

Wolfram Language code: SeriesCoefficient[LameS[ν, j, z, m], {z, 0, 2}]

Plot the first- and third-order approximations for LameS around :

Wolfram Language code: {ν, j, m} = {1 / 9, 1, 9 / 10};
Wolfram Language code: terms = Normal@Table[Series[LameS[ν, j, z, m], {z, 0, l}], {l, 1, 3, 2}];
Wolfram Language code: Plot[{LameS[ν, j, z, m], terms}//Flatten//Evaluate, {z, -2EllipticK[m], 2EllipticK[m]}, PlotLegends -> {LameS[ν, j, z, m], "1st approximation", "3rd approximation"}]

Series expansion for LameS at any ordinary complex point:

Wolfram Language code: Series[LameS[ν, j, z, m], {z, 1 / 2, 1}]//FullSimplify

Function Representations  (2)

LameS cannot be represented in terms of MeijerG:

Wolfram Language code: MeijerGReduce[LameS[ν, j, z, m], z]

TraditionalForm formatting:

Wolfram Language code: LameS[ν, j, z, m]//TraditionalForm

Applications  (1)

LameS solves the Lamé differential equation when h=LameEigenvalueB[ν,j,m]:

Wolfram Language code: y[x_] := LameS[ν, j, x, m];
Wolfram Language code: y''[x] + (LameEigenvalueB[ν, j, m] - ν(ν + 1)m JacobiSN[x, m]^2)y[x] == 0//Simplify

Properties & Relations  (2)

LameS is an even function when is a positive odd integer:

Wolfram Language code: LameS[ν, 1, -z, m]

LameS is an odd function when is a positive even integer:

Wolfram Language code: LameS[ν, 2, -z, m]

Use FunctionExpand to expand LameS for integer values of and :

Wolfram Language code: LameS[7, 5, z, (3/4)]//FunctionExpand

Possible Issues  (1)

LameS is not defined if is a negative integer:

Wolfram Language code: LameS[ν, -3, z, m]

LameS is not defined if is not an integer:

Wolfram Language code: LameS[ν, 3 / 2, z, m]
Wolfram Research (2020), LameS, Wolfram Language function, https://reference.wolfram.com/language/ref/LameS.html.

Text

Wolfram Research (2020), LameS, Wolfram Language function, https://reference.wolfram.com/language/ref/LameS.html.

CMS

Wolfram Language. 2020. "LameS." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/LameS.html.

APA

Wolfram Language. (2020). LameS. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/LameS.html

BibTeX

@misc{reference.wolfram_2026_lames, author="Wolfram Research", title="{LameS}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/LameS.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_lames, organization={Wolfram Research}, title={LameS}, year={2020}, url={https://reference.wolfram.com/language/ref/LameS.html}, note=[Accessed: 13-June-2026]}