Wolfram Language & System Documentation Center

MittagLefflerE

MittagLefflerE[α,z]

gives the Mittag–Leffler function .

MittagLefflerE[α,β,z]

gives the generalized Mittag–Leffler function .

Details

MittagLefflerE is a mathematical function, suitable for both symbolic and numerical manipulation.
MittagLefflerE is typically used in the solution of fractional-order differential equations, similar to the Exp function in the solution of ordinary differential equations.
MittagLefflerE allows to be any real number.
The generalized Mittag–Leffler function is an entire function of given by its defining series $TemplateBox[{alpha, beta, z}, MittagLefflerE2]=sum_(k=0)^inftyz^k/TemplateBox[{{{alpha, , k}, +, beta}}, Gamma]$ .
The Mittag–Leffler function is equivalent to .
MittagLefflerE automatically threads over lists. »

Examples

open all close all

Basic Examples (5)

Evaluate numerically:

Wolfram Language code: MittagLefflerE[2., 1]

Plot over a subset of the reals:

Wolfram Language code: Plot[MittagLefflerE[1 / 4, z], {z, -4, 1}]

Plot over a subset of the complexes:

Wolfram Language code: ComplexPlot3D[MittagLefflerE[1 / 4, z], {z, -1 - I, 1 + I}, PlotLegends -> Automatic]

Series expansion at the origin:

Wolfram Language code: Series[MittagLefflerE[α, β, z], {z, 0, 4}]

Series expansion at Infinity:

Wolfram Language code: Series[MittagLefflerE[1, 1 / 2, x], {x, ∞, 6}]//Normal//FullSimplify

Scope (34)

Numerical Evaluation (7)

Evaluate numerically:

Wolfram Language code: MittagLefflerE[7., 5]

Wolfram Language code: MittagLefflerE[.2, .51, .87]

Evaluate for negative values of :

Wolfram Language code: MittagLefflerE[-7., 5]

Wolfram Language code: MittagLefflerE[-.2, .51, .87]

Evaluate to high precision:

Wolfram Language code: N[MittagLefflerE[2 / 5, 1 / 3, 8 / 7], 50]

The precision of the output tracks the precision of the input:

Wolfram Language code: MittagLefflerE[2.3000000000000000000000000, 3, 48]

Complex number input:

Wolfram Language code: MittagLefflerE[2.8, 8 + I]

Evaluate efficiently at high precision:

Wolfram Language code: MittagLefflerE[1 / 5, 1 / 3, 1 / 7`100]//Timing

Wolfram Language code: MittagLefflerE[1 / 5, 1 / 3, 1 / 7`500];//Timing

Compute the elementwise values of an array using automatic threading:

Wolfram Language code: MittagLefflerE[1 / 2, {{1 / 2, -1}, {0, 1 / 2}}]

Or compute the matrix MittagLefflerE function using MatrixFunction:

