WOLFRAM

Wolfram Language & System Documentation Center

MeanShiftFilter[data,r,d]

filters data by replacing every value by the mean of the pixels in a range-r neighborhood and whose value is within a distance d.

MeanShiftFilter[data,{r1,r2,…},d]

uses ri for filtering the ^(th)dimension in data.

Details and Options
Details and Options Details and Options
Background & Context
Examples  
Basic Examples  
Scope  
Data  
Parameters  
Options  
DistanceFunction  
MaxIterations  
Applications  
Properties & Relations  
Neat Examples  
See Also
Related Guides
History
Cite this Page

MeanShiftFilter

MeanShiftFilter[data,r,d]

filters data by replacing every value by the mean of the pixels in a range-r neighborhood and whose value is within a distance d.

MeanShiftFilter[data,{r1,r2,…},d]

uses ri for filtering the ^(th)dimension in data.

Details and Options

  • MeanShiftFilter is used to locally smooth data and diminish noise while preserving significant jumps such as edges in images, where the amount of smoothing is dependent on the values of r and d.
  • The function applied to each range-r neighborhood is MeanShift.
  • The data can be any of the following:
  • listarbitrary-rank numerical array
    tseriestemporal data such as TimeSeries, TemporalData, …
    imagearbitrary Image or Image3D object
    audioan Audio object
    videoa Video object
  • For multichannel images and audio signals, the distance is computed between channel vectors.
  • MeanShiftFilter[data,{r1,r2,…},d] computes the mean shift value in blocks centered on each sample.
  • MeanShiftFilter assumes the index coordinate system for lists and images.
  • At the data boundaries, MeanShiftFilter uses smaller neighborhoods.
  • The following options can be given:
  • DistanceFunction EuclideanDistancehow to compute the distance between values
    MaxIterations 1maximum number of iterations to be performed
  • For a complete list of possible settings for DistanceFunction, see the reference page for MeanShift.
  • The possible range for the distance parameter d depends on the distance function as well as the dimension of the color space.

Background & Context

Examples

open all close all

Basic Examples  (3)

Mean-shift filtering of a vector:

Wolfram Language code: MeanShiftFilter[ {1, 0, 1, 4, 4, 5, 2, 1}, 2, 1]

Filter a TimeSeries:

Wolfram Language code: ts = TemporalData[TimeSeries, {{{0., -0.054108337548928784, 0.1280211704499059, 0.28162021808461324, -0.2057320325139802, -0.4871901025739722, -0.7154387408784426, -0.7399660905024047, -0.6981022018441507, -0.7178077145466483, -0.8034462541874 ... 7894984276149, 1.8851123992920942, 1.8341759268762767, 2.0335844117979263}}, {{0., 10., 0.1}}, 1, {"Continuous", 1}, {"Continuous", 1}, 1, {ValueDimensions -> 1, ResamplingMethod -> {"Interpolation", InterpolationOrder -> 1}}}, False, 10.];
Wolfram Language code: filtered = MeanShiftFilter[ts, 5, 2]
Wolfram Language code: ListLinePlot[{ts, filtered}, PlotLegends -> {"original data", "filtered"}]

Mean-shift filtering of a color image:

Wolfram Language code: MeanShiftFilter[[image], 10, .5]

Scope  (12)

Data  (7)

Mean-shift filtering of data:

Wolfram Language code: MeanShiftFilter[ {0, 1, 10, 11}, 1, 1]

Mean-shift filtering of a 2D array:

Wolfram Language code: MeanShiftFilter[(⁠| | | | | | - | - | - | - | | 0 | 3 | 2 | 2 | | 3 | 9 | 9 | 6 | | 5 | 8 | 7 | 0 | | 3 | 1 | 1 | 2 |⁠), 1, 2]//MatrixForm

Filter a TimeSeries:

Wolfram Language code: ts = TemporalData[TimeSeries, {{{0., -0.27267267057145633, -0.6672983789995302, -0.5338541947930846, -0.6117404489279314, -0.6755527076595494, -0.02125421294486496, -0.10792797291843935, -0.6138271235477938, -0.3248568606554575, -0.08843449054 ... 2053424, -0.49980440691873723, -0.5388679788215971, -0.4101602764645551}}, {{0, 1., 0.01}}, 1, {"Continuous", 1}, {"Continuous", 1}, 1, {ValueDimensions -> 1, ResamplingMethod -> {"Interpolation", InterpolationOrder -> 1}}}, False, 10.1];
Wolfram Language code: filtered = MeanShiftFilter[ts, 5, 1, MaxIterations -> 100]
Wolfram Language code: ListLinePlot[{ts, filtered}, PlotLegends -> {"original data", "filtered"}]

