NFractionalD[f,{x,α},x0]
gives a numerical approximation to the Riemann–Liouville fractional derivative 
of order α of the function f at the point x0.
NFractionalD
NFractionalD[f,{x,α},x0]
gives a numerical approximation to the Riemann–Liouville fractional derivative 
of order α of the function f at the point x0.
Details and Options
- NFractionalD is the numerical analog of FractionalD, also known as the Riemann–Liouville differintegral of f.
- The Riemann–Liouville fractional derivative of
of order 
is defined as 
, where ![n=max(0,TemplateBox[{alpha}, Ceiling])](Files/NFractionalD.en/5.png "n=max(0,TemplateBox[{alpha}, Ceiling])")
. - NFractionalD is typically used in cases when symbolic evaluation with FractionalD fails.
- The following options can be given to NFractionalD:
-
Method Automatic method to use AccuracyGoal Infinity digits of absolute accuracy sought PrecisionGoal Automatic digits of precision sought WorkingPrecision MachinePrecision the precision used in internal computations - The following Method option settings may be used:
-
Automatic automatically selected method "GrunwaldLetnikov" Grünwald-Letnikov fractional differintegration scheme "RiemannLiouville" Riemann-Liouville fractional differintegration scheme
Examples
open all close allBasic Examples (4)
Calculate the half-order fractional derivative of a quadratic function with respect to x at some point:
NFractionalD[x^2, {x, 1 / 2}, 0.25]Calculate the 
-order fractional derivative of a constant with respect to x at some point:
NFractionalD[4, {x, 1 / 3}, 0.4]Plot the 
-order fractional derivative of an exponential function:
Plot[NFractionalD[Exp[x], {x, 1 / 3}, x0], {x0, 0, 1 / 10}]Numerical fractional integral:
NFractionalD[MittagLefflerE[1 / 4, x], {x, -3 / 2}, 0.25]Scope (9)
Plot the 
-order fractional derivative of the square function with respect to x:
Plot[NFractionalD[x ^ 2, {x, 1 / 3}, x0], {x0, 0, 1}]Calculate the 0.23-order fractional derivative of the Exp function numerically and symbolically:
NFractionalD[Exp[x], {x, 0.23}, 1 / 2]FractionalD[Exp[x], {x, 0.23}] /. x -> 1 / 2Calculate the value of the half-order derivative of the ArcTan function at some point:
NFractionalD[ArcTan[x], {x, 1 / 2}, 0.2]Plot[NFractionalD[ArcTan[x], {x, 1 / 2}, x0], {x0, 0, 10}, PlotRange -> All]The 
-order fractional derivative of the Sin function:
Plot[NFractionalD[Sin[x], {x, 3 / 2}, x0], {x0, 0, 3π}]The 
-order fractional integral of the Sin function:
Plot[NFractionalD[Sin[x], {x, -3 / 2}, x0], {x0, 0, 3π}]The half-order fractional derivative of the AiryAi function:
Plot[NFractionalD[AiryAi[x], {x, 1 / 2}, x0], {x0, 0, 2π}]Numerically calculate the fractional derivative of the BesselJ function:
NFractionalD[BesselJ[1 / 2, x], {x, 1 / 3}, 0.25]Numerically calculate the fractional derivative of the MeijerG function:
NFractionalD[MeijerG[{{1 / 2}, {1 / 3}}, {{1 / 4}, {1 / 5}}, x], {x, 1 / 2}, 0.23]Plot the numerically calculated fractional derivatives and integrals of a trigonometric product:
Plot[NFractionalD[Sin[x] Cos[x], {x, 1 / 2}, x0], {x0, 0, 1}]Plot[NFractionalD[Sin[x] Cos[x], {x, -1 / 2}, x0], {x0, 0, 1}]Options (2)
Method (2)
NFractionalD has two built-in methods, the Riemann–Liouville and the Grünwald–Letnikov methods:
NFractionalD[Sin[x], {x, 1 / 2}, 0.23, Method -> "RiemannLiouville"]NFractionalD[Sin[x], {x, 1 / 2}, 0.23, Method -> "GrunwaldLetnikov"]If the Method is not specified, NFractionalD automatically uses the Riemann–Liouville approach:
NFractionalD[Sin[x], {x, 1 / 2}, 0.23]In some cases, the Grünwald–Letnikov method is able to calculate the numerical fractional derivative:
NFractionalD[AngerJ[10 / 3, x], {x, -4 / 3}, 1 / 3, Method -> "GrunwaldLetnikov"]It is not possible to calculate this fractional derivative using the Riemann–Liouville method:
NFractionalD[AngerJ[10 / 3, x], {x, -4 / 3}, 1 / 3, Method -> "RiemannLiouville"]Applications (3)
NFractionalD is able to numerically calculate fractional derivatives when FractionalD fails:
FractionalD[Hypergeometric2F1[1 / 2, 2 / 3, 3 / 4, x] Log[x - 1], {x, 1 / 2}]NFractionalD[Hypergeometric2F1[1 / 2, 2 / 3, 3 / 4, x] Log[x - 1], {x, 1 / 2}, 0.23]//AbsoluteTimingFractionalD outputs may contain DifferenceRoot sequences:
FractionalD[Sin[x] Cos[x], {x, α}, Assumptions -> {α∉ℤ, α > 0}]For a specific order of fractional differentiation, this is a cumbersome sum of HypergeometricPFQ functions:
Out[1] /. α -> 1.2However, the numerically calculated fractional derivative plot might be insightful:
Plot[NFractionalD[Sin[x]Cos[x], {x, 1.2}, x0], {x0, 0, 3 / 2π}]Effectively generate a list of numerical values of fractional derivatives of a complex function using NFractionalD:
AbsoluteTiming[Table[{x0, NFractionalD[Sin[x]Cos[x]Log[x], {x, 1 / 2}, x0]}, {x0, 1 / 2, 2, 1 / 100}]];The timing for the calculated 151 values:
%[[1]]Plot this fractional derivative:
ListLinePlot[%%[[2]]]Properties & Relations (6)
NFractionalD is defined for all real 
:
NFractionalD[x ^ 2, {x, 4 / 5}, 1 / 2]NFractionalD[x ^ 2, {x, -4 / 5}, 1 / 2]NFractionalD[x ^ 2, {x, -4 / 5 + I}, 1 / 2]
In general, the fractional derivative of a constant is not 0:
NFractionalD[4, {x, 1 / 2}, 0.25]NFractionalD gives the output in WorkingPrecision (if not specified, it is MachinePrecision):
NFractionalD[x ^ 2, {x, 1 / 4}, 1 / 2]NFractionalD[x ^ 2, {x, 1 / 4}, 1 / 2, WorkingPrecision -> 30]If the Method option is not specified, NFractionalD uses the "RiemannLiouville" method:
NFractionalD[x^2, {x, 1 / 2}, 1 / 4]NFractionalD[x^2, {x, 1 / 2}, 1 / 4, Method -> "RiemannLiouville"]Plot the fractional derivative using the numerical NFractionalD approach:
ListLinePlot[Table[{x0, NFractionalD[Sin[x]Cos[x], {x, 3.43}, x0]}, {x0, 1 / 2, 2, 1 / 20}]]Compare with the symbolic FractionalD approach:
Plot[Evaluate[FractionalD[Sin[x]Cos[x], {x, 3.43}]], {x, 1 / 2, 2}]For negative orders 
, NCaputoD coincides with NFractionalD:
NCaputoD[x ^ 2, {x, -1 / 4}, 1 / 2, WorkingPrecision -> 20]NFractionalD[x ^ 2, {x, -1 / 4}, 1 / 2, WorkingPrecision -> 20]Possible Issues (3)
NFractionalD will generate an error message if the Method option is not correct:
NFractionalD[x ^ 2, {x, -1 / 4}, 1 / 2, Method -> "GrunwaldLetniko"]
NFractionalD will generate an error message if the precision of input is less than the WorkingPrecision:
NFractionalD[x ^ 2, {x, -1 / 4}, 0.2, WorkingPrecision -> 20]
NFractionalD takes only numeric points of evaluation:
NFractionalD[x ^ 2, {x, 4 / 5}, 1 / 2]NFractionalD[x ^ 2, {x, -4 / 5}, b]
Neat Examples (2)
Plot the Sin function and its half, first and 
-order derivatives:
Plot[{NFractionalD[Sin[x], {x, 0}, x0], NFractionalD[Sin[x], {x, 1 / 2}, x0], NFractionalD[Sin[x], {x, 1}, x0], NFractionalD[Sin[x], {x, 3 / 2}, x0]}, {x0, 0, 2π}, Rule[...]]Numerical fractional derivative of MittagLefflerE at a point:
NFractionalD[MittagLefflerE[1 / 4, x], {x, 3 / 2}, 0.25]Generate a list of numerical values of the fractional derivative of the MittagLefflerE function:
Table[{x0, NFractionalD[MittagLefflerE[1 / 4, x], {x, 3 / 2}, x0]}, {x0, 1 / 10, 1 / 2, 1 / 100}];Plot this fractional derivative:
ListLinePlot[%, PlotRange -> All]Text
Wolfram Research (2022), NFractionalD, Wolfram Language function, https://reference.wolfram.com/language/ref/NFractionalD.html.
CMS
Wolfram Language. 2022. "NFractionalD." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/NFractionalD.html.
APA
Wolfram Language. (2022). NFractionalD. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/NFractionalD.html