Wolfram Language code: MatrixFunction[MittagLefflerE[1 / 2, #]&, {{1 / 2, -1}, {0, 1 / 2}}]

Compute average-case statistical intervals using Around:

Wolfram Language code: MittagLefflerE[ 2, Around[2, 0.01]]

Specific Values (5)

Simple exact values are generated automatically:

Wolfram Language code: MittagLefflerE[2, 2 Pi]

Wolfram Language code: MittagLefflerE[2, 2, I Pi]

Evaluate symbolically:

Wolfram Language code: MittagLefflerE[2, 2 I Pi n]

Wolfram Language code: MittagLefflerE[1, 1, x]

Wolfram Language code: MittagLefflerE[1, β, x]

For small integer values of and , MittagLefflerE can be expressed in terms of elementary functions:

Wolfram Language code: MittagLefflerE[4, -1, z]

Use FunctionExpand for other cases:

Wolfram Language code: MittagLefflerE[8, 4, z]//FunctionExpand

Wolfram Language code: MittagLefflerE[1 / 2, 1 / 3, z]//FunctionExpand

Values at infinity:

Wolfram Language code: MittagLefflerE[1, {Infinity, -Infinity}]//Quiet

Find a value of x for which MittagLefflerE[1/2,x]=0.5:

Wolfram Language code: xval = x /. Solve[MittagLefflerE[1 / 2, x] == 0.5 && -1 < x < 5, x][[1]]//Quiet

Wolfram Language code:

Plot[MittagLefflerE[1 / 2, x], {x, -2, 1}, Epilog -> Style[Point[{xval, MittagLefflerE[1 / 2, xval]}], PointSize[Large], Red]]

Visualization (3)

Plot the MittagLefflerE function for integer values of :

Wolfram Language code: Plot[{MittagLefflerE[1, x], MittagLefflerE[2, x], MittagLefflerE[3, x]}, {x, -40, 10}, PlotRange -> Automatic]

Plot the MittagLefflerE function for noninteger values of :

Wolfram Language code: Plot[{MittagLefflerE[1 / 2, x], MittagLefflerE[1 / 3, x], MittagLefflerE[1 / 4, x]}, {x, -1, 2}, PlotRange -> Automatic]

Plot the real part of :

Wolfram Language code: ComplexContourPlot[Re[MittagLefflerE[2, z]], {z, -4 - 4 I, 4 + 4 I}, Contours -> 20]

Plot the imaginary part of :

Wolfram Language code: ComplexContourPlot[Im[MittagLefflerE[2, z]], {z, -4 - 4 I, 4 + 4 I}, Contours -> 20]

Function Properties (8)

is defined for all and real :

Wolfram Language code: FunctionDomain[MittagLefflerE[a, x], {a, x}]

The complex domain of MittagLefflerE is the same:

Wolfram Language code: FunctionDomain[MittagLefflerE[a, z], {a, z}, Complexes]

MittagLefflerE has the mirror property :

Wolfram Language code: FullSimplify[MittagLefflerE[1, Conjugate[z]] == Conjugate[MittagLefflerE[1, z]]]

MittagLefflerE threads elementwise over lists:

Wolfram Language code: MittagLefflerE[{1, 2, 3}, x]

MittagLefflerE is an analytic function for :

Wolfram Language code: FunctionAnalytic[{MittagLefflerE[a, x], a > 0}, {a, x}]

It is singular and discontinuous for :

Wolfram Language code: FunctionSingularities[MittagLefflerE[a, x], x]

Wolfram Language code: FunctionDiscontinuities[MittagLefflerE[a, x], x]

is injective:

Wolfram Language code: FunctionInjective[MittagLefflerE[2, x], x]

Wolfram Language code: Plot[{MittagLefflerE[2, x], 5}, {x, -10, 10}]

is not surjective:

Wolfram Language code: FunctionSurjective[MittagLefflerE[1 / 2, x], x]

Wolfram Language code: Plot[{MittagLefflerE[1 / 2, x], -1}, {x, -3, 3}]

is non-negative:

Wolfram Language code: FunctionSign[MittagLefflerE[1 / 2, x], x]

simplifies to :

Wolfram Language code: MittagLefflerE[a, 1, x]

Differentiation (3)

First derivatives with respect to z:

Wolfram Language code: D[MittagLefflerE[a, z], z]

Wolfram Language code: D[MittagLefflerE[a, b, z], z]

Higher derivatives with respect to z:

Wolfram Language code: Table[D[MittagLefflerE[a, z], {z, k}], {k, 1, 3}]//FullSimplify

Plot the higher derivatives with respect to z when a=1/4:

Wolfram Language code:

Plot[Evaluate[% /. { a -> 1 / 4}], {z, -1, 1}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative"}]

Use FunctionExpand for derivatives with respect to parameters:

Wolfram Language code: D[MittagLefflerE[a, z], a] /. a -> 1 / 2//FunctionExpand//Simplify

Wolfram Language code: D[MittagLefflerE[a, b, z], b] /. a -> 1 / 2//FunctionExpand//Simplify

Integration (2)

Indefinite integral of MittagLefflerE:

Wolfram Language code: Integrate[MittagLefflerE[α, x], x]

Wolfram Language code: Integrate[MittagLefflerE[α, β, x], x]

More integrals:

Wolfram Language code: ∫ z^pMittagLefflerE[α, z^2]ⅆz//TraditionalForm

Wolfram Language code: ∫ z^pMittagLefflerE[α, β, z^q]ⅆz//TraditionalForm

Series Expansions (2)

Find the Taylor expansion using Series:

Wolfram Language code: Series[MittagLefflerE[n, x], {x, 0, 3}]//Normal

Plots of the first three approximations around :

Wolfram Language code:

terms = Normal@Table[Series[MittagLefflerE[1 / 2, x], {x, 0, m}], {m, 1, 5, 2}];
Plot[{MittagLefflerE[1 / 2, x], terms}, {x, -10, 10}, PlotRange -> {-50, 50}]

Taylor expansion at a generic point:

Wolfram Language code: Series[MittagLefflerE[n, x], {x, x0, 2}]//Normal// FullSimplify

Fractional Differential Equations (3)

MittagLefflerE plays an important role in expressing solutions of fractional DEs with constant coefficients:

Wolfram Language code: sol = DSolve[{CaputoD[y[x], {x, 21 / 10}] + 10y[x] == 0, y[0] == 1, y'[0] == 0, y''[0] == 0}, y[x], x]

Verify the solution:

Wolfram Language code: CaputoD[y[x], {x, 21 / 10}] + 10y[x] == 0 /. sol

Plot the solution:

Wolfram Language code: Plot[y[x] /. sol, {x, 0, 10}]

Solve a fractional DE with constant coefficients containing two Caputo derivatives of different orders:

Wolfram Language code: sol = DSolve[{CaputoD[y[x], {x, 3 / 4}] == -2CaputoD[y[x], {x, 1 / 2}] + y[x], y[0] == 1}, y[x], x]//FullSimplify

Solve a system of two fractional DEs in vector form:

Wolfram Language code:

B = {{0, 1}, {-1, 0}};
a = 16 / 17;
v = {-3, 5};
sol = DSolve[{CaputoD[x[t], {t, a}] == B. x[t], x[0] == v}, Element[x[t], Vectors[2]], t]

Plot the solution:

Wolfram Language code: Plot[Evaluate[x[t] /. sol[[1]]], {t, 0, 10}]

Parametrically plot the solution:

Wolfram Language code: ParametricPlot[Evaluate[x[t] /. sol[[1]]], {t, 0, 20}]

Integral Transforms (1)

Laplace transform of specific MittagLefflerE functions:

Wolfram Language code:

LaplaceTransform[(1/Sqrt[t])(-MittagLefflerE[1 / 2, 1 / 2, Sqrt[t] / 2] + MittagLefflerE[1 / 2, 1 / 2, 2 / 3Sqrt[t]]), t, s]

ComplexPlot in the -domain:

Wolfram Language code: ComplexPlot[%, {s, -1 - I, 1 + I}]

Apply InverseLaplaceTransform to transform back to the time domain and get the initial expression:

Wolfram Language code: InverseLaplaceTransform[(1/(1 - (2/3 Sqrt[s])) Sqrt[s]) - (1/(1 - (1/2 Sqrt[s])) Sqrt[s]), s, t]

Applications (5)

The InverseLaplaceTransform of an algebraic function with fractional exponents can be expressed in terms of MittagLefflerE:

Wolfram Language code: InverseLaplaceTransform[(s^2 / 3/(s^2 / 3 - 1) (2s^2 / 3 + 5)), s, t]

Define a Mittag–Leffler random variate for :

Wolfram Language code:

Clear[MittagLeffler𝒟];
MittagLeffler𝒟[a_] = ProbabilityDistribution[x^a - 1MittagLefflerE[a, a, -x ^ a], {x, 0, Infinity}, Assumptions -> 0 < a < 1];

A Mittag–Leffler random variate is related to the positive stable random variate:

Wolfram Language code:

MittagLefflerRandomVariate[a_ /; 0 < a < 1, len_] := RandomVariate[TransformedDistribution[y x^1 / a, {yStableDistribution[1, a, 1, 0, Cos[Pi a / 2]^1 / a], xExponentialDistribution[1]}], len]

Generate random variates and compare the histogram to the distribution density:

Wolfram Language code:

Show[
	Histogram[MittagLefflerRandomVariate[2 / 3, 10 ^ 5], {1 / 10, 1, 1 / 25}, "PDF"], 
	Plot[PDF[MittagLeffler𝒟[2 / 3], x] / NProbability[1 / 10 < x < 1, xMittagLeffler𝒟[2 / 3]], {x, 1 / 10, 1}, Evaluated -> True, PlotRange -> All, PlotStyle -> Directive[Red, Thick]]]

A matrix and vector:

Wolfram Language code:

a = {{-19, -10, -2, -18}, {-23, -12, -3, -19}, {6, 6, 5, 6}, {38, 18, 2, 33}};
v0 = {1, 0, -1, 2};

Define a function for computing the Krylov matrix from a given matrix and vector:

Wolfram Language code: krylovMatrix[m_ ? SquareMatrixQ, v_ ? VectorQ] /; Length[m] == Length[v] := Transpose[NestList[m.#&, v, Length[v] - 1]]

Compute the eigenvalues of the matrix:

Wolfram Language code: λ = Eigenvalues[a]

Linear Caputo differential equations with constant coefficients can be solved using MittagLefflerE along with a Krylov matrix and the inverse of a Vandermonde matrix:

Wolfram Language code:

α = 3 / 4;
solα = krylovMatrix[a, v0].Inverse[VandermondeMatrix[λ]].MittagLefflerE[α, λ t^α]

Verify that the same result can be obtained from DSolveValue:

Wolfram Language code: DSolveValue[{CaputoD[v[t], {t, α}] == a.v[t], v[0] == v0}, v[t]∈Vectors[Length[v0]], t] == solα//FullSimplify

Carlitz defines a -permutation as a permutation with consecutive runs of increasing elements, followed by a tail of increasing elements. The figure below illustrates the case , :

Generate all permutations of length 8:

Wolfram Language code:

n = 8;
perms = Permutations[Range[n]];

Count the number of (3,2)-permutations of length 8:

Wolfram Language code:

k = 3;t = 2;
j = Quotient[n, k];
iseq = PadRight[Flatten[Riffle[ConstantArray[Less, {j, k - 1}], Greater, {2, -1, 2}]], n - 1, Less];
Count[perms, p_ /; Apply[Inequality, Riffle[p, iseq]]]

Define the Olivier function:

Wolfram Language code: OlivierPhi[k_, t_, x_] := x^tMittagLefflerE[k, t + 1, -x^k]

The generating function for the number of -permutations can be expressed as a ratio of Olivier functions. Use the generating function to count the number of (3,2)-permutations of length 8:

Wolfram Language code: SeriesCoefficient[(If[t == 0, 1, OlivierPhi[k, t, x]]/OlivierPhi[k, 0, x]), {x, 0, n}]n!

The universal Kepler equation can be used to predict the position and velocity of an orbiting body at a given time from an initial time . Here are the heliocentric position and velocity vectors of Mars from a given initial time:

Wolfram Language code:

date = DateObject[{2020, 8, 29, 12, 0, 0}, "Instant", "Gregorian", "America/Chicago"];
r0 = UnitConvert[EntityValue[Entity["Planet", "Mars"], EntityProperty["Planet", "HelioCoordinates", {"Date" -> date}]], "Kilometers"]

Wolfram Language code: v0 = EntityValue[Entity["Planet", "Mars"], EntityProperty["Planet", "HelioVelocityVector", {"Date" -> date}]]

Compute the magnitudes of the position and velocity vectors:

Wolfram Language code: {r0m, v0m} = Norm /@ {r0, v0}

Compute the initial radial velocity:

Wolfram Language code: vr0 = (r0.v0/r0m)

Compute the reciprocal of the semimajor axis from the vis-viva equation:

Wolfram Language code:

μ = Quantity["SolarMassParameter"];
α = UnitConvert[(2/r0m) - (v0m^2/μ), 1 / "Kilometers"]

Estimate the position and velocity vectors of Mars after 8 hours have passed:

Wolfram Language code: Δt = Quantity[8, "Hour"];

Define the Stumpff function, which appears in the universal variable formulation of the Kepler equation:

Wolfram Language code: StumpffC[k_, x_] := MittagLefflerE[2, k + 1, -x]

Solve for the "universal anomaly" from the universal Kepler equation:

Wolfram Language code:

𝒶 = QuantityMagnitude[α];
c1 = QuantityMagnitude[(r0m vr0/Sqrt[μ]), Sqrt["Kilometers"]];
c2 = 1 - α r0m;
c3 = QuantityMagnitude[Sqrt[μ]Δt, Sqrt["Kilometers"^3]];
c4 = QuantityMagnitude[r0m];
χt = Quantity[χ, Sqrt["Kilometers"]] /. FindRoot[c1 χ^2StumpffC[2, 𝒶 χ^2] + c2 χ^3StumpffC[3, 𝒶 χ^2] == c3 - c4 χ, {χ, QuantityMagnitude[Sqrt[μ]Abs[α]Δt, Sqrt["Kilometers"]]}]//Chop

Compute the Lagrange coefficients from the universal anomaly:

Wolfram Language code: {𝒻, ℊ} = {1 - (χt^2/r0m)StumpffC[2, α χt^2], Δt - (χt^3/Sqrt[μ])StumpffC[3, α χt^2]}//UnitConvert

Compute the position vector after eight hours:

Wolfram Language code: rf = {𝒻, ℊ}.{r0, v0}

Compare with the true value:

Wolfram Language code:

UnitConvert[EntityValue[Entity["Planet", "Mars"], EntityProperty["Planet", "HelioCoordinates", {"Date" -> DatePlus[date, Δt]}]], "Kilometers"]

Compute the derivative of the Lagrange coefficients with respect to time:

Wolfram Language code:

{𝒻𝓅, ℊ𝓅} = {(Sqrt[μ]/r0m Norm[rf])(α χt^3StumpffC[3, α χt^2] - χt), 1 - (χt^2/Norm[rf])StumpffC[2, α χt^2]}//UnitConvert

Compute the velocity vector after eight hours:

Wolfram Language code: vf = {𝒻𝓅, ℊ𝓅}.{r0, v0}

Compare with the true value:

Wolfram Language code: EntityValue[Entity["Planet", "Mars"], EntityProperty["Planet", "HelioVelocityVector", {"Date" -> DatePlus[date, Δt]}]]

Properties & Relations (4)

The Mittag–Leffler function is closed under differentiation:

Wolfram Language code: D[MittagLefflerE[α, β, z], z]

The function simplifies to elementary functions for small non-negative integer :

Wolfram Language code: MittagLefflerE[5, z]

Larger non-negative integer values of give results in terms of HypergeometricPFQ:

Wolfram Language code: MittagLefflerE[8, z]

For non-negative half-integer , simplifies to a sum of HypergeometricPFQ functions:

Wolfram Language code: MittagLefflerE[5 / 2, z]

The defining sum for the Mittag–Leffler function:

Wolfram Language code: Sum[(z^k/Gamma[a k + 1]), {k, 0, ∞}]

For specific values of , this sum might be written in terms of HypergeometricPFQ functions:

Wolfram Language code: Sum[(z^k/Gamma[5 / 2k + 1]), {k, 0, ∞}, Method -> "InactivePFQ"]

Compare this with the MittagLefflerE output:

Wolfram Language code: MittagLefflerE[5 / 2, z]

The family of MittagLefflerE functions can be represented in terms of FoxH:

Wolfram Language code: FoxHReduce[MittagLefflerE[1 / 2, x], x]

Wolfram Language code: FoxHReduce[MittagLefflerE[a, b, x], x]

Top

More Learning

Tech Support

Wolfram Solutions

Wolfram Solutions For Education

Get Started

Grow Your Skills

Work with Us

Educational Programs for Adults

Educational Programs for Youth

Read

MittagLefflerE

Details

Examples

Basic Examples (5)

Scope (34)

Numerical Evaluation (7)

Specific Values (5)

Visualization (3)

Function Properties (8)

Differentiation (3)

Integration (2)

Series Expansions (2)

Fractional Differential Equations (3)

Integral Transforms (1)

Applications (5)

Properties & Relations (4)

Text

CMS

APA

BibTeX

BibLaTeX

MittagLefflerE

Details

Examples

Basic Examples (5)

Scope (34)

Numerical Evaluation (7)

Specific Values (5)

Visualization (3)

Function Properties (8)

Differentiation (3)

Integration (2)

Series Expansions (2)

Fractional Differential Equations (3)

Integral Transforms (1)

Applications (5)

Properties & Relations (4)

See Also

Tech Notes

Related Guides

History

Text

CMS

APA

BibTeX

BibLaTeX