Filter an Audio signal:

Wolfram Language code: a = Import["ExampleData/rule30.wav"];
Wolfram Language code: b = MeanShiftFilter[a, 25, 0.5]
Wolfram Language code: AudioPlot[{a, b}]

Mean-shift filtering of a grayscale image:

Wolfram Language code: MeanShiftFilter[[image], 5, 0.1]

Filter video frames:

Wolfram Language code: MeanShiftFilter[Video["ExampleData/fish.mp4"], 3, .02]

Mean-shift filtering of a 3D image:

Wolfram Language code: MeanShiftFilter[[image], 6, 0.1]

Parameters  (5)

Specify one radius to be used in all directions:

Wolfram Language code: MeanShiftFilter[[image], 5, 1]

Mean-shift filtering in just the first direction:

Wolfram Language code: MeanShiftFilter[[image], {5, 0}, 1]

Filtering in just the second direction:

Wolfram Language code: MeanShiftFilter[[image], {0, 5}, 1]

Mean-shift filtering of a 3D image in the vertical direction only:

Wolfram Language code: MeanShiftFilter[[image], {5, 0, 0}, 1]

Mean-shift filtering of a 3D image in the horizontal planes only:

Wolfram Language code: MeanShiftFilter[[image], {0, 5, 5}, 1]

Mean-shift filter averages only over pixels that differ in value by less than d:

Wolfram Language code: Labeled[MeanShiftFilter[[image], 5, #], #]& /@ {0.1, 0.3, 0.5}

Options  (3)

DistanceFunction  (2)

By default, EuclideanDistance is used:

Wolfram Language code: MeanShiftFilter[[image], 10, .5]

Specify the distance function:

Wolfram Language code: MeanShiftFilter[[image], 10, .5, DistanceFunction -> ManhattanDistance]

MaxIterations  (1)

By default, only one iteration of mean shift is applied to input:

Wolfram Language code: MeanShiftFilter[[image], 3, .1]

Use MaxIterations to specify the number of iterations:

Wolfram Language code: MeanShiftFilter[[image], 3, .1, MaxIterations -> 100]

Applications  (2)

Use mean-shift filtering to smooth an image while preserving the edges:

Wolfram Language code: MeanShiftFilter[[image], 4, 0.05, MaxIterations -> 30]

Use mean-shift filtering as a preprocessing step for image segmentation:

Wolfram Language code: ClusteringComponents[MeanShiftFilter[[image], 3, 0.2], 5]// Colorize

Properties & Relations  (1)

MeanShiftFilter is equivalent to MeanFilter for distance d greater than the data dynamic range:

Wolfram Language code: r = 1; data = RandomReal[{0, r}, 100];
Wolfram Language code: MeanShiftFilter[data, 1, r + $MachineEpsilon] == MeanFilter[data, 1]

Neat Examples  (1)

Show how MeanShiftFilter iteratively shifts values until they converge:

Wolfram Language code: data = Join[RandomReal[NormalDistribution[0, .4], {500, 2}], RandomReal[NormalDistribution[1, .4], {500, 2}]];
Wolfram Language code: ListPlot[data]
Wolfram Language code: ms = NestList[MeanShiftFilter[#, 1000, {.6, .6}]&, data, 5];
Wolfram Language code: ListLinePlot[Transpose[ms]]
Wolfram Research (2010), MeanShiftFilter, Wolfram Language function, https://reference.wolfram.com/language/ref/MeanShiftFilter.html (updated 2025).

Text

Wolfram Research (2010), MeanShiftFilter, Wolfram Language function, https://reference.wolfram.com/language/ref/MeanShiftFilter.html (updated 2025).

CMS

Wolfram Language. 2010. "MeanShiftFilter." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2025. https://reference.wolfram.com/language/ref/MeanShiftFilter.html.

APA

Wolfram Language. (2010). MeanShiftFilter. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/MeanShiftFilter.html

BibTeX

@misc{reference.wolfram_2026_meanshiftfilter, author="Wolfram Research", title="{MeanShiftFilter}", year="2025", howpublished="\url{https://reference.wolfram.com/language/ref/MeanShiftFilter.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_meanshiftfilter, organization={Wolfram Research}, title={MeanShiftFilter}, year={2025}, url={https://reference.wolfram.com/language/ref/MeanShiftFilter.html}, note=[Accessed: 13-June-2026]}